1*> \brief \b ZLQT03
2*
3*  =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6*            http://www.netlib.org/lapack/explore-html/
7*
8*  Definition:
9*  ===========
10*
11*       SUBROUTINE ZLQT03( M, N, K, AF, C, CC, Q, LDA, TAU, WORK, LWORK,
12*                          RWORK, RESULT )
13*
14*       .. Scalar Arguments ..
15*       INTEGER            K, LDA, LWORK, M, N
16*       ..
17*       .. Array Arguments ..
18*       DOUBLE PRECISION   RESULT( * ), RWORK( * )
19*       COMPLEX*16         AF( LDA, * ), C( LDA, * ), CC( LDA, * ),
20*      $                   Q( LDA, * ), TAU( * ), WORK( LWORK )
21*       ..
22*
23*
24*> \par Purpose:
25*  =============
26*>
27*> \verbatim
28*>
29*> ZLQT03 tests ZUNMLQ, which computes Q*C, Q'*C, C*Q or C*Q'.
30*>
31*> ZLQT03 compares the results of a call to ZUNMLQ with the results of
32*> forming Q explicitly by a call to ZUNGLQ and then performing matrix
33*> multiplication by a call to ZGEMM.
34*> \endverbatim
35*
36*  Arguments:
37*  ==========
38*
39*> \param[in] M
40*> \verbatim
41*>          M is INTEGER
42*>          The number of rows or columns of the matrix C; C is n-by-m if
43*>          Q is applied from the left, or m-by-n if Q is applied from
44*>          the right.  M >= 0.
45*> \endverbatim
46*>
47*> \param[in] N
48*> \verbatim
49*>          N is INTEGER
50*>          The order of the orthogonal matrix Q.  N >= 0.
51*> \endverbatim
52*>
53*> \param[in] K
54*> \verbatim
55*>          K is INTEGER
56*>          The number of elementary reflectors whose product defines the
57*>          orthogonal matrix Q.  N >= K >= 0.
58*> \endverbatim
59*>
60*> \param[in] AF
61*> \verbatim
62*>          AF is COMPLEX*16 array, dimension (LDA,N)
63*>          Details of the LQ factorization of an m-by-n matrix, as
64*>          returned by ZGELQF. See CGELQF for further details.
65*> \endverbatim
66*>
67*> \param[out] C
68*> \verbatim
69*>          C is COMPLEX*16 array, dimension (LDA,N)
70*> \endverbatim
71*>
72*> \param[out] CC
73*> \verbatim
74*>          CC is COMPLEX*16 array, dimension (LDA,N)
75*> \endverbatim
76*>
77*> \param[out] Q
78*> \verbatim
79*>          Q is COMPLEX*16 array, dimension (LDA,N)
80*> \endverbatim
81*>
82*> \param[in] LDA
83*> \verbatim
84*>          LDA is INTEGER
85*>          The leading dimension of the arrays AF, C, CC, and Q.
86*> \endverbatim
87*>
88*> \param[in] TAU
89*> \verbatim
90*>          TAU is COMPLEX*16 array, dimension (min(M,N))
91*>          The scalar factors of the elementary reflectors corresponding
92*>          to the LQ factorization in AF.
93*> \endverbatim
94*>
95*> \param[out] WORK
96*> \verbatim
97*>          WORK is COMPLEX*16 array, dimension (LWORK)
98*> \endverbatim
99*>
100*> \param[in] LWORK
101*> \verbatim
102*>          LWORK is INTEGER
103*>          The length of WORK.  LWORK must be at least M, and should be
104*>          M*NB, where NB is the blocksize for this environment.
105*> \endverbatim
106*>
107*> \param[out] RWORK
108*> \verbatim
109*>          RWORK is DOUBLE PRECISION array, dimension (M)
110*> \endverbatim
111*>
112*> \param[out] RESULT
113*> \verbatim
114*>          RESULT is DOUBLE PRECISION array, dimension (4)
115*>          The test ratios compare two techniques for multiplying a
116*>          random matrix C by an n-by-n orthogonal matrix Q.
117*>          RESULT(1) = norm( Q*C - Q*C )  / ( N * norm(C) * EPS )
118*>          RESULT(2) = norm( C*Q - C*Q )  / ( N * norm(C) * EPS )
119*>          RESULT(3) = norm( Q'*C - Q'*C )/ ( N * norm(C) * EPS )
120*>          RESULT(4) = norm( C*Q' - C*Q' )/ ( N * norm(C) * EPS )
121*> \endverbatim
122*
123*  Authors:
124*  ========
125*
126*> \author Univ. of Tennessee
127*> \author Univ. of California Berkeley
128*> \author Univ. of Colorado Denver
129*> \author NAG Ltd.
130*
131*> \date November 2011
132*
133*> \ingroup complex16_lin
134*
135*  =====================================================================
136      SUBROUTINE ZLQT03( M, N, K, AF, C, CC, Q, LDA, TAU, WORK, LWORK,
137     $                   RWORK, RESULT )
138*
139*  -- LAPACK test routine (version 3.4.0) --
140*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
141*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
142*     November 2011
143*
144*     .. Scalar Arguments ..
145      INTEGER            K, LDA, LWORK, M, N
146*     ..
147*     .. Array Arguments ..
148      DOUBLE PRECISION   RESULT( * ), RWORK( * )
149      COMPLEX*16         AF( LDA, * ), C( LDA, * ), CC( LDA, * ),
150     $                   Q( LDA, * ), TAU( * ), WORK( LWORK )
151*     ..
152*
153*  =====================================================================
154*
155*     .. Parameters ..
156      DOUBLE PRECISION   ZERO, ONE
157      PARAMETER          ( ZERO = 0.0D+0, ONE = 1.0D+0 )
158      COMPLEX*16         ROGUE
159      PARAMETER          ( ROGUE = ( -1.0D+10, -1.0D+10 ) )
160*     ..
161*     .. Local Scalars ..
162      CHARACTER          SIDE, TRANS
163      INTEGER            INFO, ISIDE, ITRANS, J, MC, NC
164      DOUBLE PRECISION   CNORM, EPS, RESID
165*     ..
166*     .. External Functions ..
167      LOGICAL            LSAME
168      DOUBLE PRECISION   DLAMCH, ZLANGE
169      EXTERNAL           LSAME, DLAMCH, ZLANGE
170*     ..
171*     .. External Subroutines ..
172      EXTERNAL           ZGEMM, ZLACPY, ZLARNV, ZLASET, ZUNGLQ, ZUNMLQ
173*     ..
174*     .. Local Arrays ..
175      INTEGER            ISEED( 4 )
176*     ..
177*     .. Intrinsic Functions ..
178      INTRINSIC          DBLE, DCMPLX, MAX
179*     ..
180*     .. Scalars in Common ..
181      CHARACTER*32       SRNAMT
182*     ..
183*     .. Common blocks ..
184      COMMON             / SRNAMC / SRNAMT
185*     ..
186*     .. Data statements ..
187      DATA               ISEED / 1988, 1989, 1990, 1991 /
188*     ..
189*     .. Executable Statements ..
190*
191      EPS = DLAMCH( 'Epsilon' )
192*
193*     Copy the first k rows of the factorization to the array Q
194*
195      CALL ZLASET( 'Full', N, N, ROGUE, ROGUE, Q, LDA )
196      CALL ZLACPY( 'Upper', K, N-1, AF( 1, 2 ), LDA, Q( 1, 2 ), LDA )
197*
198*     Generate the n-by-n matrix Q
199*
200      SRNAMT = 'ZUNGLQ'
201      CALL ZUNGLQ( N, N, K, Q, LDA, TAU, WORK, LWORK, INFO )
202*
203      DO 30 ISIDE = 1, 2
204         IF( ISIDE.EQ.1 ) THEN
205            SIDE = 'L'
206            MC = N
207            NC = M
208         ELSE
209            SIDE = 'R'
210            MC = M
211            NC = N
212         END IF
213*
214*        Generate MC by NC matrix C
215*
216         DO 10 J = 1, NC
217            CALL ZLARNV( 2, ISEED, MC, C( 1, J ) )
218   10    CONTINUE
219         CNORM = ZLANGE( '1', MC, NC, C, LDA, RWORK )
220         IF( CNORM.EQ.ZERO )
221     $      CNORM = ONE
222*
223         DO 20 ITRANS = 1, 2
224            IF( ITRANS.EQ.1 ) THEN
225               TRANS = 'N'
226            ELSE
227               TRANS = 'C'
228            END IF
229*
230*           Copy C
231*
232            CALL ZLACPY( 'Full', MC, NC, C, LDA, CC, LDA )
233*
234*           Apply Q or Q' to C
235*
236            SRNAMT = 'ZUNMLQ'
237            CALL ZUNMLQ( SIDE, TRANS, MC, NC, K, AF, LDA, TAU, CC, LDA,
238     $                   WORK, LWORK, INFO )
239*
240*           Form explicit product and subtract
241*
242            IF( LSAME( SIDE, 'L' ) ) THEN
243               CALL ZGEMM( TRANS, 'No transpose', MC, NC, MC,
244     $                     DCMPLX( -ONE ), Q, LDA, C, LDA,
245     $                     DCMPLX( ONE ), CC, LDA )
246            ELSE
247               CALL ZGEMM( 'No transpose', TRANS, MC, NC, NC,
248     $                     DCMPLX( -ONE ), C, LDA, Q, LDA,
249     $                     DCMPLX( ONE ), CC, LDA )
250            END IF
251*
252*           Compute error in the difference
253*
254            RESID = ZLANGE( '1', MC, NC, CC, LDA, RWORK )
255            RESULT( ( ISIDE-1 )*2+ITRANS ) = RESID /
256     $         ( DBLE( MAX( 1, N ) )*CNORM*EPS )
257*
258   20    CONTINUE
259   30 CONTINUE
260*
261      RETURN
262*
263*     End of ZLQT03
264*
265      END
266