1# Copyright 2013 The Chromium Authors. All rights reserved.
2# Use of this source code is governed by a BSD-style license that can be
3# found in the LICENSE file.
4
5import("//build/config/clang/clang.gni")
6import("//build/config/sysroot.gni")  # Imports android/config.gni.
7import("//build/toolchain/gcc_toolchain.gni")
8
9# The Android GCC toolchains share most of the same parameters, so we have this
10# wrapper around gcc_toolchain to avoid duplication of logic.
11#
12# Parameters:
13#  - toolchain_root
14#      Path to cpu-specific toolchain within the ndk.
15#  - sysroot
16#      Sysroot for this architecture.
17#  - lib_dir
18#      Subdirectory inside of sysroot where libs go.
19#  - binary_prefix
20#      Prefix of compiler executables.
21template("android_gcc_toolchain") {
22  gcc_toolchain(target_name) {
23    assert(defined(invoker.toolchain_args),
24           "toolchain_args must be defined for android_gcc_toolchain()")
25    toolchain_args = invoker.toolchain_args
26    toolchain_args.current_os = "android"
27
28    # Output linker map files for binary size analysis.
29    enable_linker_map = true
30
31    # Make our manually injected libs relative to the build dir.
32    _ndk_lib =
33        rebase_path(invoker.sysroot + "/" + invoker.lib_dir, root_build_dir)
34
35    libs_section_prefix = "$_ndk_lib/crtbegin_dynamic.o"
36    libs_section_postfix = "$_ndk_lib/crtend_android.o"
37
38    solink_libs_section_prefix = "$_ndk_lib/crtbegin_so.o"
39    solink_libs_section_postfix = "$_ndk_lib/crtend_so.o"
40
41    _android_tool_prefix =
42        "${invoker.toolchain_root}/bin/${invoker.binary_prefix}-"
43
44    # The tools should be run relative to the build dir.
45    _tool_prefix = rebase_path("$_android_tool_prefix", root_build_dir)
46
47    # Use the clang specified by the toolchain if there is one. Otherwise fall
48    # back to the global flag.
49    if (defined(toolchain_args.is_clang)) {
50      toolchain_uses_clang = toolchain_args.is_clang
51    } else {
52      toolchain_uses_clang = is_clang
53    }
54
55    if (toolchain_uses_clang) {
56      _prefix = rebase_path("$clang_base_path/bin", root_build_dir)
57      cc = "$_prefix/clang"
58      cxx = "$_prefix/clang++"
59    } else {
60      cc = "${_tool_prefix}gcc"
61      cxx = "${_tool_prefix}g++"
62    }
63    ar = _tool_prefix + "ar"
64    ld = cxx
65    readelf = _tool_prefix + "readelf"
66    nm = _tool_prefix + "nm"
67    strip = "${_tool_prefix}strip"
68
69    # Don't use .cr.so for loadable_modules since they are always loaded via
70    # absolute path.
71    loadable_module_extension = ".so"
72  }
73}
74
75template("android_gcc_toolchains_helper") {
76  android_gcc_toolchain("android_$target_name") {
77    forward_variables_from(invoker, "*")
78    toolchain_args.is_clang = false
79  }
80
81  android_gcc_toolchain("android_clang_$target_name") {
82    forward_variables_from(invoker, "*")
83    toolchain_args.is_clang = true
84  }
85}
86
87android_gcc_toolchains_helper("x86") {
88  toolchain_root = x86_android_toolchain_root
89  sysroot = "$android_ndk_root/$x86_android_sysroot_subdir"
90  lib_dir = "usr/lib"
91  binary_prefix = "i686-linux-android"
92  toolchain_args = {
93    current_cpu = "x86"
94  }
95}
96
97android_gcc_toolchains_helper("arm") {
98  toolchain_root = arm_android_toolchain_root
99  sysroot = "$android_ndk_root/$arm_android_sysroot_subdir"
100  lib_dir = "usr/lib"
101  binary_prefix = "arm-linux-androideabi"
102  toolchain_args = {
103    current_cpu = "arm"
104  }
105}
106
107android_gcc_toolchains_helper("mipsel") {
108  toolchain_root = mips_android_toolchain_root
109  sysroot = "$android_ndk_root/$mips_android_sysroot_subdir"
110  lib_dir = "usr/lib"
111  binary_prefix = "mipsel-linux-android"
112  toolchain_args = {
113    current_cpu = "mipsel"
114  }
115}
116
117android_gcc_toolchains_helper("x64") {
118  toolchain_root = x86_64_android_toolchain_root
119  sysroot = "$android_ndk_root/$x86_64_android_sysroot_subdir"
120  lib_dir = "usr/lib64"
121  binary_prefix = "x86_64-linux-android"
122  toolchain_args = {
123    current_cpu = "x64"
124  }
125}
126
127android_gcc_toolchains_helper("arm64") {
128  toolchain_root = arm64_android_toolchain_root
129  sysroot = "$android_ndk_root/$arm64_android_sysroot_subdir"
130  lib_dir = "usr/lib"
131  binary_prefix = "aarch64-linux-android"
132  toolchain_args = {
133    current_cpu = "arm64"
134  }
135}
136
137android_gcc_toolchains_helper("mips64el") {
138  toolchain_root = mips64_android_toolchain_root
139  sysroot = "$android_ndk_root/$mips64_android_sysroot_subdir"
140  lib_dir = "usr/lib64"
141  binary_prefix = "mips64el-linux-android"
142  toolchain_args = {
143    current_cpu = "mips64el"
144  }
145}
146