1## Process this file with autoconf to produce configure.
2## In general, the safest way to proceed is to run ./autogen.sh
3
4AC_PREREQ(2.59)
5
6# Note:  If you change the version, you must also update it in:
7# * Protobuf.podspec
8# * csharp/Google.Protobuf.Tools.nuspec
9# * csharp/src/*/AssemblyInfo.cs
10# * csharp/src/Google.Protobuf/Google.Protobuf.nuspec
11# * java/*/pom.xml
12# * python/google/protobuf/__init__.py
13# * protoc-artifacts/pom.xml
14# * src/google/protobuf/stubs/common.h
15# * src/Makefile.am (Update -version-info for LDFLAGS if needed)
16#
17# In the SVN trunk, the version should always be the next anticipated release
18# version with the "-pre" suffix.  (We used to use "-SNAPSHOT" but this pushed
19# the size of one file name in the dist tarfile over the 99-char limit.)
20AC_INIT([Protocol Buffers],[3.17.3],[protobuf@googlegroups.com],[protobuf])
21
22AM_MAINTAINER_MODE([enable])
23
24AC_CONFIG_SRCDIR(src/google/protobuf/message.cc)
25# The config file is generated but not used by the source code, since we only
26# need very few of them, e.g. HAVE_PTHREAD and HAVE_ZLIB. Those macros are
27# passed down in CXXFLAGS manually in src/Makefile.am
28AC_CONFIG_HEADERS([config.h])
29AC_CONFIG_MACRO_DIR([m4])
30
31AC_ARG_VAR(DIST_LANG, [language to include in the distribution package (i.e., make dist)])
32case "$DIST_LANG" in
33  "") DIST_LANG=all ;;
34  all | cpp | csharp | java | python | javanano | objectivec | ruby | js | php) ;;
35  *) AC_MSG_FAILURE([unknown language: $DIST_LANG]) ;;
36esac
37AC_SUBST(DIST_LANG)
38
39# autoconf's default CXXFLAGS are usually "-g -O2".  These aren't necessarily
40# the best choice for libprotobuf.
41AS_IF([test "x${ac_cv_env_CFLAGS_set}" = "x"],
42      [CFLAGS=""])
43AS_IF([test "x${ac_cv_env_CXXFLAGS_set}" = "x"],
44      [CXXFLAGS=""])
45
46AC_CANONICAL_TARGET
47
48AM_INIT_AUTOMAKE([1.9 tar-ustar subdir-objects])
49
50# Silent rules enabled: the output is minimal but informative.
51# In particular, the warnings from the compiler stick out very clearly.
52# To see all logs, use the --disable-silent-rules on configure or via make V=1
53AM_SILENT_RULES([yes])
54
55AC_ARG_WITH([zlib],
56  [AS_HELP_STRING([--with-zlib],
57    [include classes for streaming compressed data in and out @<:@default=check@:>@])],
58  [],[with_zlib=check])
59
60AC_ARG_WITH([zlib-include],
61  [AS_HELP_STRING([--with-zlib-include=PATH],
62    [zlib include directory])],
63  [CPPFLAGS="-I$withval $CPPFLAGS"])
64
65AC_ARG_WITH([zlib-lib],
66  [AS_HELP_STRING([--with-zlib-lib=PATH],
67    [zlib lib directory])],
68  [LDFLAGS="-L$withval $LDFLAGS"])
69
70AC_ARG_WITH([protoc],
71  [AS_HELP_STRING([--with-protoc=COMMAND],
72    [use the given protoc command instead of building a new one when building tests (useful for cross-compiling)])],
73  [],[with_protoc=no])
74
75# Checks for programs.
76AC_PROG_CC
77AC_PROG_CXX
78AC_PROG_CXX_FOR_BUILD
79AC_LANG([C++])
80ACX_USE_SYSTEM_EXTENSIONS
81m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
82AM_CONDITIONAL(GCC, test "$GCC" = yes)   # let the Makefile know if we're gcc
83AC_PROG_OBJC
84
85# test_util.cc takes forever to compile with GCC and optimization turned on.
86AC_MSG_CHECKING([C++ compiler flags...])
87AS_IF([test "x${ac_cv_env_CXXFLAGS_set}" = "x"],[
88  AS_IF([test "$GCC" = "yes"],[
89    PROTOBUF_OPT_FLAG="-O2"
90    CXXFLAGS="${CXXFLAGS} -g"
91  ])
92
93  # Protocol Buffers contains several checks that are intended to be used only
94  # for debugging and which might hurt performance.  Most users are probably
95  # end users who don't want these checks, so add -DNDEBUG by default.
96  CXXFLAGS="$CXXFLAGS -std=c++11 -DNDEBUG"
97
98  AC_MSG_RESULT([use default: $PROTOBUF_OPT_FLAG $CXXFLAGS])
99],[
100  AC_MSG_RESULT([use user-supplied: $CXXFLAGS])
101])
102
103AC_SUBST(PROTOBUF_OPT_FLAG)
104
105ACX_CHECK_SUNCC
106
107# Have to do libtool after SUNCC, other wise it "helpfully" adds Crun Cstd
108# to the link
109AC_PROG_LIBTOOL
110
111# Check whether the linker supports version scripts
112AC_MSG_CHECKING([whether the linker supports version scripts])
113save_LDFLAGS=$LDFLAGS
114LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
115cat > conftest.map <<EOF
116{
117  global:
118    main;
119  local:
120    *;
121};
122EOF
123AC_LINK_IFELSE(
124  [AC_LANG_SOURCE([int main() { return 0; }])],
125  [have_ld_version_script=yes; AC_MSG_RESULT(yes)],
126  [have_ld_version_script=no; AC_MSG_RESULT(no)])
127LDFLAGS=$save_LDFLAGS
128AM_CONDITIONAL([HAVE_LD_VERSION_SCRIPT], [test "$have_ld_version_script" = "yes"])
129
130# Checks for header files.
131AC_HEADER_STDC
132AC_CHECK_HEADERS([fcntl.h inttypes.h limits.h stdlib.h unistd.h])
133
134# Checks for library functions.
135AC_FUNC_MEMCMP
136AC_FUNC_STRTOD
137AC_CHECK_FUNCS([ftruncate memset mkdir strchr strerror strtol])
138
139# Check for zlib.
140HAVE_ZLIB=0
141AS_IF([test "$with_zlib" != no], [
142  AC_MSG_CHECKING([zlib version])
143
144  # First check the zlib header version.
145  AC_COMPILE_IFELSE(
146    [AC_LANG_PROGRAM([[
147        #include <zlib.h>
148        #if !defined(ZLIB_VERNUM) || (ZLIB_VERNUM < 0x1204)
149        # error zlib version too old
150        #endif
151        ]], [])], [
152    AC_MSG_RESULT([ok (1.2.0.4 or later)])
153
154    # Also need to add -lz to the linker flags and make sure this succeeds.
155    AC_SEARCH_LIBS([zlibVersion], [z], [
156      AC_DEFINE([HAVE_ZLIB], [1], [Enable classes using zlib compression.])
157      HAVE_ZLIB=1
158    ], [
159      AS_IF([test "$with_zlib" != check], [
160        AC_MSG_FAILURE([--with-zlib was given, but no working zlib library was found])
161      ])
162    ])
163  ], [
164    AS_IF([test "$with_zlib" = check], [
165      AC_MSG_RESULT([headers missing or too old (requires 1.2.0.4)])
166    ], [
167      AC_MSG_FAILURE([--with-zlib was given, but zlib headers were not present or were too old (requires 1.2.0.4)])
168    ])
169  ])
170])
171AM_CONDITIONAL([HAVE_ZLIB], [test $HAVE_ZLIB = 1])
172
173# Add -std=c++11 if necesssary. It is important for us to do this before the
174# libatomic check below, since that also depends on C++11.
175AX_CXX_COMPILE_STDCXX([11], [noext], [mandatory])
176
177dnl On some platforms, std::atomic needs a helper library
178AC_MSG_CHECKING(whether -latomic is needed)
179AC_LINK_IFELSE([AC_LANG_SOURCE([[
180  #include <atomic>
181  #include <cstdint>
182  std::atomic<std::int64_t> v;
183  int main() {
184    return v;
185  }
186]])], STD_ATOMIC_NEED_LIBATOMIC=no, STD_ATOMIC_NEED_LIBATOMIC=yes)
187AC_MSG_RESULT($STD_ATOMIC_NEED_LIBATOMIC)
188if test "x$STD_ATOMIC_NEED_LIBATOMIC" = xyes; then
189  LIBATOMIC_LIBS="-latomic"
190fi
191AC_SUBST([LIBATOMIC_LIBS])
192
193AS_IF([test "$with_protoc" != "no"], [
194  PROTOC=$with_protoc
195  AS_IF([test "$with_protoc" = "yes"], [
196    # No argument given.  Use system protoc.
197    PROTOC=protoc
198  ])
199  AS_IF([echo "$PROTOC" | grep -q '^@<:@^/@:>@.*/'], [
200    # Does not start with a slash, but contains a slash.  So, it's a relative
201    # path (as opposed to an absolute path or an executable in $PATH).
202    # Since it will actually be executed from the src directory, prefix with
203    # the current directory.  We also insert $ac_top_build_prefix in case this
204    # is a nested package and --with-protoc was actually given on the outer
205    # package's configure script.
206    PROTOC=`pwd`/${ac_top_build_prefix}$PROTOC
207  ])
208  AC_SUBST([PROTOC])
209])
210AM_CONDITIONAL([USE_EXTERNAL_PROTOC], [test "$with_protoc" != "no"])
211
212AX_PTHREAD
213AM_CONDITIONAL([HAVE_PTHREAD], [test "x$ax_pthread_ok" = "xyes"])
214# We still keep this for improving pbconfig.h for unsupported platforms.
215AC_CXX_STL_HASH
216
217# Enable ObjC support for conformance directory on OS X.
218OBJC_CONFORMANCE_TEST=0
219case "$target_os" in
220  darwin*)
221    OBJC_CONFORMANCE_TEST=1
222    ;;
223esac
224AM_CONDITIONAL([OBJC_CONFORMANCE_TEST], [test $OBJC_CONFORMANCE_TEST = 1])
225
226AC_MSG_CHECKING(whether -llog is needed)
227ANDROID_TEST=no
228case "$target_os" in
229  *android*)
230    ANDROID_TEST=yes
231    ;;
232esac
233AC_MSG_RESULT($ANDROID_TEST)
234if test "x$ANDROID_TEST" = xyes; then
235  LIBLOG_LIBS="-llog"
236fi
237AC_SUBST([LIBLOG_LIBS])
238
239# HACK:  Make gmock's configure script pick up our copy of CFLAGS and CXXFLAGS,
240#   since the flags added by ACX_CHECK_SUNCC must be used when compiling gmock
241#   too.
242export CFLAGS
243export CXXFLAGS
244AC_CONFIG_SUBDIRS([third_party/googletest])
245
246AC_CONFIG_FILES([Makefile src/Makefile benchmarks/Makefile conformance/Makefile protobuf.pc protobuf-lite.pc])
247AC_OUTPUT
248