1dnl Process this file with autoconf to produce a configure script.
2dnl
3
4AC_PREREQ(2.13)
5AC_INIT(libbfd.c)
6
7AC_CANONICAL_SYSTEM
8AC_ISC_POSIX
9
10AM_INIT_AUTOMAKE(bfd, 2.15)
11# Uncomment the next line to remove the date from the reported bfd version
12is_release=y
13
14changequote(,)dnl
15bfd_version=`echo "${VERSION}" | sed -e 's/\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\).*/\1.00\2.00\3.00\4.00\5/' -e 's/\([^\.]*\)\..*\(..\)\..*\(..\)\..*\(..\)\..*\(..\)$/\1\2\3\4\5/'`
16changequote([,])dnl
17
18bfd_version_string="\"${VERSION}\""
19if test x${is_release} = x; then
20  bfd_version_date=`sed -n -e 's/.*DATE //p' < ${srcdir}/version.h`
21  bfd_version_string="\"${VERSION} ${bfd_version_date}\""
22fi
23AC_SUBST(bfd_version)
24AC_SUBST(bfd_version_string)
25
26dnl These must be called before AM_PROG_LIBTOOL, because it may want
27dnl to call AC_CHECK_PROG.
28AC_CHECK_TOOL(AR, ar)
29AC_CHECK_TOOL(RANLIB, ranlib, :)
30
31dnl Default to a non shared library.  This may be overridden by the
32dnl configure option --enable-shared.
33AM_DISABLE_SHARED
34
35AM_PROG_LIBTOOL
36
37AC_ARG_ENABLE(64-bit-bfd,
38[  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
39[case "${enableval}" in
40  yes)  want64=true  ;;
41  no)   want64=false ;;
42  *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
43esac],[want64=false])dnl
44AC_ARG_ENABLE(targets,
45[  --enable-targets        alternative target configurations],
46[case "${enableval}" in
47  yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
48            ;;
49  no)       enable_targets= ;;
50  *)        enable_targets=$enableval ;;
51esac])dnl
52AC_ARG_ENABLE(commonbfdlib,
53[  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
54[case "${enableval}" in
55  yes) commonbfdlib=true ;;
56  no)  commonbfdlib=false ;;
57  *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
58esac])dnl
59AC_ARG_WITH(mmap,
60[  --with-mmap             try using mmap for BFD input files if available],
61[case "${withval}" in
62  yes)  want_mmap=true ;;
63  no)   want_mmap=false ;;
64  *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
65esac],[want_mmap=false])dnl
66
67build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
68AC_ARG_ENABLE(build-warnings,
69[  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
70[case "${enableval}" in
71  yes)	;;
72  no)	build_warnings="-w";;
73  ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
74        build_warnings="${build_warnings} ${t}";;
75  *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
76        build_warnings="${t} ${build_warnings}";;
77  *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
78esac
79if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
80  echo "Setting warning flags = $build_warnings" 6>&1
81fi])dnl
82WARN_CFLAGS=""
83if test "x${build_warnings}" != x && test "x$GCC" = xyes ; then
84    WARN_CFLAGS="${build_warnings}"
85fi
86AC_SUBST(WARN_CFLAGS)
87
88AM_CONFIG_HEADER(config.h:config.in)
89
90if test -z "$target" ; then
91    AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
92fi
93
94AM_MAINTAINER_MODE
95AM_INSTALL_LIBBFD
96AC_EXEEXT
97
98host64=false
99target64=false
100bfd_default_target_size=32
101
102# host stuff:
103
104AC_PROG_CC
105
106ALL_LINGUAS="fr tr ja es sv da zh_CN ro"
107CY_GNU_GETTEXT
108
109# Permit host specific settings.
110. ${srcdir}/configure.host
111
112AC_SUBST(HDEFINES)
113AC_PROG_INSTALL
114
115BFD_HOST_64BIT_LONG=0
116BFD_HOST_LONG_LONG=0
117BFD_HOST_64_BIT_DEFINED=0
118BFD_HOST_64_BIT=
119BFD_HOST_U_64_BIT=
120
121AC_MSG_CHECKING([for long long])
122AC_CACHE_VAL(bfd_cv_has_long_long,
123[AC_TRY_COMPILE(,
124[unsigned long long ll = 18446744073709551615ULL;],
125bfd_cv_has_long_long=yes, bfd_cv_has_long_long=no)])
126AC_MSG_RESULT($bfd_cv_has_long_long)
127if test $bfd_cv_has_long_long = yes; then
128  BFD_HOST_LONG_LONG=1
129  AC_COMPILE_CHECK_SIZEOF(long long)
130fi
131
132AC_COMPILE_CHECK_SIZEOF(long)
133if test "x${ac_cv_sizeof_long}" = "x8"; then
134  host64=true
135  BFD_HOST_64BIT_LONG=1
136  test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
137  test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
138elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
139  test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
140  test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
141fi
142
143if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
144  BFD_HOST_64_BIT_DEFINED=1
145  BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
146  BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
147fi
148
149AC_SUBST(BFD_HOST_64BIT_LONG)
150AC_SUBST(BFD_HOST_LONG_LONG)
151AC_SUBST(BFD_HOST_64_BIT_DEFINED)
152AC_SUBST(BFD_HOST_64_BIT)
153AC_SUBST(BFD_HOST_U_64_BIT)
154
155BFD_CC_FOR_BUILD
156
157AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
158AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
159AC_HEADER_TIME
160AC_HEADER_DIRENT
161AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
162AC_CHECK_FUNCS(strtoull)
163
164BFD_BINARY_FOPEN
165
166BFD_NEED_DECLARATION(strstr)
167BFD_NEED_DECLARATION(malloc)
168BFD_NEED_DECLARATION(realloc)
169BFD_NEED_DECLARATION(free)
170BFD_NEED_DECLARATION(getenv)
171
172# If we are configured native, pick a core file support file.
173COREFILE=
174COREFLAG=
175TRAD_HEADER=
176if test "${target}" = "${host}"; then
177  case "${host}" in
178  alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
179	COREFILE=''
180	;;
181  alpha*-*-linux-gnu*)
182	COREFILE=trad-core.lo
183	TRAD_HEADER='"hosts/alphalinux.h"'
184	;;
185  alpha*-*-netbsd* | alpha*-*-openbsd*)
186	COREFILE=netbsd-core.lo
187	;;
188  alpha*-*-*)		COREFILE=osf-core.lo ;;
189  arm-*-freebsd* | arm-*-kfreebsd*-gnu)
190			COREFILE='' ;;
191  arm-*-netbsd*)	COREFILE=netbsd-core.lo ;;
192  arm-*-riscix)		COREFILE=trad-core.lo ;;
193  hppa*-*-hpux*)	COREFILE=hpux-core.lo ;;
194  hppa*-*-hiux*)	COREFILE=hpux-core.lo ;;
195  hppa*-*-mpeix*)	COREFILE=hpux-core.lo ;;
196  hppa*-*-bsd*)		COREFILE="hpux-core.lo hppabsd-core.lo"
197			COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
198  i370-*-*)
199	COREFILE=trad-core.lo
200	TRAD_HEADER='"hosts/i370linux.h"'
201	;;
202
203changequote(,)dnl
204  i[3-7]86-sequent-bsd*)
205changequote([,])dnl
206	COREFILE=trad-core.lo
207	TRAD_HEADER='"hosts/symmetry.h"'
208	;;
209changequote(,)dnl
210  i[3-7]86-sequent-sysv4*) ;;
211  i[3-7]86-sequent-sysv*)
212changequote([,])dnl
213	COREFILE=trad-core.lo
214	TRAD_HEADER='"hosts/symmetry.h"'
215	;;
216changequote(,)dnl
217  i[3-7]86-*-bsdi)
218changequote([,])dnl
219	COREFILE=
220	;;
221changequote(,)dnl
222  i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234]* | i[3-7]86-*-freebsd*aout*)
223changequote([,])dnl
224	COREFILE=trad-core.lo
225	TRAD_HEADER='"hosts/i386bsd.h"'
226	;;
227changequote(,)dnl
228  i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
229changequote([,])dnl
230	COREFILE=''
231	TRAD_HEADER='"hosts/i386bsd.h"'
232	;;
233changequote(,)dnl
234  i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
235changequote([,])dnl
236	COREFILE=netbsd-core.lo
237	;;
238changequote(,)dnl
239  i[3-7]86-esix-sysv3*)
240changequote([,])dnl
241	COREFILE=trad-core.lo
242	TRAD_HEADER='"hosts/esix.h"'
243	;;
244changequote(,)dnl
245  i[3-7]86-*-sco3.2v5*)
246changequote([,])dnl
247	COREFILE=sco5-core.lo
248	;;
249changequote(,)dnl
250  i[3-7]86-*-sco* | i[3-7]86-*-isc*)
251changequote([,])dnl
252	COREFILE=trad-core.lo
253	TRAD_HEADER='"hosts/i386sco.h"'
254	;;
255changequote(,)dnl
256  i[3-7]86-*-mach3*)
257changequote([,])dnl
258	COREFILE=trad-core.lo
259	TRAD_HEADER='"hosts/i386mach3.h"'
260	;;
261changequote(,)dnl
262  i[3-7]86-*-linux-gnu*)
263changequote([,])dnl
264	COREFILE=trad-core.lo
265	TRAD_HEADER='"hosts/i386linux.h"'
266	;;
267changequote(,)dnl
268  i[3-7]86-*-isc*)	COREFILE=trad-core.lo ;;
269  i[3-7]86-*-aix*)	COREFILE=aix386-core.lo ;;
270changequote([,])dnl
271  i860-*-mach3* | i860-*-osf1*)
272	COREFILE=trad-core.lo
273	TRAD_HEADER='"hosts/i860mach3.h"'
274	;;
275  mips-*-netbsd* | mips*-*-openbsd*)
276	COREFILE=netbsd-core.lo
277	;;
278  mips-dec-*)
279	COREFILE=trad-core.lo
280	TRAD_HEADER='"hosts/decstation.h"'
281	;;
282  mips-sgi-irix4*)	COREFILE=irix-core.lo ;;
283  mips-sgi-irix5*)	COREFILE=irix-core.lo ;;
284  mips-sgi-irix6*)	COREFILE=irix-core.lo ;;
285  mips-*-sysv4*)	;;
286  mips-*-sysv* | mips-*-riscos*)
287	COREFILE=trad-core.lo
288	TRAD_HEADER='"hosts/riscos.h"'
289	;;
290  mips-sony-bsd*)
291	COREFILE=trad-core.lo
292	TRAD_HEADER='"hosts/news-mips.h"'
293	;;
294  m68*-bull*-sysv*)
295	COREFILE=trad-core.lo
296	TRAD_HEADER='"hosts/dpx2.h"'
297	;;
298  m68*-hp-hpux*)	COREFILE=hpux-core.lo ;;
299  m68*-hp-bsd*)
300	COREFILE=trad-core.lo
301	TRAD_HEADER='"hosts/hp300bsd.h"'
302	;;
303  m68*-*-linux-gnu*)
304	COREFILE=trad-core.lo
305	TRAD_HEADER='"hosts/m68klinux.h"'
306	;;
307  m68*-motorola-sysv*)
308	COREFILE=trad-core.lo
309	TRAD_HEADER='"hosts/delta68.h"'
310	;;
311  m68*-sony-*)
312	COREFILE=trad-core.lo
313	TRAD_HEADER='"hosts/news.h"'
314	;;
315  m68*-*-netbsd* | m68*-*-openbsd*)
316	COREFILE=netbsd-core.lo
317	;;
318  m68*-apple-aux*)
319	COREFILE=trad-core.lo
320	TRAD_HEADER='"hosts/m68kaux.h"'
321	;;
322  m88*-*-sysv4*)
323	;;
324  m88*-motorola-sysv*)
325	COREFILE=ptrace-core.lo
326	;;
327  m88*-*-mach3*)
328	COREFILE=trad-core.lo
329	TRAD_HEADER='"hosts/m88kmach3.h"'
330	;;
331  ns32k-pc532-mach)
332	COREFILE=trad-core.lo
333	TRAD_HEADER='"hosts/pc532mach.h"'
334	;;
335  ns32k-*-netbsd* | ns32k-*-openbsd*)
336	COREFILE=netbsd-core.lo
337	;;
338  rs6000-*-lynx*)
339  	COREFILE=lynx-core.lo
340	;;
341  rs6000-*-aix5.* | powerpc-*-aix5.*)
342        COREFILE=rs6000-core.lo
343	COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
344	;;
345changequote(,)dnl
346  rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
347changequote([,])dnl
348        COREFILE=rs6000-core.lo
349	COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
350	# Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
351	# have c_impl as a member of struct core_dumpx
352	AC_MSG_CHECKING([for c_impl in struct core_dumpx])
353	AC_TRY_COMPILE([#include <core.h>],
354	  [struct core_dumpx c; c.c_impl = 0;],
355	  [AC_DEFINE(HAVE_ST_C_IMPL, 1,
356	    [Define if struct core_dumpx has member c_impl])
357	  AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
358	;;
359  rs6000-*-aix4*)	COREFILE=rs6000-core.lo ;;
360  rs6000-*-*)		COREFILE=rs6000-core.lo ;;
361  powerpc-*-aix4*)	COREFILE=rs6000-core.lo ;;
362  powerpc-*-aix*)	COREFILE=rs6000-core.lo ;;
363  powerpc-*-beos*)	;;
364  powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
365		        COREFILE='' ;;
366  powerpc-*-netbsd*)	COREFILE=netbsd-core.lo ;;
367  powerpc-*-*bsd*)	COREFILE=netbsd-core.lo ;;
368  s390*-*-*)            COREFILE=trad-core.lo ;;
369  sh*-*-netbsd*)	COREFILE=netbsd-core.lo ;;
370  sparc-*-netbsd* | sparc*-*-openbsd*)
371	COREFILE=netbsd-core.lo
372	;;
373  tahoe-*-*)
374	COREFILE=trad-core.lo
375	TRAD_HEADER='"hosts/tahoe.h"'
376	;;
377  vax-*-netbsd* | vax-*-openbsd*)
378  	COREFILE=netbsd-core.lo
379	;;
380  vax-*-ultrix2*)
381	COREFILE=trad-core.lo
382	TRAD_HEADER='"hosts/vaxult2.h"'
383	;;
384  vax-*-ultrix*)
385	COREFILE=trad-core.lo
386	TRAD_HEADER='"hosts/vaxult2.h"'
387	;;
388  vax-*-linux-gnu*)
389	COREFILE=trad-core.lo
390	TRAD_HEADER='"hosts/vaxlinux.h"'
391	;;
392  vax-*-*)
393	COREFILE=trad-core.lo
394	TRAD_HEADER='"hosts/vaxbsd.h"'
395	;;
396  x86_64-*-netbsd* | x86_64-*-openbsd*)
397	COREFILE=netbsd-core.lo
398	;;
399  esac
400
401  case "$COREFILE" in
402  aix386-core.lo)	COREFLAG=-DAIX386_CORE ;;
403  hppabsd-core.lo)	COREFLAG=-DHPPABSD_CORE ;;
404  hpux-core.lo)		COREFLAG=-DHPUX_CORE ;;
405  irix-core.lo)		COREFLAG=-DIRIX_CORE ;;
406  lynx-core.lo)		COREFLAG=-DLYNX_CORE ;;
407  netbsd-core.lo)	COREFLAG=-DNETBSD_CORE ;;
408  osf-core.lo)		COREFLAG=-DOSF_CORE ;;
409  ptrace-core.lo)	COREFLAG=-DPTRACE_CORE ;;
410  rs6000-core.lo)	COREFLAG="$COREFLAG -DAIX_CORE" ;;
411  sco5-core.lo)		COREFLAG="$COREFLAG -DSCO5_CORE" ;;
412  trad-core.lo)		COREFLAG="$COREFLAG -DTRAD_CORE" ;;
413  esac
414
415  # ELF corefile support has several flavors, but all of
416  # them use something called <sys/procfs.h>
417  AC_CHECK_HEADERS(sys/procfs.h)
418  if test "$ac_cv_header_sys_procfs_h" = yes; then
419    BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
420    BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
421    BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
422    BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
423    BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
424    BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
425    BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
426    BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
427    BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
428    BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
429    BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
430    BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
431    BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
432    BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
433    BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
434    BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
435  fi
436fi
437AC_SUBST(COREFILE)
438AC_SUBST(COREFLAG)
439if test -n "$TRAD_HEADER"; then
440  AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
441    [Name of host specific header file to include in trad-core.c.])
442fi
443
444# Horrible hacks to build DLLs on Windows.
445WIN32LDFLAGS=
446WIN32LIBADD=
447case "${host}" in
448*-*-cygwin*)
449  if test "$enable_shared" = "yes"; then
450    WIN32LDFLAGS="-no-undefined"
451    WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
452  fi
453  ;;
454*-*-linux*)
455  # We borrow WIN32LIBADD so that the shared libbfd won't depend on
456  # libiberty.a.
457  case "${host}" in
458  mips*-*-linux*)
459    # Linux/MIPS uses PIC by default.
460    if test "$enable_shared" = "yes"; then
461      WIN32LIBADD="-L../libiberty -liberty"
462    fi
463    ;;
464  *)
465changequote(,)dnl
466    x=`sed -n -e 's/^[ 	]*PICFLAG[ 	]*=[ 	]*//p' < ../libiberty/Makefile | sed -n '$p'`
467changequote([,])dnl
468    if test -n "$x"; then
469      WIN32LIBADD="-L../libiberty/pic -liberty"
470    fi
471  ;;
472  esac
473  ;;
474esac
475AC_SUBST(WIN32LDFLAGS)
476AC_SUBST(WIN32LIBADD)
477
478# target stuff:
479
480# Canonicalize the secondary target names.
481if test -n "$enable_targets" ; then
482    for targ in `echo $enable_targets | sed 's/,/ /g'`
483    do
484	result=`$ac_config_sub $targ 2>/dev/null`
485	if test -n "$result" ; then
486	    canon_targets="$canon_targets $result"
487	else
488	    # Allow targets that config.sub doesn't recognize, like "all".
489	    canon_targets="$canon_targets $targ"
490	fi
491    done
492fi
493
494all_targets=false
495defvec=
496selvecs=
497assocvecs=
498selarchs=
499TDEFINES=
500for targ in $target $canon_targets
501do
502    if test "x$targ" = "xall"; then
503        all_targets=true
504	assocvecs="$assocvecs $targ_defvec $targ_selvecs"
505    else
506	. $srcdir/config.bfd
507	if test "x$targ" = "x$target"; then
508	    defvec=$targ_defvec
509	fi
510	selvecs="$selvecs $targ_defvec $targ_selvecs"
511	selarchs="$selarchs $targ_archs"
512	TDEFINES="$TDEFINES $targ_cflags"
513    fi
514done
515AC_SUBST(TDEFINES)
516
517# This processing still needs to be done if we're to decide properly whether
518# 64-bit support needs to be compiled in.  Currently, it will be included if
519# the default or any other explicitly requested target requires it; it
520# will not be included on a 32-bit host if no 64-bit target is requested, and
521# no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
522# used.
523
524# uniq the default and selected vectors in all the configured targets.
525f=""
526for i in $selvecs ; do
527    case " $f " in
528    *" $i "*) ;;
529    *) f="$f $i" ;;
530    esac
531done
532selvecs="$f"
533
534
535# uniq the associated vectors in all the configured targets.
536f=""
537for i in $assocvecs ; do
538    case " $f " in
539    *" $i "*) ;;
540    *) f="$f $i" ;;
541    esac
542done
543assocvecs="$f"
544
545
546# uniq the architectures in all the configured targets.
547f=""
548for i in $selarchs ; do
549    case " $f " in
550    *" $i "*) ;;
551    *) f="$f $i" ;;
552    esac
553done
554selarchs="$f"
555
556# Target backend .o files.
557tb=
558
559elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
560
561for vec in $selvecs
562do
563    target_size=32
564    case "$vec" in
565    # This list is alphabetized to make it easy to compare
566    # with the two vector lists in targets.c.  For the same reason,
567    # use one entry per line, even though this leads to long lines.
568    a29kcoff_big_vec)		tb="$tb coff-a29k.lo cofflink.lo" ;;
569    a_out_adobe_vec)		tb="$tb aout-adobe.lo aout32.lo" ;;
570    aix5coff64_vec)		tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
571    aout0_big_vec)		tb="$tb aout0.lo aout32.lo" ;;
572    aout_arm_big_vec)		tb="$tb aout-arm.lo aout32.lo" ;;
573    aout_arm_little_vec)	tb="$tb aout-arm.lo aout32.lo" ;;
574    apollocoff_vec)		tb="$tb coff-apollo.lo" ;;
575    arm_epoc_pe_big_vec)	tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
576    arm_epoc_pe_little_vec)	tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
577    arm_epoc_pei_big_vec)	tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
578    arm_epoc_pei_little_vec)	tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
579    armcoff_big_vec)		tb="$tb coff-arm.lo cofflink.lo " ;;
580    armcoff_little_vec)		tb="$tb coff-arm.lo cofflink.lo " ;;
581    armnetbsd_vec)		tb="$tb armnetbsd.lo aout32.lo" ;;
582    armpe_big_vec)		tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
583    armpe_little_vec)		tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
584    armpei_big_vec)		tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
585    armpei_little_vec)		tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
586    b_out_vec_big_host)		tb="$tb bout.lo aout32.lo" ;;
587    b_out_vec_little_host)	tb="$tb bout.lo aout32.lo" ;;
588    bfd_efi_app_ia32_vec)	tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
589    bfd_efi_app_ia64_vec)	tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
590    bfd_elf32_am33lin_vec)	tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
591    bfd_elf32_avr_vec)		tb="$tb elf32-avr.lo elf32.lo $elf" ;;
592    bfd_elf32_big_generic_vec) 	tb="$tb elf32-gen.lo elf32.lo $elf" ;;
593    bfd_elf32_bigarc_vec)	tb="$tb elf32-arc.lo elf32.lo $elf" ;;
594    bfd_elf32_bigarm_oabi_vec)	tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
595    bfd_elf32_bigarm_vec)	tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
596    bfd_elf32_bigmips_vec) 	tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
597    bfd_elf32_cris_vec)		tb="$tb elf32-cris.lo elf32.lo $elf" ;;
598    bfd_elf32_d10v_vec)		tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
599    bfd_elf32_d30v_vec)		tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
600    bfd_elf32_dlx_big_vec)	tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
601    bfd_elf32_fr30_vec)		tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
602    bfd_elf32_frv_vec)		tb="$tb elf32-frv.lo elf32.lo $elf" ;;
603    bfd_elf32_frvfdpic_vec)	tb="$tb elf32-frv.lo elf32.lo $elf" ;;
604    bfd_elf32_h8300_vec)	tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
605    bfd_elf32_hppa_linux_vec)	tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
606    bfd_elf32_hppa_vec)		tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
607    bfd_elf32_i370_vec)		tb="$tb elf32-i370.lo elf32.lo $elf" ;;
608    bfd_elf32_i386_freebsd_vec)	tb="$tb elf32-i386.lo elf32.lo $elf" ;;
609    bfd_elf32_i386_vec)		tb="$tb elf32-i386.lo elf32.lo $elf" ;;
610    bfd_elf32_i860_little_vec)	tb="$tb elf32-i860.lo elf32.lo $elf" ;;
611    bfd_elf32_i860_vec)		tb="$tb elf32-i860.lo elf32.lo $elf" ;;
612    bfd_elf32_i960_vec)		tb="$tb elf32-i960.lo elf32.lo $elf" ;;
613    bfd_elf32_ia64_big_vec)	tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
614    bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
615    bfd_elf32_ip2k_vec)		tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
616    bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
617    bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
618    bfd_elf32_littlearc_vec)	tb="$tb elf32-arc.lo elf32.lo $elf" ;;
619    bfd_elf32_littlearm_oabi_vec) tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
620    bfd_elf32_littlearm_vec)	tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
621    bfd_elf32_littlemips_vec) 	tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
622    bfd_elf32_m32r_vec)		tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
623    bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
624    bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
625    bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
626    bfd_elf32_zpu_vec)		tb="$tb elf32-zpu.lo elf32.lo $elf" ;;
627    bfd_elf32_m68hc11_vec)	tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
628    bfd_elf32_m68hc12_vec)	tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
629    bfd_elf32_m68k_vec)		tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
630    bfd_elf32_m88k_vec)		tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
631    bfd_elf32_mcore_big_vec)	tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
632    bfd_elf32_mcore_little_vec)	tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
633    bfd_elf32_mn10200_vec)	tb="$tb elf-m10200.lo elf32.lo $elf" ;;
634    bfd_elf32_mn10300_vec)	tb="$tb elf-m10300.lo elf32.lo $elf" ;;
635    bfd_elf32_msp430_vec)	tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
636    bfd_elf32_nbigmips_vec)	tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
637    bfd_elf32_nlittlemips_vec)	tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
638    bfd_elf32_ntradbigmips_vec)	tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
639    bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
640    bfd_elf32_openrisc_vec)	tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
641    bfd_elf32_or32_big_vec)	tb="$tb elf32-or32.lo elf32.lo $elf" ;;
642    bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
643    bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
644    bfd_elf32_powerpc_vec)	tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
645    bfd_elf32_powerpcle_vec)	tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
646    bfd_elf32_s390_vec)		tb="$tb elf32-s390.lo elf32.lo $elf" ;;
647    # FIXME: We include cofflink.lo not because it's needed for
648    # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
649    # which needs it but does not list it.  Should be fixed in right place.
650    bfd_elf32_sh64_vec)		tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
651    bfd_elf32_sh64l_vec)	tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
652    bfd_elf32_sh64lin_vec)	tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
653    bfd_elf32_sh64blin_vec)	tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
654    bfd_elf32_sh64lnbsd_vec)	tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
655    bfd_elf32_sh64nbsd_vec)	tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
656    bfd_elf32_sh_vec)		tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
657    bfd_elf32_shblin_vec)	tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
658    bfd_elf32_shl_vec)		tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
659    bfd_elf32_shlin_vec)	tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
660    bfd_elf32_shlnbsd_vec)	tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
661    bfd_elf32_shnbsd_vec)	tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
662    bfd_elf32_sparc_vec)	tb="$tb elf32-sparc.lo elf32.lo $elf" ;;
663    bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
664    bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
665    bfd_elf32_us_cris_vec)	tb="$tb elf32-cris.lo elf32.lo $elf" ;;
666    bfd_elf32_v850_vec)		tb="$tb elf32-v850.lo elf32.lo $elf" ;;
667    bfd_elf32_vax_vec)		tb="$tb elf32-vax.lo elf32.lo $elf" ;;
668    bfd_elf32_xstormy16_vec)	tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
669    bfd_elf32_xtensa_le_vec)	tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
670    bfd_elf32_xtensa_be_vec)	tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
671    bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
672    bfd_elf64_alpha_vec)	tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
673    bfd_elf64_big_generic_vec) 	tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
674    bfd_elf64_bigmips_vec) 	tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
675    bfd_elf64_hppa_linux_vec)	tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
676    bfd_elf64_hppa_vec)		tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
677    bfd_elf64_ia64_big_vec)	tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
678    bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
679    bfd_elf64_ia64_little_vec)	tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
680    bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
681    bfd_elf64_littlemips_vec) 	tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
682    bfd_elf64_mmix_vec) 	tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
683    bfd_elf64_powerpc_vec)	tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
684    bfd_elf64_powerpcle_vec)	tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
685    bfd_elf64_s390_vec)		tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
686    bfd_elf64_sh64_vec)		tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
687    bfd_elf64_sh64l_vec)	tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
688    bfd_elf64_sh64lin_vec)	tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
689    bfd_elf64_sh64blin_vec)	tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
690    bfd_elf64_sh64lnbsd_vec)	tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
691    bfd_elf64_sh64nbsd_vec)	tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
692    bfd_elf64_sparc_vec)	tb="$tb elf64-sparc.lo elf64.lo $elf"; target_size=64 ;;
693    bfd_elf64_tradbigmips_vec)	tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
694    bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
695    bfd_elf64_x86_64_vec)	tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
696    bfd_mmo_vec)		tb="$tb mmo.lo" target_size=64 ;;
697    bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
698    bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
699    bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
700    bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
701    cris_aout_vec)		tb="$tb aout-cris.lo" ;;
702    demo_64_vec)		tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
703    ecoff_big_vec)		tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
704    ecoff_biglittle_vec)	tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
705    ecoff_little_vec)		tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
706    ecoffalpha_little_vec)	tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
707    go32coff_vec)		tb="$tb coff-go32.lo cofflink.lo" ;;
708    go32stubbedcoff_vec)	tb="$tb coff-stgo32.lo cofflink.lo" ;;
709    h8300coff_vec)		tb="$tb coff-h8300.lo reloc16.lo" ;;
710    h8500coff_vec)		tb="$tb coff-h8500.lo reloc16.lo" ;;
711    host_aout_vec)		tb="$tb host-aout.lo aout32.lo" ;;
712    hp300bsd_vec)		tb="$tb hp300bsd.lo aout32.lo" ;;
713    hp300hpux_vec)		tb="$tb hp300hpux.lo aout32.lo" ;;
714    i386aout_vec)		tb="$tb i386aout.lo aout32.lo" ;;
715    i386bsd_vec)		tb="$tb i386bsd.lo aout32.lo" ;;
716    i386coff_vec)		tb="$tb coff-i386.lo cofflink.lo" ;;
717    i386dynix_vec)		tb="$tb i386dynix.lo aout32.lo" ;;
718    i386freebsd_vec)		tb="$tb i386freebsd.lo aout32.lo" ;;
719    i386linux_vec)		tb="$tb i386linux.lo aout32.lo" ;;
720    i386lynx_aout_vec)		tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
721    i386lynx_coff_vec)		tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
722    i386mach3_vec)		tb="$tb i386mach3.lo aout32.lo" ;;
723    i386msdos_vec)		tb="$tb i386msdos.lo" ;;
724    i386netbsd_vec)		tb="$tb i386netbsd.lo aout32.lo" ;;
725    i386os9k_vec)		tb="$tb i386os9k.lo aout32.lo" ;;
726    i386pe_vec)			tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
727    i386pei_vec)		tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
728    i860coff_vec)		tb="$tb coff-i860.lo cofflink.lo" ;;
729    icoff_big_vec)		tb="$tb coff-i960.lo cofflink.lo" ;;
730    icoff_little_vec)		tb="$tb coff-i960.lo cofflink.lo" ;;
731    ieee_vec)			tb="$tb ieee.lo" ;;
732    m68k4knetbsd_vec)		tb="$tb m68k4knetbsd.lo aout32.lo" ;;
733    m68kaux_coff_vec)		tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
734    m68kcoff_vec)		tb="$tb coff-m68k.lo cofflink.lo" ;;
735    m68kcoffun_vec)		tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
736    m68klinux_vec)		tb="$tb m68klinux.lo aout32.lo" ;;
737    m68klynx_aout_vec)		tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
738    m68klynx_coff_vec)		tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
739    m68knetbsd_vec)		tb="$tb m68knetbsd.lo aout32.lo" ;;
740    m68ksysvcoff_vec)		tb="$tb coff-svm68k.lo cofflink.lo" ;;
741    m88kbcs_vec)		tb="$tb coff-m88k.lo" ;;
742    m88kmach3_vec)		tb="$tb m88kmach3.lo aout32.lo" ;;
743    mach_o_be_vec)              tb="$tb mach-o.lo" ;;
744    mach_o_le_vec)              tb="$tb mach-o.lo" ;;
745    mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
746    mcore_pe_big_vec)		tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
747    mcore_pe_little_vec)	tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
748    mcore_pei_big_vec)		tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
749    mcore_pei_little_vec)	tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
750    mipslpe_vec)		tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
751    mipslpei_vec)		tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
752    newsos3_vec)		tb="$tb newsos3.lo aout32.lo" ;;
753    nlm32_alpha_vec)		tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
754    nlm32_i386_vec)		tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
755    nlm32_powerpc_vec)		tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
756    nlm32_sparc_vec)		tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
757    or32coff_big_vec)		tb="$tb coff-or32.lo cofflink.lo" ;;
758    pc532machaout_vec)		tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
759    pc532netbsd_vec)		tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
760    pef_vec)                    tb="$tb pef.lo" ;;
761    pef_xlib_vec)               tb="$tb pef.lo" ;;
762    pdp11_aout_vec)		tb="$tb pdp11.lo" ;;
763    pmac_xcoff_vec)		tb="$tb coff-rs6000.lo xcofflink.lo" ;;
764    ppcboot_vec)		tb="$tb ppcboot.lo" ;;
765    riscix_vec)			tb="$tb aout32.lo riscix.lo" ;;
766    rs6000coff64_vec)		tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
767    rs6000coff_vec)		tb="$tb coff-rs6000.lo xcofflink.lo" ;;
768    shcoff_small_vec)		tb="$tb coff-sh.lo cofflink.lo" ;;
769    shcoff_vec)			tb="$tb coff-sh.lo cofflink.lo" ;;
770    shlcoff_small_vec)		tb="$tb coff-sh.lo cofflink.lo" ;;
771    shlcoff_vec)		tb="$tb coff-sh.lo cofflink.lo" ;;
772    shlpe_vec)			tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
773    shlpei_vec)			tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
774    som_vec)			tb="$tb som.lo" ;;
775    sparccoff_vec)		tb="$tb coff-sparc.lo" ;;
776    sparcle_aout_vec)		tb="$tb aout-sparcle.lo aout32.lo" ;;
777    sparclinux_vec)		tb="$tb sparclinux.lo aout32.lo" ;;
778    sparclynx_aout_vec)		tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
779    sparclynx_coff_vec)		tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
780    sparcnetbsd_vec)		tb="$tb sparcnetbsd.lo aout32.lo" ;;
781    sunos_big_vec)		tb="$tb sunos.lo aout32.lo" ;;
782    sym_vec)                    tb="$tb xsym.lo" ;;
783    tic30_aout_vec)		tb="$tb aout-tic30.lo" ;;
784    tic30_coff_vec)		tb="$tb coff-tic30.lo" ;;
785    tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
786    tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
787    tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
788    tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
789    tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
790    tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
791    tic54x_coff0_beh_vec)	tb="$tb coff-tic54x.lo" ;;
792    tic54x_coff0_vec)		tb="$tb coff-tic54x.lo" ;;
793    tic54x_coff1_beh_vec)	tb="$tb coff-tic54x.lo" ;;
794    tic54x_coff1_vec)		tb="$tb coff-tic54x.lo" ;;
795    tic54x_coff2_beh_vec)	tb="$tb coff-tic54x.lo" ;;
796    tic54x_coff2_vec)		tb="$tb coff-tic54x.lo" ;;
797    tic80coff_vec)		tb="$tb coff-tic80.lo cofflink.lo" ;;
798    vaxnetbsd_vec)		tb="$tb vaxnetbsd.lo aout32.lo" ;;
799    vax1knetbsd_vec)		tb="$tb vax1knetbsd.lo aout32.lo" ;;
800    vaxbsd_vec)			tb="$tb vaxbsd.lo aout32.lo" ;;
801    versados_vec)		tb="$tb versados.lo" ;;
802    vms_alpha_vec)		tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
803    vms_vax_vec)		tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
804    w65_vec)			tb="$tb coff-w65.lo reloc16.lo" ;;
805    we32kcoff_vec)		tb="$tb coff-we32k.lo" ;;
806    z8kcoff_vec)		tb="$tb coff-z8k.lo reloc16.lo" ;;
807
808    # These appear out of order in targets.c
809    srec_vec)			tb="$tb srec.lo" ;;
810    symbolsrec_vec)		tb="$tb srec.lo" ;;
811    tekhex_vec)			tb="$tb tekhex.lo" ;;
812    cisco_core_big_vec)		tb="$tb cisco-core.lo" ;;
813    cisco_core_little_vec)	tb="$tb cisco-core.lo" ;;
814
815    "")			;;
816    *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
817    esac
818
819    if test ${target_size} = 64; then
820	target64=true
821    fi
822    if test x"${vec}" = x"${defvec}"; then
823	bfd_default_target_size=${target_size}
824    fi
825done
826
827# Target architecture .o files.
828# A couple of CPUs use shorter file names to avoid problems on DOS
829# filesystems.
830ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
831
832# Weed out duplicate .o files.
833f=""
834for i in $tb ; do
835    case " $f " in
836    *" $i "*) ;;
837    *) f="$f $i" ;;
838    esac
839done
840tb="$f"
841
842f=""
843for i in $ta ; do
844    case " $f " in
845    *" $i "*) ;;
846    *) f="$f $i" ;;
847    esac
848done
849ta="$f"
850
851bfd_backends="$tb"
852bfd_machines="$ta"
853
854if test x${all_targets} = xtrue ; then
855  bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
856  bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
857  selvecs=
858  havevecs=
859  selarchs=
860  test -n "$assocvecs" &&
861    assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
862else	# all_targets is true
863  # Only set these if they will be nonempty, for the clever echo.
864  havevecs=
865  assocvecs=
866  test -n "$selvecs" &&
867    havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
868  test -n "$selvecs" &&
869    selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
870  test -n "$selarchs" &&
871    selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
872fi	# all_targets is true
873
874case ${host64}-${target64}-${want64} in
875  *true*)
876    wordsize=64
877    bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
878    all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
879    if test $BFD_HOST_64_BIT_DEFINED = 0; then
880      AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
881      AC_MSG_WARN([your compiler may not have a 64 bit integral type])
882    fi
883    if test -n "$GCC" ; then
884       bad_64bit_gcc=no;
885       AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
886       # Add more tests for gcc versions with non-working 64-bit support here.
887       AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
888		    bad_64bit_gcc=yes;
889		    AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
890		    AC_MSG_RESULT(no))
891       if test $bad_64bit_gcc = yes ; then
892	 AC_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
893       fi
894    fi
895    ;;
896  false-false-false)
897    wordsize=32
898    bfd_libs='$(BFD32_LIBS)'
899    all_backends='$(BFD32_BACKENDS)'
900    ;;
901esac
902
903AC_SUBST(wordsize)
904AC_SUBST(bfd_libs)
905AC_SUBST(all_backends)
906AC_SUBST(bfd_backends)
907AC_SUBST(bfd_machines)
908AC_SUBST(bfd_default_target_size)
909
910# Determine the host dependant file_ptr a.k.a. off_t type.  In order
911# prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
912# fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
913# Hopefully a reasonable assumption since fseeko et.al. should be
914# upward compatible.
915AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64)
916if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
917    AC_COMPILE_CHECK_SIZEOF(off_t)
918fi
919AC_MSG_CHECKING([file_ptr type])
920bfd_file_ptr="long"
921bfd_ufile_ptr="unsigned long"
922if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
923	-o x"${ac_cv_sizeof_off_t}" = x8; then
924    bfd_file_ptr=BFD_HOST_64_BIT
925    bfd_ufile_ptr=BFD_HOST_U_64_BIT
926fi
927AC_MSG_RESULT($bfd_file_ptr)
928AC_SUBST(bfd_file_ptr)
929AC_SUBST(bfd_ufile_ptr)
930
931
932tdefaults=""
933test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
934test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
935test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
936test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
937test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
938AC_SUBST(tdefaults)
939
940dnl AC_CHECK_HEADERS(sys/mman.h)
941AC_FUNC_MMAP
942AC_CHECK_FUNCS(madvise mprotect)
943case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
944  true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
945esac
946
947rm -f doc/config.status
948AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h bfdver.h:version.h po/Makefile.in:po/Make-in,
949[sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile])
950
951