1m4_divert(-1)
2# file      : build/meta/vc9proj.m4
3# copyright : Copyright (c) 2009-2012 Code Synthesis Tools CC
4# license   : GNU GPL v2; see accompanying LICENSE file
5
6m4_changequote([, ])
7
8m4_include(__meta_base__[/common.m4])
9m4_include(__meta_base__[/windows-common.m4])
10
11# file
12#
13m4_define([__file_entry_impl__],[
14			<File
15				RelativePath=".\[$1]"
16				>
17			</File>])
18
19m4_define([__file_entry__],
20[m4_equote()__file_entry_impl__([$1])[]m4_dquote()])
21
22
23m4_define([__file_entries_impl__],
24[m4_foreach_w([__f], __path_impl__([$1]), [__file_entry_impl__(__f)])])
25
26m4_define([__file_entries__],
27[m4_equote()__file_entries_impl__([$1])[]m4_dquote()])
28
29# file_custom_build
30#
31m4_define([__custom_build_entry_impl__],[
32				<FileConfiguration
33					Name=[$1]
34					>
35					<Tool
36						Name="VCCustomBuildTool"
37						Description="[$2]"
38						CommandLine="[$3]"m4_ifelse([$5], [], [], [
39						AdditionalDependencies="$5"])
40						Outputs="[$4]"
41					/>
42				</FileConfiguration>])
43
44m4_define([__file_entry_custom_build_impl__],[
45			<File
46				RelativePath=".\[$1]"
47				>m4_dnl
48m4_foreach([__c],
49[__value_impl__([configurations])],
50[__custom_build_entry_impl__(__c, [$2], [$3], [$4], [$5])])
51			</File>])
52
53# (file, cmd-description, cmd, output;output[, add-dep;add-dep])
54#
55m4_define([__file_entry_custom_build__],
56[m4_equote()__file_entry_custom_build_impl__([$1],
57[$2], [$3], [$4], [$5])[]m4_dquote()])
58
59
60# source
61#
62
63# $1 - configuration
64# $2 - directory
65#
66m4_define([__source_config_entry_impl__],[
67				<FileConfiguration
68					Name=[$1]
69					>
70					<Tool
71						Name="VCCLCompilerTool"
72						ObjectFile="$(IntDir)\[$2]\"
73					/>
74				</FileConfiguration>])
75
76m4_define([__source_config_impl__],
77[m4_ifelse([$1], [$2], [],
78[m4_foreach([__c],
79[__value_impl__([configurations])],
80[__source_config_entry_impl__(__c, [$1])])])])
81
82m4_define([__source_entry_impl__],[
83			<File
84				RelativePath=".\[$1]"
85				>m4_dnl
86__source_config_impl__(m4_patsubst([$1], [^\(.*\)\\\(.*\)$], [\1]), [$1])
87			</File>])
88
89m4_define([__source_entry__],
90[m4_equote()__source_entry_impl__([$1])[]m4_dquote()])
91
92m4_define([__source_entries_impl__],
93[m4_foreach_w([__f], __path_impl__([$1]), [__source_entry_impl__(__f)])])
94
95m4_define([__source_entries__],
96[m4_equote()__source_entries_impl__([$1])[]m4_dquote()])
97
98# Disable comments and quoting.
99#
100m4_changecom([])
101m4_changequote([])
102
103m4_divert(0)m4_dnl
104