1*> \brief \b ZGET07
2*
3*  =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6*            http://www.netlib.org/lapack/explore-html/
7*
8*  Definition:
9*  ===========
10*
11*       SUBROUTINE ZGET07( TRANS, N, NRHS, A, LDA, B, LDB, X, LDX, XACT,
12*                          LDXACT, FERR, CHKFERR, BERR, RESLTS )
13*
14*       .. Scalar Arguments ..
15*       CHARACTER          TRANS
16*       LOGICAL            CHKFERR
17*       INTEGER            LDA, LDB, LDX, LDXACT, N, NRHS
18*       ..
19*       .. Array Arguments ..
20*       DOUBLE PRECISION   BERR( * ), FERR( * ), RESLTS( * )
21*       COMPLEX*16         A( LDA, * ), B( LDB, * ), X( LDX, * ),
22*      $                   XACT( LDXACT, * )
23*       ..
24*
25*
26*> \par Purpose:
27*  =============
28*>
29*> \verbatim
30*>
31*> ZGET07 tests the error bounds from iterative refinement for the
32*> computed solution to a system of equations op(A)*X = B, where A is a
33*> general n by n matrix and op(A) = A or A**T, depending on TRANS.
34*>
35*> RESLTS(1) = test of the error bound
36*>           = norm(X - XACT) / ( norm(X) * FERR )
37*>
38*> A large value is returned if this ratio is not less than one.
39*>
40*> RESLTS(2) = residual from the iterative refinement routine
41*>           = the maximum of BERR / ( (n+1)*EPS + (*) ), where
42*>             (*) = (n+1)*UNFL / (min_i (abs(op(A))*abs(X) +abs(b))_i )
43*> \endverbatim
44*
45*  Arguments:
46*  ==========
47*
48*> \param[in] TRANS
49*> \verbatim
50*>          TRANS is CHARACTER*1
51*>          Specifies the form of the system of equations.
52*>          = 'N':  A * X = B     (No transpose)
53*>          = 'T':  A**T * X = B  (Transpose)
54*>          = 'C':  A**H * X = B  (Conjugate transpose = Transpose)
55*> \endverbatim
56*>
57*> \param[in] N
58*> \verbatim
59*>          N is INTEGER
60*>          The number of rows of the matrices X and XACT.  N >= 0.
61*> \endverbatim
62*>
63*> \param[in] NRHS
64*> \verbatim
65*>          NRHS is INTEGER
66*>          The number of columns of the matrices X and XACT.  NRHS >= 0.
67*> \endverbatim
68*>
69*> \param[in] A
70*> \verbatim
71*>          A is COMPLEX*16 array, dimension (LDA,N)
72*>          The original n by n matrix A.
73*> \endverbatim
74*>
75*> \param[in] LDA
76*> \verbatim
77*>          LDA is INTEGER
78*>          The leading dimension of the array A.  LDA >= max(1,N).
79*> \endverbatim
80*>
81*> \param[in] B
82*> \verbatim
83*>          B is COMPLEX*16 array, dimension (LDB,NRHS)
84*>          The right hand side vectors for the system of linear
85*>          equations.
86*> \endverbatim
87*>
88*> \param[in] LDB
89*> \verbatim
90*>          LDB is INTEGER
91*>          The leading dimension of the array B.  LDB >= max(1,N).
92*> \endverbatim
93*>
94*> \param[in] X
95*> \verbatim
96*>          X is COMPLEX*16 array, dimension (LDX,NRHS)
97*>          The computed solution vectors.  Each vector is stored as a
98*>          column of the matrix X.
99*> \endverbatim
100*>
101*> \param[in] LDX
102*> \verbatim
103*>          LDX is INTEGER
104*>          The leading dimension of the array X.  LDX >= max(1,N).
105*> \endverbatim
106*>
107*> \param[in] XACT
108*> \verbatim
109*>          XACT is COMPLEX*16 array, dimension (LDX,NRHS)
110*>          The exact solution vectors.  Each vector is stored as a
111*>          column of the matrix XACT.
112*> \endverbatim
113*>
114*> \param[in] LDXACT
115*> \verbatim
116*>          LDXACT is INTEGER
117*>          The leading dimension of the array XACT.  LDXACT >= max(1,N).
118*> \endverbatim
119*>
120*> \param[in] FERR
121*> \verbatim
122*>          FERR is DOUBLE PRECISION array, dimension (NRHS)
123*>          The estimated forward error bounds for each solution vector
124*>          X.  If XTRUE is the true solution, FERR bounds the magnitude
125*>          of the largest entry in (X - XTRUE) divided by the magnitude
126*>          of the largest entry in X.
127*> \endverbatim
128*>
129*> \param[in] CHKFERR
130*> \verbatim
131*>          CHKFERR is LOGICAL
132*>          Set to .TRUE. to check FERR, .FALSE. not to check FERR.
133*>          When the test system is ill-conditioned, the "true"
134*>          solution in XACT may be incorrect.
135*> \endverbatim
136*>
137*> \param[in] BERR
138*> \verbatim
139*>          BERR is DOUBLE PRECISION array, dimension (NRHS)
140*>          The componentwise relative backward error of each solution
141*>          vector (i.e., the smallest relative change in any entry of A
142*>          or B that makes X an exact solution).
143*> \endverbatim
144*>
145*> \param[out] RESLTS
146*> \verbatim
147*>          RESLTS is DOUBLE PRECISION array, dimension (2)
148*>          The maximum over the NRHS solution vectors of the ratios:
149*>          RESLTS(1) = norm(X - XACT) / ( norm(X) * FERR )
150*>          RESLTS(2) = BERR / ( (n+1)*EPS + (*) )
151*> \endverbatim
152*
153*  Authors:
154*  ========
155*
156*> \author Univ. of Tennessee
157*> \author Univ. of California Berkeley
158*> \author Univ. of Colorado Denver
159*> \author NAG Ltd.
160*
161*> \date November 2011
162*
163*> \ingroup complex16_lin
164*
165*  =====================================================================
166      SUBROUTINE ZGET07( TRANS, N, NRHS, A, LDA, B, LDB, X, LDX, XACT,
167     $                   LDXACT, FERR, CHKFERR, BERR, RESLTS )
168*
169*  -- LAPACK test routine (version 3.4.0) --
170*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
171*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
172*     November 2011
173*
174*     .. Scalar Arguments ..
175      CHARACTER          TRANS
176      LOGICAL            CHKFERR
177      INTEGER            LDA, LDB, LDX, LDXACT, N, NRHS
178*     ..
179*     .. Array Arguments ..
180      DOUBLE PRECISION   BERR( * ), FERR( * ), RESLTS( * )
181      COMPLEX*16         A( LDA, * ), B( LDB, * ), X( LDX, * ),
182     $                   XACT( LDXACT, * )
183*     ..
184*
185*  =====================================================================
186*
187*     .. Parameters ..
188      DOUBLE PRECISION   ZERO, ONE
189      PARAMETER          ( ZERO = 0.0D+0, ONE = 1.0D+0 )
190*     ..
191*     .. Local Scalars ..
192      LOGICAL            NOTRAN
193      INTEGER            I, IMAX, J, K
194      DOUBLE PRECISION   AXBI, DIFF, EPS, ERRBND, OVFL, TMP, UNFL, XNORM
195      COMPLEX*16         ZDUM
196*     ..
197*     .. External Functions ..
198      LOGICAL            LSAME
199      INTEGER            IZAMAX
200      DOUBLE PRECISION   DLAMCH
201      EXTERNAL           LSAME, IZAMAX, DLAMCH
202*     ..
203*     .. Intrinsic Functions ..
204      INTRINSIC          ABS, DBLE, DIMAG, MAX, MIN
205*     ..
206*     .. Statement Functions ..
207      DOUBLE PRECISION   CABS1
208*     ..
209*     .. Statement Function definitions ..
210      CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
211*     ..
212*     .. Executable Statements ..
213*
214*     Quick exit if N = 0 or NRHS = 0.
215*
216      IF( N.LE.0 .OR. NRHS.LE.0 ) THEN
217         RESLTS( 1 ) = ZERO
218         RESLTS( 2 ) = ZERO
219         RETURN
220      END IF
221*
222      EPS = DLAMCH( 'Epsilon' )
223      UNFL = DLAMCH( 'Safe minimum' )
224      OVFL = ONE / UNFL
225      NOTRAN = LSAME( TRANS, 'N' )
226*
227*     Test 1:  Compute the maximum of
228*        norm(X - XACT) / ( norm(X) * FERR )
229*     over all the vectors X and XACT using the infinity-norm.
230*
231      ERRBND = ZERO
232      IF( CHKFERR ) THEN
233         DO 30 J = 1, NRHS
234            IMAX = IZAMAX( N, X( 1, J ), 1 )
235            XNORM = MAX( CABS1( X( IMAX, J ) ), UNFL )
236            DIFF = ZERO
237            DO 10 I = 1, N
238               DIFF = MAX( DIFF, CABS1( X( I, J )-XACT( I, J ) ) )
239 10         CONTINUE
240*
241            IF( XNORM.GT.ONE ) THEN
242               GO TO 20
243            ELSE IF( DIFF.LE.OVFL*XNORM ) THEN
244               GO TO 20
245            ELSE
246               ERRBND = ONE / EPS
247               GO TO 30
248            END IF
249*
250 20         CONTINUE
251            IF( DIFF / XNORM.LE.FERR( J ) ) THEN
252               ERRBND = MAX( ERRBND, ( DIFF / XNORM ) / FERR( J ) )
253            ELSE
254               ERRBND = ONE / EPS
255            END IF
256 30      CONTINUE
257      END IF
258      RESLTS( 1 ) = ERRBND
259*
260*     Test 2:  Compute the maximum of BERR / ( (n+1)*EPS + (*) ), where
261*     (*) = (n+1)*UNFL / (min_i (abs(op(A))*abs(X) +abs(b))_i )
262*
263      DO 70 K = 1, NRHS
264         DO 60 I = 1, N
265            TMP = CABS1( B( I, K ) )
266            IF( NOTRAN ) THEN
267               DO 40 J = 1, N
268                  TMP = TMP + CABS1( A( I, J ) )*CABS1( X( J, K ) )
269   40          CONTINUE
270            ELSE
271               DO 50 J = 1, N
272                  TMP = TMP + CABS1( A( J, I ) )*CABS1( X( J, K ) )
273   50          CONTINUE
274            END IF
275            IF( I.EQ.1 ) THEN
276               AXBI = TMP
277            ELSE
278               AXBI = MIN( AXBI, TMP )
279            END IF
280   60    CONTINUE
281         TMP = BERR( K ) / ( ( N+1 )*EPS+( N+1 )*UNFL /
282     $         MAX( AXBI, ( N+1 )*UNFL ) )
283         IF( K.EQ.1 ) THEN
284            RESLTS( 2 ) = TMP
285         ELSE
286            RESLTS( 2 ) = MAX( RESLTS( 2 ), TMP )
287         END IF
288   70 CONTINUE
289*
290      RETURN
291*
292*     End of ZGET07
293*
294      END
295