1# - try to find the Wii SCAAT library
2#
3# Users may optionally supply:
4#  WIISCAAT_ROOT_DIR - a prefix to start searching for the headers.
5#
6# Cache Variables: (probably not for direct use in your scripts)
7#  WIISCAAT_INCLUDE_DIR
8#  WIISCAAT_LIBRARY
9#
10# Non-cache variables you might use in your CMakeLists.txt:
11#  WIISCAAT_FOUND
12#  WIISCAAT_INCLUDE_DIRS
13#  WIISCAAT_LIBRARIES
14#
15# Requires these CMake modules:
16#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
17#
18# Original Author:
19# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
20# http://academic.cleardefinition.com
21# Iowa State University HCI Graduate Program/VRAC
22#
23# Copyright Iowa State University 2009-2010.
24# Distributed under the Boost Software License, Version 1.0.
25# (See accompanying file LICENSE_1_0.txt or copy at
26# http://www.boost.org/LICENSE_1_0.txt)
27
28set(WIISCAAT_ROOT_DIR
29	"${WIISCAAT_ROOT_DIR}"
30	CACHE
31	PATH
32	"Path to search for Wii SCAAT module")
33
34###
35# Prereq: tag
36###
37if(NOT TOONTAG_ROOT_DIR)
38	set(TOONTAG_ROOT_DIR "${WIISCAAT_ROOT_DIR}")
39endif()
40find_package(TooNtag QUIET)
41
42###
43# Configure tag
44###
45find_path(WIISCAAT_INCLUDE_DIR
46	NAMES
47	HeadCollection.h
48	HINTS
49	"${WIISCAAT_ROOT_DIR}"
50	PATH_SUFFIXES
51	include)
52mark_as_advanced(WIISCAAT_INCLUDE_DIR)
53
54find_library(WIISCAAT_LIBRARY
55	NAMES
56	wiiscaattracker
57	HINTS
58	"${WIISCAAT_ROOT_DIR}"
59	PATH_SUFFIXES
60	lib
61	lib64)
62mark_as_advanced(WIISCAAT_LIBRARY)
63
64# handle the QUIETLY and REQUIRED arguments and set xxx_FOUND to TRUE if
65# all listed variables are TRUE
66include(FindPackageHandleStandardArgs)
67find_package_handle_standard_args(WiiSCAAT
68	DEFAULT_MSG
69	WIISCAAT_LIBRARY
70	WIISCAAT_INCLUDE_DIR
71	TOONTAG_FOUND)
72
73if(WIISCAAT_FOUND)
74	set(WIISCAAT_INCLUDE_DIRS
75		"${WIISCAAT_INCLUDE_DIR}"
76		${TOONTAG_INCLUDE_DIRS})
77	set(WIISCAAT_LIBRARIES "${WIISCAAT_LIBRARY}" ${TOONTAG_LIBRARIES})
78	mark_as_advanced(WIISCAAT_ROOT_DIR)
79endif()
80