1# - try to find Arrington Research ViewPoint EyeTracker SDK
2#
3# Cache Variables: (probably not for direct use in your scripts)
4#  VIEWPOINT_INCLUDE_DIR
5#  VIEWPOINT_LIBRARY
6#  VIEWPOINT_RUNTIME_LIBRARY
7#
8# Non-cache variables you might use in your CMakeLists.txt:
9#  VIEWPOINT_FOUND
10#  VIEWPOINT_INCLUDE_DIRS
11#  VIEWPOINT_LIBRARIES
12#  VIEWPOINT_RUNTIME_LIBRARIES - aka the dll for installing
13#  VIEWPOINT_RUNTIME_LIBRARY_DIRS
14#
15# Requires these CMake modules:
16#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
17#
18# Original Author:
19# 2012 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
20# http://academic.cleardefinition.com
21# Iowa State University HCI Graduate Program/VRAC
22#
23# Copyright Iowa State University 2012.
24# Distributed under the Boost Software License, Version 1.0.
25# (See accompanying file LICENSE_1_0.txt or copy at
26# http://www.boost.org/LICENSE_1_0.txt)
27
28set(VIEWPOINT_ROOT_DIR
29	"${VIEWPOINT_ROOT_DIR}"
30	CACHE
31	PATH
32	"Directory to search for Arrington Research ViewPoint EyeTracker SDK")
33
34if(CMAKE_SIZEOF_VOID_P MATCHES "8")
35	set(_LIBSUFFIXES /lib64 /lib)
36else()
37	set(_LIBSUFFIXES /lib)
38endif()
39
40find_library(VIEWPOINT_LIBRARY
41	NAMES
42	VPX_InterApp
43	PATHS
44	"${VIEWPOINT_ROOT_DIR}"
45	PATH_SUFFIXES
46	"${_LIBSUFFIXES}")
47
48get_filename_component(_libdir "${VIEWPOINT_LIBRARY}" PATH)
49
50find_path(VIEWPOINT_INCLUDE_DIR
51	NAMES
52	vpx.h
53	HINTS
54	"${_libdir}"
55	PATHS
56	"${VIEWPOINT_ROOT_DIR}"
57	PATH_SUFFIXES
58	include/)
59
60set(_deps_check)
61if(WIN32)
62	find_file(VIEWPOINT_RUNTIME_LIBRARY
63		NAMES
64		VPX_InterApp.dll
65		HINTS
66		"${_libdir}")
67
68	set(VIEWPOINT_RUNTIME_LIBRARIES "${VIEWPOINT_RUNTIME_LIBRARY}")
69	get_filename_component(VIEWPOINT_RUNTIME_LIBRARY_DIRS
70		"${VIEWPOINT_RUNTIME_LIBRARY}"
71		PATH)
72	list(APPEND _deps_check VIEWPOINT_RUNTIME_LIBRARY)
73else()
74	get_filename_component(VIEWPOINT_RUNTIME_LIBRARY_DIRS
75		"${VIEWPOINT_LIBRARY}"
76		PATH)
77endif()
78
79include(FindPackageHandleStandardArgs)
80find_package_handle_standard_args(ViewPoint
81	DEFAULT_MSG
82	VIEWPOINT_LIBRARY
83	VIEWPOINT_INCLUDE_DIR
84	${_deps_check})
85
86if(VIEWPOINT_FOUND)
87	set(VIEWPOINT_LIBRARIES "${VIEWPOINT_LIBRARY}")
88	set(VIEWPOINT_INCLUDE_DIRS "${VIEWPOINT_INCLUDE_DIR}")
89	mark_as_advanced(VIEWPOINT_ROOT_DIR)
90endif()
91
92mark_as_advanced(VIEWPOINT_INCLUDE_DIR
93	VIEWPOINT_LIBRARY
94	VIEWPOINT_RUNTIME_LIBRARY)
95