1m4_define([libart_major_version], [2])
2m4_define([libart_minor_version], [3])
3m4_define([libart_micro_version], [21])
4m4_define([libart_version],
5          [libart_major_version.libart_minor_version.libart_micro_version])
6
7AC_INIT([libart-lgpl],[libart_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=libart],[libart_lgpl])
8
9AC_CONFIG_HEADERS([config.h])
10
11LIBART_MAJOR_VERSION=libart_major_version
12LIBART_MINOR_VERSION=libart_minor_version
13LIBART_MICRO_VERSION=libart_micro_version
14LIBART_VERSION=libart_version
15
16LIBART_VERSION_INFO=`expr $LIBART_MAJOR_VERSION + $LIBART_MINOR_VERSION`:$LIBART_MICRO_VERSION:$LIBART_MINOR_VERSION
17
18AC_SUBST(LIBART_MAJOR_VERSION)
19AC_SUBST(LIBART_MINOR_VERSION)
20AC_SUBST(LIBART_MICRO_VERSION)
21AC_SUBST(LIBART_VERSION)
22AC_SUBST(LIBART_VERSION_INFO)
23
24AM_INIT_AUTOMAKE([1.9 foreign no-dist-gzip dist-bzip2])
25
26AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
27		    , enable_ansi=no)
28
29AC_PROG_CC
30AC_PROG_CPP
31AC_LIBTOOL_WIN32_DLL
32AM_PROG_LIBTOOL
33
34AM_MAINTAINER_MODE
35
36AC_MSG_CHECKING([for some Win32 platform])
37case "$host" in
38  *-*-mingw*|*-*-cygwin*)
39    platform_win32=yes
40    ;;
41  *)
42    platform_win32=no
43    ;;
44esac
45AC_MSG_RESULT([$platform_win32])
46AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
47
48AC_MSG_CHECKING([for native Win32])
49case "$host" in
50  *-*-mingw*)
51    os_win32=yes
52    ;;
53  *)
54    os_win32=no
55    ;;
56esac
57AC_MSG_RESULT([$os_win32])
58AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
59
60if test "$os_win32" = "yes"; then
61  AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
62fi
63AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
64
65changequote(,)dnl
66if test "x$GCC" = "xyes"; then
67  case " $CFLAGS " in
68  *[\ \	]-Wall[\ \	]*) ;;
69  *) CFLAGS="$CFLAGS -Wall" ;;
70  esac
71
72  case " $CFLAGS " in
73  *[\ \	]-Wmissing-prototypes[\ \	]*) ;;
74  *) CFLAGS="$CFLAGS -Wmissing-prototypes" ;;
75  esac
76
77  if test "x$enable_ansi" = "xyes"; then
78    case " $CFLAGS " in
79    *[\ \	]-ansi[\ \	]*) ;;
80    *) CFLAGS="$CFLAGS -ansi" ;;
81    esac
82
83    case " $CFLAGS " in
84    *[\ \	]-pedantic[\ \	]*) ;;
85    *) CFLAGS="$CFLAGS -pedantic" ;;
86    esac
87  fi
88fi
89changequote([,])dnl
90
91AC_FUNC_ALLOCA
92
93AC_C_BIGENDIAN
94
95AC_CHECK_SIZEOF(char)
96AC_SUBST(ART_SIZEOF_CHAR, $ac_cv_sizeof_char)
97AC_CHECK_SIZEOF(short)
98AC_SUBST(ART_SIZEOF_SHORT, $ac_cv_sizeof_short)
99AC_CHECK_SIZEOF(int)
100AC_SUBST(ART_SIZEOF_INT, $ac_cv_sizeof_int)
101AC_CHECK_SIZEOF(long)
102AC_SUBST(ART_SIZEOF_LONG, $ac_cv_sizeof_long)
103
104AC_CONFIG_FILES([
105libart-features.h
106Makefile
107libart-2.0.pc
108libart-2.0-uninstalled.pc
109libart-zip])
110
111AC_CONFIG_FILES([libart-config],[chmod +x libart-config])
112AC_CONFIG_FILES([gen_art_config.sh],[chmod +x gen_art_config.sh])
113
114AC_OUTPUT
115