1*> \brief \b SCHKQL
2*
3*  =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6*            http://www.netlib.org/lapack/explore-html/
7*
8*  Definition:
9*  ===========
10*
11*       SUBROUTINE SCHKQL( DOTYPE, NM, MVAL, NN, NVAL, NNB, NBVAL, NXVAL,
12*                          NRHS, THRESH, TSTERR, NMAX, A, AF, AQ, AL, AC,
13*                          B, X, XACT, TAU, WORK, RWORK, NOUT )
14*
15*       .. Scalar Arguments ..
16*       LOGICAL            TSTERR
17*       INTEGER            NM, NMAX, NN, NNB, NOUT, NRHS
18*       REAL               THRESH
19*       ..
20*       .. Array Arguments ..
21*       LOGICAL            DOTYPE( * )
22*       INTEGER            MVAL( * ), NBVAL( * ), NVAL( * ),
23*      $                   NXVAL( * )
24*       REAL               A( * ), AC( * ), AF( * ), AL( * ), AQ( * ),
25*      $                   B( * ), RWORK( * ), TAU( * ), WORK( * ),
26*      $                   X( * ), XACT( * )
27*       ..
28*
29*
30*> \par Purpose:
31*  =============
32*>
33*> \verbatim
34*>
35*> SCHKQL tests SGEQLF, SORGQL and SORMQL.
36*> \endverbatim
37*
38*  Arguments:
39*  ==========
40*
41*> \param[in] DOTYPE
42*> \verbatim
43*>          DOTYPE is LOGICAL array, dimension (NTYPES)
44*>          The matrix types to be used for testing.  Matrices of type j
45*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
46*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
47*> \endverbatim
48*>
49*> \param[in] NM
50*> \verbatim
51*>          NM is INTEGER
52*>          The number of values of M contained in the vector MVAL.
53*> \endverbatim
54*>
55*> \param[in] MVAL
56*> \verbatim
57*>          MVAL is INTEGER array, dimension (NM)
58*>          The values of the matrix row dimension M.
59*> \endverbatim
60*>
61*> \param[in] NN
62*> \verbatim
63*>          NN is INTEGER
64*>          The number of values of N contained in the vector NVAL.
65*> \endverbatim
66*>
67*> \param[in] NVAL
68*> \verbatim
69*>          NVAL is INTEGER array, dimension (NN)
70*>          The values of the matrix column dimension N.
71*> \endverbatim
72*>
73*> \param[in] NNB
74*> \verbatim
75*>          NNB is INTEGER
76*>          The number of values of NB and NX contained in the
77*>          vectors NBVAL and NXVAL.  The blocking parameters are used
78*>          in pairs (NB,NX).
79*> \endverbatim
80*>
81*> \param[in] NBVAL
82*> \verbatim
83*>          NBVAL is INTEGER array, dimension (NNB)
84*>          The values of the blocksize NB.
85*> \endverbatim
86*>
87*> \param[in] NXVAL
88*> \verbatim
89*>          NXVAL is INTEGER array, dimension (NNB)
90*>          The values of the crossover point NX.
91*> \endverbatim
92*>
93*> \param[in] NRHS
94*> \verbatim
95*>          NRHS is INTEGER
96*>          The number of right hand side vectors to be generated for
97*>          each linear system.
98*> \endverbatim
99*>
100*> \param[in] THRESH
101*> \verbatim
102*>          THRESH is REAL
103*>          The threshold value for the test ratios.  A result is
104*>          included in the output file if RESULT >= THRESH.  To have
105*>          every test ratio printed, use THRESH = 0.
106*> \endverbatim
107*>
108*> \param[in] TSTERR
109*> \verbatim
110*>          TSTERR is LOGICAL
111*>          Flag that indicates whether error exits are to be tested.
112*> \endverbatim
113*>
114*> \param[in] NMAX
115*> \verbatim
116*>          NMAX is INTEGER
117*>          The maximum value permitted for M or N, used in dimensioning
118*>          the work arrays.
119*> \endverbatim
120*>
121*> \param[out] A
122*> \verbatim
123*>          A is REAL array, dimension (NMAX*NMAX)
124*> \endverbatim
125*>
126*> \param[out] AF
127*> \verbatim
128*>          AF is REAL array, dimension (NMAX*NMAX)
129*> \endverbatim
130*>
131*> \param[out] AQ
132*> \verbatim
133*>          AQ is REAL array, dimension (NMAX*NMAX)
134*> \endverbatim
135*>
136*> \param[out] AL
137*> \verbatim
138*>          AL is REAL array, dimension (NMAX*NMAX)
139*> \endverbatim
140*>
141*> \param[out] AC
142*> \verbatim
143*>          AC is REAL array, dimension (NMAX*NMAX)
144*> \endverbatim
145*>
146*> \param[out] B
147*> \verbatim
148*>          B is REAL array, dimension (NMAX*NRHS)
149*> \endverbatim
150*>
151*> \param[out] X
152*> \verbatim
153*>          X is REAL array, dimension (NMAX*NRHS)
154*> \endverbatim
155*>
156*> \param[out] XACT
157*> \verbatim
158*>          XACT is REAL array, dimension (NMAX*NRHS)
159*> \endverbatim
160*>
161*> \param[out] TAU
162*> \verbatim
163*>          TAU is REAL array, dimension (NMAX)
164*> \endverbatim
165*>
166*> \param[out] WORK
167*> \verbatim
168*>          WORK is REAL array, dimension (NMAX*NMAX)
169*> \endverbatim
170*>
171*> \param[out] RWORK
172*> \verbatim
173*>          RWORK is REAL array, dimension (NMAX)
174*> \endverbatim
175*>
176*> \param[in] NOUT
177*> \verbatim
178*>          NOUT is INTEGER
179*>          The unit number for output.
180*> \endverbatim
181*
182*  Authors:
183*  ========
184*
185*> \author Univ. of Tennessee
186*> \author Univ. of California Berkeley
187*> \author Univ. of Colorado Denver
188*> \author NAG Ltd.
189*
190*> \ingroup single_lin
191*
192*  =====================================================================
193      SUBROUTINE SCHKQL( DOTYPE, NM, MVAL, NN, NVAL, NNB, NBVAL, NXVAL,
194     $                   NRHS, THRESH, TSTERR, NMAX, A, AF, AQ, AL, AC,
195     $                   B, X, XACT, TAU, WORK, RWORK, NOUT )
196*
197*  -- LAPACK test routine --
198*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
199*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
200*
201*     .. Scalar Arguments ..
202      LOGICAL            TSTERR
203      INTEGER            NM, NMAX, NN, NNB, NOUT, NRHS
204      REAL               THRESH
205*     ..
206*     .. Array Arguments ..
207      LOGICAL            DOTYPE( * )
208      INTEGER            MVAL( * ), NBVAL( * ), NVAL( * ),
209     $                   NXVAL( * )
210      REAL               A( * ), AC( * ), AF( * ), AL( * ), AQ( * ),
211     $                   B( * ), RWORK( * ), TAU( * ), WORK( * ),
212     $                   X( * ), XACT( * )
213*     ..
214*
215*  =====================================================================
216*
217*     .. Parameters ..
218      INTEGER            NTESTS
219      PARAMETER          ( NTESTS = 7 )
220      INTEGER            NTYPES
221      PARAMETER          ( NTYPES = 8 )
222      REAL               ZERO
223      PARAMETER          ( ZERO = 0.0E0 )
224*     ..
225*     .. Local Scalars ..
226      CHARACTER          DIST, TYPE
227      CHARACTER*3        PATH
228      INTEGER            I, IK, IM, IMAT, IN, INB, INFO, K, KL, KU, LDA,
229     $                   LWORK, M, MINMN, MODE, N, NB, NERRS, NFAIL, NK,
230     $                   NRUN, NT, NX
231      REAL               ANORM, CNDNUM
232*     ..
233*     .. Local Arrays ..
234      INTEGER            ISEED( 4 ), ISEEDY( 4 ), KVAL( 4 )
235      REAL               RESULT( NTESTS )
236*     ..
237*     .. External Subroutines ..
238      EXTERNAL           ALAERH, ALAHD, ALASUM, SERRQL, SGEQLS, SGET02,
239     $                   SLACPY, SLARHS, SLATB4, SLATMS, SQLT01, SQLT02,
240     $                   SQLT03, XLAENV
241*     ..
242*     .. Intrinsic Functions ..
243      INTRINSIC          MAX, MIN
244*     ..
245*     .. Scalars in Common ..
246      LOGICAL            LERR, OK
247      CHARACTER*32       SRNAMT
248      INTEGER            INFOT, NUNIT
249*     ..
250*     .. Common blocks ..
251      COMMON             / INFOC / INFOT, NUNIT, OK, LERR
252      COMMON             / SRNAMC / SRNAMT
253*     ..
254*     .. Data statements ..
255      DATA               ISEEDY / 1988, 1989, 1990, 1991 /
256*     ..
257*     .. Executable Statements ..
258*
259*     Initialize constants and the random number seed.
260*
261      PATH( 1: 1 ) = 'Single precision'
262      PATH( 2: 3 ) = 'QL'
263      NRUN = 0
264      NFAIL = 0
265      NERRS = 0
266      DO 10 I = 1, 4
267         ISEED( I ) = ISEEDY( I )
268   10 CONTINUE
269*
270*     Test the error exits
271*
272      IF( TSTERR )
273     $   CALL SERRQL( PATH, NOUT )
274      INFOT = 0
275      CALL XLAENV( 2, 2 )
276*
277      LDA = NMAX
278      LWORK = NMAX*MAX( NMAX, NRHS )
279*
280*     Do for each value of M in MVAL.
281*
282      DO 70 IM = 1, NM
283         M = MVAL( IM )
284*
285*        Do for each value of N in NVAL.
286*
287         DO 60 IN = 1, NN
288            N = NVAL( IN )
289            MINMN = MIN( M, N )
290            DO 50 IMAT = 1, NTYPES
291*
292*              Do the tests only if DOTYPE( IMAT ) is true.
293*
294               IF( .NOT.DOTYPE( IMAT ) )
295     $            GO TO 50
296*
297*              Set up parameters with SLATB4 and generate a test matrix
298*              with SLATMS.
299*
300               CALL SLATB4( PATH, IMAT, M, N, TYPE, KL, KU, ANORM, MODE,
301     $                      CNDNUM, DIST )
302*
303               SRNAMT = 'SLATMS'
304               CALL SLATMS( M, N, DIST, ISEED, TYPE, RWORK, MODE,
305     $                      CNDNUM, ANORM, KL, KU, 'No packing', A, LDA,
306     $                      WORK, INFO )
307*
308*              Check error code from SLATMS.
309*
310               IF( INFO.NE.0 ) THEN
311                  CALL ALAERH( PATH, 'SLATMS', INFO, 0, ' ', M, N, -1,
312     $                         -1, -1, IMAT, NFAIL, NERRS, NOUT )
313                  GO TO 50
314               END IF
315*
316*              Set some values for K: the first value must be MINMN,
317*              corresponding to the call of SQLT01; other values are
318*              used in the calls of SQLT02, and must not exceed MINMN.
319*
320               KVAL( 1 ) = MINMN
321               KVAL( 2 ) = 0
322               KVAL( 3 ) = 1
323               KVAL( 4 ) = MINMN / 2
324               IF( MINMN.EQ.0 ) THEN
325                  NK = 1
326               ELSE IF( MINMN.EQ.1 ) THEN
327                  NK = 2
328               ELSE IF( MINMN.LE.3 ) THEN
329                  NK = 3
330               ELSE
331                  NK = 4
332               END IF
333*
334*              Do for each value of K in KVAL
335*
336               DO 40 IK = 1, NK
337                  K = KVAL( IK )
338*
339*                 Do for each pair of values (NB,NX) in NBVAL and NXVAL.
340*
341                  DO 30 INB = 1, NNB
342                     NB = NBVAL( INB )
343                     CALL XLAENV( 1, NB )
344                     NX = NXVAL( INB )
345                     CALL XLAENV( 3, NX )
346                     DO I = 1, NTESTS
347                        RESULT( I ) = ZERO
348                     END DO
349                     NT = 2
350                     IF( IK.EQ.1 ) THEN
351*
352*                       Test SGEQLF
353*
354                        CALL SQLT01( M, N, A, AF, AQ, AL, LDA, TAU,
355     $                               WORK, LWORK, RWORK, RESULT( 1 ) )
356                     ELSE IF( M.GE.N ) THEN
357*
358*                       Test SORGQL, using factorization
359*                       returned by SQLT01
360*
361                        CALL SQLT02( M, N, K, A, AF, AQ, AL, LDA, TAU,
362     $                               WORK, LWORK, RWORK, RESULT( 1 ) )
363                     END IF
364                     IF( M.GE.K ) THEN
365*
366*                       Test SORMQL, using factorization returned
367*                       by SQLT01
368*
369                        CALL SQLT03( M, N, K, AF, AC, AL, AQ, LDA, TAU,
370     $                               WORK, LWORK, RWORK, RESULT( 3 ) )
371                        NT = NT + 4
372*
373*                       If M>=N and K=N, call SGEQLS to solve a system
374*                       with NRHS right hand sides and compute the
375*                       residual.
376*
377                        IF( K.EQ.N .AND. INB.EQ.1 ) THEN
378*
379*                          Generate a solution and set the right
380*                          hand side.
381*
382                           SRNAMT = 'SLARHS'
383                           CALL SLARHS( PATH, 'New', 'Full',
384     $                                  'No transpose', M, N, 0, 0,
385     $                                  NRHS, A, LDA, XACT, LDA, B, LDA,
386     $                                  ISEED, INFO )
387*
388                           CALL SLACPY( 'Full', M, NRHS, B, LDA, X,
389     $                                  LDA )
390                           SRNAMT = 'SGEQLS'
391                           CALL SGEQLS( M, N, NRHS, AF, LDA, TAU, X,
392     $                                  LDA, WORK, LWORK, INFO )
393*
394*                          Check error code from SGEQLS.
395*
396                           IF( INFO.NE.0 )
397     $                        CALL ALAERH( PATH, 'SGEQLS', INFO, 0, ' ',
398     $                                     M, N, NRHS, -1, NB, IMAT,
399     $                                     NFAIL, NERRS, NOUT )
400*
401                           CALL SGET02( 'No transpose', M, N, NRHS, A,
402     $                                  LDA, X( M-N+1 ), LDA, B, LDA,
403     $                                  RWORK, RESULT( 7 ) )
404                           NT = NT + 1
405                        END IF
406                     END IF
407*
408*                    Print information about the tests that did not
409*                    pass the threshold.
410*
411                     DO 20 I = 1, NT
412                        IF( RESULT( I ).GE.THRESH ) THEN
413                           IF( NFAIL.EQ.0 .AND. NERRS.EQ.0 )
414     $                        CALL ALAHD( NOUT, PATH )
415                           WRITE( NOUT, FMT = 9999 )M, N, K, NB, NX,
416     $                        IMAT, I, RESULT( I )
417                           NFAIL = NFAIL + 1
418                        END IF
419   20                CONTINUE
420                     NRUN = NRUN + NT
421   30             CONTINUE
422   40          CONTINUE
423   50       CONTINUE
424   60    CONTINUE
425   70 CONTINUE
426*
427*     Print a summary of the results.
428*
429      CALL ALASUM( PATH, NOUT, NFAIL, NRUN, NERRS )
430*
431 9999 FORMAT( ' M=', I5, ', N=', I5, ', K=', I5, ', NB=', I4, ', NX=',
432     $      I5, ', type ', I2, ', test(', I2, ')=', G12.5 )
433      RETURN
434*
435*     End of SCHKQL
436*
437      END
438