1# - try to find Bluez
2#
3# Cache Variables: (probably not for direct use in your scripts)
4#  BLUEZ_INCLUDE_DIR
5#  BLUEZ_LIBRARY
6#
7# Non-cache variables you might use in your CMakeLists.txt:
8#  BLUEZ_FOUND
9#  BLUEZ_INCLUDE_DIRS
10#  BLUEZ_LIBRARIES
11#
12# Requires these CMake modules:
13#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
14#
15# Original Author:
16# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
17# http://academic.cleardefinition.com
18# Iowa State University HCI Graduate Program/VRAC
19#
20# Copyright Iowa State University 2009-2010.
21# Distributed under the Boost Software License, Version 1.0.
22# (See accompanying file LICENSE_1_0.txt or copy at
23# http://www.boost.org/LICENSE_1_0.txt)
24
25if(WIN32 OR APPLE OR NOT UNIX)
26	if(NOT Bluez_FIND_QUIETLY)
27		message(STATUS "Platform not supported by Bluez - skipping search")
28	endif()
29else()
30	set(BLUEZ_ROOT_DIR
31		"${BLUEZ_ROOT_DIR}"
32		CACHE
33		PATH
34		"Directory to search")
35
36	if(CMAKE_SIZEOF_VOID_P MATCHES "8")
37		set(_LIBSUFFIXES lib64 lib)
38	else()
39		set(_LIBSUFFIXES lib)
40	endif()
41
42	find_library(BLUEZ_LIBRARY
43		NAMES
44		bluetooth
45		HINTS
46		"${BLUEZ_ROOT_DIR}"
47		PATH_SUFFIXES
48		"${_LIBSUFFIXES}")
49
50	# Might want to look close to the library first for the includes.
51	get_filename_component(_libdir "${BLUEZ_LIBRARY}" PATH)
52
53	find_path(BLUEZ_INCLUDE_DIR
54		NAMES
55		bluetooth/bluetooth.h
56		HINTS
57		"${_libdir}/.."
58		PATHS
59		"${BLUEZ_ROOT_DIR}"
60		PATH_SUFFIXES
61		include/)
62endif()
63
64include(FindPackageHandleStandardArgs)
65find_package_handle_standard_args(Bluez
66	DEFAULT_MSG
67	BLUEZ_LIBRARY
68	BLUEZ_INCLUDE_DIR)
69
70if(BLUEZ_FOUND)
71	set(BLUEZ_LIBRARIES "${BLUEZ_LIBRARY}")
72	set(BLUEZ_INCLUDE_DIRS "${BLUEZ_INCLUDE_DIR}")
73	mark_as_advanced(BLUEZ_ROOT_DIR)
74endif()
75
76mark_as_advanced(BLUEZ_INCLUDE_DIR
77	BLUEZ_LIBRARY)
78