1%%
2%% %CopyrightBegin%
3%%
4%% Copyright Ericsson AB 2012-2017. All Rights Reserved.
5%%
6%% Licensed under the Apache License, Version 2.0 (the "License");
7%% you may not use this file except in compliance with the License.
8%% You may obtain a copy of the License at
9%%
10%%     http://www.apache.org/licenses/LICENSE-2.0
11%%
12%% Unless required by applicable law or agreed to in writing, software
13%% distributed under the License is distributed on an "AS IS" BASIS,
14%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
15%% See the License for the specific language governing permissions and
16%% limitations under the License.
17%%
18%% %CopyrightEnd%
19%%
20%%
21
22-module(asn1ct_func).
23-export([start_link/0,need/1,call/3,call_gen/3,call_gen/4,
24	 generate/1,is_used/1]).
25-export([init/1,handle_call/3,handle_cast/2,terminate/2]).
26
27start_link() ->
28    {ok,Pid} = gen_server:start_link(?MODULE, [], []),
29    put(?MODULE, Pid),
30    ok.
31
32call(M, F, Args) ->
33    A = length(Args),
34    MFA = {M,F,A},
35    need(MFA),
36    case M of
37	binary ->
38	    asn1ct_gen:emit(["binary:",F,"(",call_args(Args, ""),")"]);
39	_ ->
40	    asn1ct_gen:emit([F,"(",call_args(Args, ""),")"])
41    end.
42
43need({binary,_,_}) ->
44    ok;
45need({erlang,_,_}) ->
46    ok;
47need(MFA) ->
48    asn1ct_rtt:assert_defined(MFA),
49    cast({need,MFA}).
50
51call_gen(Prefix, Key, Gen, Args) when is_function(Gen, 2) ->
52    F = req({gen_func,Prefix,Key,Gen}),
53    asn1ct_gen:emit([{asis,F},"(",call_args(Args, ""),")"]).
54
55call_gen(Prefix, Key, Gen) when is_function(Gen, 2) ->
56    req({gen_func,Prefix,Key,Gen}).
57
58generate(Fd) ->
59    do_generate(Fd),
60    Used0 = req(get_used),
61    erase(?MODULE),
62    Used = sofs:set(Used0, [mfa]),
63    Code = sofs:relation(asn1ct_rtt:code(), [{mfa,code}]),
64    Funcs0 = sofs:image(Code, Used),
65    Funcs = sofs:to_external(Funcs0),
66    ok = file:write(Fd, Funcs).
67
68is_used({M,F,A}=MFA) when is_atom(M), is_atom(F), is_integer(A) ->
69    req({is_used,MFA}).
70
71
72req(Req) ->
73    gen_server:call(get(?MODULE), Req, infinity).
74
75cast(Req) ->
76    gen_server:cast(get(?MODULE), Req).
77
78%%% Internal functions.
79
80-record(st, {used,				%Used functions
81	     gen,				%Dynamically generated functions
82	     gc=1				%Counter for generated functions
83	    }).
84
85init([]) ->
86    St = #st{used=gb_sets:empty(),gen=gb_trees:empty()},
87    {ok,St}.
88
89handle_cast({need,MFA}, #st{used=Used0}=St) ->
90    case gb_sets:is_member(MFA, Used0) of
91	false ->
92	    Used = pull_in_deps(gb_sets:singleton(MFA), Used0),
93	    {noreply,St#st{used=Used}};
94	true ->
95	    {noreply,St}
96    end.
97
98handle_call(get_used, _From, #st{used=Used}=St) ->
99    {stop,normal,gb_sets:to_list(Used),St};
100handle_call(get_gen, _From, #st{gen=G0}=St) ->
101    {L,G} = do_get_gen(gb_trees:to_list(G0), [], []),
102    {reply,L,St#st{gen=gb_trees:from_orddict(G)}};
103handle_call({gen_func,Prefix,Key,GenFun}, _From, #st{gen=G0,gc=Gc0}=St) ->
104    case gb_trees:lookup(Key, G0) of
105	none ->
106	    Name = list_to_atom(Prefix ++ integer_to_list(Gc0)),
107	    Gc = Gc0 + 1,
108	    G = gb_trees:insert(Key, {Name,GenFun}, G0),
109	    {reply,Name,St#st{gen=G,gc=Gc}};
110	{value,{Name,_}} ->
111	    {reply,Name,St}
112    end;
113handle_call({is_used,MFA}, _From, #st{used=Used}=St) ->
114    {reply,gb_sets:is_member(MFA, Used),St}.
115
116
117terminate(_, _) ->
118    ok.
119
120call_args([A|As], Sep) ->
121    [Sep,A|call_args(As, ", ")];
122call_args([], _) -> [].
123
124pull_in_deps(Ws0, Used0) ->
125    case gb_sets:is_empty(Ws0) of
126	true ->
127	    Used0;
128	false ->
129	    {MFA,Ws1} = gb_sets:take_smallest(Ws0),
130	    Used = gb_sets:add(MFA, Used0),
131	    Needs = asn1ct_rtt:dependencies(MFA),
132	    Ws = update_worklist(Needs, Used, Ws1),
133	    pull_in_deps(Ws, Used)
134    end.
135
136update_worklist([H|T], Used, Ws) ->
137    case gb_sets:is_member(H, Used) of
138	false ->
139	    update_worklist(T, Used, gb_sets:add(H, Ws));
140	true ->
141	    update_worklist(T, Used, Ws)
142    end;
143update_worklist([], _, Ws) -> Ws.
144
145do_get_gen([{_,{_,done}}=Keep|T], Gacc, Kacc) ->
146    do_get_gen(T, Gacc, [Keep|Kacc]);
147do_get_gen([{K,{Name,_}=V}|T], Gacc, Kacc) ->
148    do_get_gen(T, [V|Gacc], [{K,{Name,done}}|Kacc]);
149do_get_gen([], Gacc, Kacc) ->
150    {lists:sort(Gacc),lists:reverse(Kacc)}.
151
152do_generate(Fd) ->
153    case req(get_gen) of
154	[] ->
155	    ok;
156	[_|_]=Gen ->
157	    _ = [begin
158		     ok = file:write(Fd, "\n"),
159		     GenFun(Fd, Name)
160		 end || {Name,GenFun} <- Gen],
161	    do_generate(Fd)
162    end.
163