1# The MIT License (MIT)
2#
3# Copyright (c)
4#   2013 Matthew Arsenault
5#   2015-2016 RWTH Aachen University, Federal Republic of Germany
6#
7# Permission is hereby granted, free of charge, to any person obtaining a copy
8# of this software and associated documentation files (the "Software"), to deal
9# in the Software without restriction, including without limitation the rights
10# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
11# copies of the Software, and to permit persons to whom the Software is
12# furnished to do so, subject to the following conditions:
13#
14# The above copyright notice and this permission notice shall be included in all
15# copies or substantial portions of the Software.
16#
17# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
18# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
19# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
20# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
21# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
22# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
23# SOFTWARE.
24
25# Helper function to get the language of a source file.
26function (sanitizer_lang_of_source FILE RETURN_VAR)
27    get_filename_component(LONGEST_EXT "${FILE}" EXT)
28    # Get shortest extension as some files can have dot in their names
29    string(REGEX REPLACE "^.*(\\.[^.]+)$" "\\1" FILE_EXT ${LONGEST_EXT})
30    string(TOLOWER "${FILE_EXT}" FILE_EXT)
31    string(SUBSTRING "${FILE_EXT}" 1 -1 FILE_EXT)
32
33    get_property(ENABLED_LANGUAGES GLOBAL PROPERTY ENABLED_LANGUAGES)
34    foreach (LANG ${ENABLED_LANGUAGES})
35        list(FIND CMAKE_${LANG}_SOURCE_FILE_EXTENSIONS "${FILE_EXT}" TEMP)
36        if (NOT ${TEMP} EQUAL -1)
37            set(${RETURN_VAR} "${LANG}" PARENT_SCOPE)
38            return()
39        endif ()
40    endforeach()
41
42    set(${RETURN_VAR} "" PARENT_SCOPE)
43endfunction ()
44
45
46# Helper function to get compilers used by a target.
47function (sanitizer_target_compilers TARGET RETURN_VAR)
48    # Check if all sources for target use the same compiler. If a target uses
49    # e.g. C and Fortran mixed and uses different compilers (e.g. clang and
50    # gfortran) this can trigger huge problems, because different compilers may
51    # use different implementations for sanitizers.
52    set(BUFFER "")
53    get_target_property(TSOURCES ${TARGET} SOURCES)
54    foreach (FILE ${TSOURCES})
55        # If expression was found, FILE is a generator-expression for an object
56        # library. Object libraries will be ignored.
57        string(REGEX MATCH "TARGET_OBJECTS:([^ >]+)" _file ${FILE})
58        if ("${_file}" STREQUAL "")
59            sanitizer_lang_of_source(${FILE} LANG)
60            if (LANG)
61                list(APPEND BUFFER ${CMAKE_${LANG}_COMPILER_ID})
62            endif ()
63        endif ()
64    endforeach ()
65
66    list(REMOVE_DUPLICATES BUFFER)
67    set(${RETURN_VAR} "${BUFFER}" PARENT_SCOPE)
68endfunction ()
69
70
71# Helper function to check compiler flags for language compiler.
72function (sanitizer_check_compiler_flag FLAG LANG VARIABLE)
73    if (${LANG} STREQUAL "C")
74        include(CheckCCompilerFlag)
75        check_c_compiler_flag("${FLAG}" ${VARIABLE})
76
77    elseif (${LANG} STREQUAL "CXX")
78        include(CheckCXXCompilerFlag)
79        check_cxx_compiler_flag("${FLAG}" ${VARIABLE})
80
81    elseif (${LANG} STREQUAL "Fortran")
82        # CheckFortranCompilerFlag was introduced in CMake 3.x. To be compatible
83        # with older Cmake versions, we will check if this module is present
84        # before we use it. Otherwise we will define Fortran coverage support as
85        # not available.
86        include(CheckFortranCompilerFlag OPTIONAL RESULT_VARIABLE INCLUDED)
87        if (INCLUDED)
88            check_fortran_compiler_flag("${FLAG}" ${VARIABLE})
89        elseif (NOT CMAKE_REQUIRED_QUIET)
90            message(STATUS "Performing Test ${VARIABLE}")
91            message(STATUS "Performing Test ${VARIABLE}"
92                " - Failed (Check not supported)")
93        endif ()
94    endif()
95endfunction ()
96
97
98# Helper function to test compiler flags.
99function (sanitizer_check_compiler_flags FLAG_CANDIDATES NAME PREFIX)
100    set(CMAKE_REQUIRED_QUIET ${${PREFIX}_FIND_QUIETLY})
101
102    get_property(ENABLED_LANGUAGES GLOBAL PROPERTY ENABLED_LANGUAGES)
103    foreach (LANG ${ENABLED_LANGUAGES})
104        # Sanitizer flags are not dependend on language, but the used compiler.
105        # So instead of searching flags foreach language, search flags foreach
106        # compiler used.
107        set(COMPILER ${CMAKE_${LANG}_COMPILER_ID})
108        if (NOT DEFINED ${PREFIX}_${COMPILER}_FLAGS)
109            foreach (FLAG ${FLAG_CANDIDATES})
110                if(NOT CMAKE_REQUIRED_QUIET)
111                    message(STATUS "Try ${COMPILER} ${NAME} flag = [${FLAG}]")
112                endif()
113
114                set(CMAKE_REQUIRED_FLAGS "${FLAG}")
115                unset(${PREFIX}_FLAG_DETECTED CACHE)
116                sanitizer_check_compiler_flag("${FLAG}" ${LANG}
117                    ${PREFIX}_FLAG_DETECTED)
118
119                if (${PREFIX}_FLAG_DETECTED)
120                    # If compiler is a GNU compiler, search for static flag, if
121                    # SANITIZE_LINK_STATIC is enabled.
122                    if (SANITIZE_LINK_STATIC AND (${COMPILER} STREQUAL "GNU"))
123                        string(TOLOWER ${PREFIX} PREFIX_lower)
124                        sanitizer_check_compiler_flag(
125                            "-static-lib${PREFIX_lower}" ${LANG}
126                            ${PREFIX}_STATIC_FLAG_DETECTED)
127
128                        if (${PREFIX}_STATIC_FLAG_DETECTED)
129                            set(FLAG "-static-lib${PREFIX_lower} ${FLAG}")
130                        endif ()
131                    endif ()
132
133                    set(${PREFIX}_${COMPILER}_FLAGS "${FLAG}" CACHE STRING
134                        "${NAME} flags for ${COMPILER} compiler.")
135                    mark_as_advanced(${PREFIX}_${COMPILER}_FLAGS)
136                    break()
137                endif ()
138            endforeach ()
139
140            if (NOT ${PREFIX}_FLAG_DETECTED)
141                set(${PREFIX}_${COMPILER}_FLAGS "" CACHE STRING
142                    "${NAME} flags for ${COMPILER} compiler.")
143                mark_as_advanced(${PREFIX}_${COMPILER}_FLAGS)
144
145                message(WARNING "${NAME} is not available for ${COMPILER} "
146                        "compiler. Targets using this compiler will be "
147                        "compiled without ${NAME}.")
148            endif ()
149        endif ()
150    endforeach ()
151endfunction ()
152
153
154# Helper to assign sanitizer flags for TARGET.
155function (sanitizer_add_flags TARGET NAME PREFIX)
156    # Get list of compilers used by target and check, if sanitizer is available
157    # for this target. Other compiler checks like check for conflicting
158    # compilers will be done in add_sanitizers function.
159    sanitizer_target_compilers(${TARGET} TARGET_COMPILER)
160    list(LENGTH TARGET_COMPILER NUM_COMPILERS)
161    if ("${${PREFIX}_${TARGET_COMPILER}_FLAGS}" STREQUAL "")
162        return()
163    endif()
164
165    # Set compile- and link-flags for target.
166    set_property(TARGET ${TARGET} APPEND_STRING
167        PROPERTY COMPILE_FLAGS " ${${PREFIX}_${TARGET_COMPILER}_FLAGS}")
168    set_property(TARGET ${TARGET} APPEND_STRING
169        PROPERTY COMPILE_FLAGS " ${SanBlist_${TARGET_COMPILER}_FLAGS}")
170    set_property(TARGET ${TARGET} APPEND_STRING
171        PROPERTY LINK_FLAGS " ${${PREFIX}_${TARGET_COMPILER}_FLAGS}")
172endfunction ()
173