1# -*- Mode: Asm -*-
2#
3# This Source Code Form is subject to the terms of the Mozilla Public
4# License, v. 2.0. If a copy of the MPL was not distributed with this
5# file, You can obtain one at http://mozilla.org/MPL/2.0/.
6
7.set r0,0; .set sp,1; .set RTOC,2; .set r3,3; .set r4,4
8.set r5,5; .set r6,6; .set r7,7; .set r8,8; .set r9,9
9.set r10,10; .set r11,11; .set r12,12; .set r13,13; .set r14,14
10.set r15,15; .set r16,16; .set r17,17; .set r18,18; .set r19,19
11.set r20,20; .set r21,21; .set r22,22; .set r23,23; .set r24,24
12.set r25,25; .set r26,26; .set r27,27; .set r28,28; .set r29,29
13.set r30,30; .set r31,31
14.set f0,0; .set f1,1; .set f2,2; .set f3,3; .set f4,4
15.set f5,5; .set f6,6; .set f7,7; .set f8,8; .set f9,9
16.set f10,10; .set f11,11; .set f12,12; .set f13,13; .set f14,14
17.set f15,15; .set f16,16; .set f17,17; .set f18,18; .set f19,19
18.set f20,20; .set f21,21; .set f22,22; .set f23,23; .set f24,24
19.set f25,25; .set f26,26; .set f27,27; .set f28,28; .set f29,29
20.set f30,30; .set f31,31
21
22        .section ".text"
23        .align 2
24	.globl SharedStub
25	.type  SharedStub,@function
26
27SharedStub:
28        stwu	sp,-112(sp)			# room for
29						# linkage (8),
30						# gprData (32),
31						# fprData (64),
32						# stack alignment(8)
33        mflr	r0
34	stw	r0,116(sp)			# save LR backchain
35
36	stw	r4,12(sp)			# save GP registers
37	stw	r5,16(sp)			# (n.b. that we don't save r3
38	stw	r6,20(sp)			# because PrepareAndDispatch() is savvy)
39	stw	r7,24(sp)
40	stw	r8,28(sp)
41	stw	r9,32(sp)
42	stw	r10,36(sp)
43
44	stfd	f1,40(sp)			# save FP registers
45	stfd	f2,48(sp)
46	stfd	f3,56(sp)
47	stfd	f4,64(sp)
48	stfd	f5,72(sp)
49	stfd	f6,80(sp)
50	stfd	f7,88(sp)
51	stfd	f8,96(sp)
52
53						# r3 has the 'self' pointer already
54
55	mr      r4,r11				# r4 <= methodIndex selector, passed
56						# via r11 in the nsXPTCStubBase::StubXX() call
57
58	addi	r5,sp,120			# r5 <= pointer to callers args area,
59						# beyond r3-r10/f1-f8 mapped range
60
61	addi	r6,sp,8				# r6 <= gprData
62	addi	r7,sp,40			# r7 <= fprData
63
64	bl	PrepareAndDispatch@local	# Go!
65
66	lwz	r0,116(sp)			# restore LR
67	mtlr	r0
68	la	sp,112(sp)			# clean up the stack
69	blr
70
71