1AC_DEFUN([GP_CHECK_GEANYVC],
2[
3    GP_ARG_DISABLE([GeanyVC], [auto])
4    GP_COMMIT_PLUGIN_STATUS([GeanyVC])
5    AC_ARG_ENABLE(gtkspell,
6        AC_HELP_STRING([--enable-gtkspell=ARG],
7            [Enable GtkSpell support in GeanyVC. [[default=auto]]]),,
8        enable_gtkspell=auto)
9    GP_CHECK_GTK3([gtkspell_package=gtkspell3-3.0],
10                  [gtkspell_package=gtkspell-2.0])
11    if [[ x"$enable_gtkspell" = "xauto" ]]; then
12        PKG_CHECK_MODULES(GTKSPELL, $gtkspell_package,
13            enable_gtkspell=yes, enable_gtkspell=no)
14    elif [[ x"$enable_gtkspell" = "xyes" ]]; then
15        PKG_CHECK_MODULES(GTKSPELL, [$gtkspell_package])
16    fi
17    if [[ x"$enable_gtkspell" = "xyes" ]]; then
18        AC_DEFINE(USE_GTKSPELL, 1, [GtkSpell support])
19    fi
20
21    if [[ "$enable_gtkspell" = yes -a "$enable_geanyvc" = no ]]; then
22       AC_MSG_WARN([GtkSpell support for GeanyVC enabled, but GeanyVC itself not enabled.])
23    fi
24
25    GP_STATUS_FEATURE_ADD([GeanyVC GtkSpell support], [$enable_gtkspell])
26
27    AC_CONFIG_FILES([
28        geanyvc/Makefile
29        geanyvc/src/Makefile
30    ])
31])
32