1*> \brief \b CDRVHE_ROOK
2*
3*  =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6*            http://www.netlib.org/lapack/explore-html/
7*
8*  Definition:
9*  ===========
10*
11*       SUBROUTINE CDRVHE_ROOK( DOTYPE, NN, NVAL, NRHS, THRESH, TSTERR,
12*                               NMAX, A, AFAC, AINV, B, X, XACT, WORK, RWORK,
13*                               IWORK, NOUT )
14*
15*       .. Scalar Arguments ..
16*       LOGICAL            TSTERR
17*       INTEGER            NMAX, NN, NOUT, NRHS
18*       REAL               THRESH
19*       ..
20*       .. Array Arguments ..
21*       LOGICAL            DOTYPE( * )
22*       INTEGER            IWORK( * ), NVAL( * )
23*       REAL               RWORK( * )
24*       COMPLEX            A( * ), AFAC( * ), AINV( * ), B( * ),
25*      $                   WORK( * ), X( * ), XACT( * )
26*       ..
27*
28*
29*> \par Purpose:
30*  =============
31*>
32*> \verbatim
33*>
34*> CDRVHE_ROOK tests the driver routines CHESV_ROOK.
35*> \endverbatim
36*
37*  Arguments:
38*  ==========
39*
40*> \param[in] DOTYPE
41*> \verbatim
42*>          DOTYPE is LOGICAL array, dimension (NTYPES)
43*>          The matrix types to be used for testing.  Matrices of type j
44*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
45*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
46*> \endverbatim
47*>
48*> \param[in] NN
49*> \verbatim
50*>          NN is INTEGER
51*>          The number of values of N contained in the vector NVAL.
52*> \endverbatim
53*>
54*> \param[in] NVAL
55*> \verbatim
56*>          NVAL is INTEGER array, dimension (NN)
57*>          The values of the matrix dimension N.
58*> \endverbatim
59*>
60*> \param[in] NRHS
61*> \verbatim
62*>          NRHS is INTEGER
63*>          The number of right hand side vectors to be generated for
64*>          each linear system.
65*> \endverbatim
66*>
67*> \param[in] THRESH
68*> \verbatim
69*>          THRESH is REAL
70*>          The threshold value for the test ratios.  A result is
71*>          included in the output file if RESULT >= THRESH.  To have
72*>          every test ratio printed, use THRESH = 0.
73*> \endverbatim
74*>
75*> \param[in] TSTERR
76*> \verbatim
77*>          TSTERR is LOGICAL
78*>          Flag that indicates whether error exits are to be tested.
79*> \endverbatim
80*>
81*> \param[in] NMAX
82*> \verbatim
83*>          NMAX is INTEGER
84*>          The maximum value permitted for N, used in dimensioning the
85*>          work arrays.
86*> \endverbatim
87*>
88*> \param[out] A
89*> \verbatim
90*>          A is COMPLEX array, dimension (NMAX*NMAX)
91*> \endverbatim
92*>
93*> \param[out] AFAC
94*> \verbatim
95*>          AFAC is COMPLEX array, dimension (NMAX*NMAX)
96*> \endverbatim
97*>
98*> \param[out] AINV
99*> \verbatim
100*>          AINV is COMPLEX array, dimension (NMAX*NMAX)
101*> \endverbatim
102*>
103*> \param[out] B
104*> \verbatim
105*>          B is COMPLEX array, dimension (NMAX*NRHS)
106*> \endverbatim
107*>
108*> \param[out] X
109*> \verbatim
110*>          X is COMPLEX array, dimension (NMAX*NRHS)
111*> \endverbatim
112*>
113*> \param[out] XACT
114*> \verbatim
115*>          XACT is COMPLEX array, dimension (NMAX*NRHS)
116*> \endverbatim
117*>
118*> \param[out] WORK
119*> \verbatim
120*>          WORK is COMPLEX array, dimension (NMAX*max(2,NRHS))
121*> \endverbatim
122*>
123*> \param[out] RWORK
124*> \verbatim
125*>          RWORK is REAL array, dimension (NMAX+2*NRHS)
126*> \endverbatim
127*>
128*> \param[out] IWORK
129*> \verbatim
130*>          IWORK is INTEGER array, dimension (NMAX)
131*> \endverbatim
132*>
133*> \param[in] NOUT
134*> \verbatim
135*>          NOUT is INTEGER
136*>          The unit number for output.
137*> \endverbatim
138*
139*  Authors:
140*  ========
141*
142*> \author Univ. of Tennessee
143*> \author Univ. of California Berkeley
144*> \author Univ. of Colorado Denver
145*> \author NAG Ltd.
146*
147*> \date November 2013
148*
149*> \ingroup complex_lin
150*
151*  =====================================================================
152      SUBROUTINE CDRVHE_ROOK( DOTYPE, NN, NVAL, NRHS, THRESH, TSTERR,
153     $                        NMAX, A, AFAC, AINV, B, X, XACT, WORK,
154     $                        RWORK, IWORK, NOUT )
155*
156*  -- LAPACK test routine (version 3.5.0) --
157*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
158*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
159*     November 2013
160*
161*     .. Scalar Arguments ..
162      LOGICAL            TSTERR
163      INTEGER            NMAX, NN, NOUT, NRHS
164      REAL               THRESH
165*     ..
166*     .. Array Arguments ..
167      LOGICAL            DOTYPE( * )
168      INTEGER            IWORK( * ), NVAL( * )
169      REAL               RWORK( * )
170      COMPLEX            A( * ), AFAC( * ), AINV( * ), B( * ),
171     $                   WORK( * ), X( * ), XACT( * )
172*     ..
173*
174*  =====================================================================
175*
176*     .. Parameters ..
177      REAL               ONE, ZERO
178      PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
179      INTEGER            NTYPES, NTESTS
180      PARAMETER          ( NTYPES = 10, NTESTS = 3 )
181      INTEGER            NFACT
182      PARAMETER          ( NFACT = 2 )
183*     ..
184*     .. Local Scalars ..
185      LOGICAL            ZEROT
186      CHARACTER          DIST, FACT, TYPE, UPLO, XTYPE
187      CHARACTER*3        MATPATH, PATH
188      INTEGER            I, I1, I2, IFACT, IMAT, IN, INFO, IOFF, IUPLO,
189     $                   IZERO, J, K, KL, KU, LDA, LWORK, MODE, N,
190     $                   NB, NBMIN, NERRS, NFAIL, NIMAT, NRUN, NT
191      REAL               AINVNM, ANORM, CNDNUM, RCONDC
192*     ..
193*     .. Local Arrays ..
194      CHARACTER          FACTS( NFACT ), UPLOS( 2 )
195      INTEGER            ISEED( 4 ), ISEEDY( 4 )
196      REAL               RESULT( NTESTS )
197
198*     ..
199*     .. External Functions ..
200      REAL               CLANHE
201      EXTERNAL           CLANHE
202*     ..
203*     .. External Subroutines ..
204      EXTERNAL           ALADHD, ALAERH, ALASVM, XLAENV, CERRVX,
205     $                   CGET04, CLACPY, CLARHS, CLATB4, CLATMS,
206     $                   CHESV_ROOK, CHET01_ROOK, CPOT02,
207     $                   CHETRF_ROOK, CHETRI_ROOK
208*     ..
209*     .. Scalars in Common ..
210      LOGICAL            LERR, OK
211      CHARACTER*32       SRNAMT
212      INTEGER            INFOT, NUNIT
213*     ..
214*     .. Common blocks ..
215      COMMON             / INFOC / INFOT, NUNIT, OK, LERR
216      COMMON             / SRNAMC / SRNAMT
217*     ..
218*     .. Intrinsic Functions ..
219      INTRINSIC          MAX, MIN
220*     ..
221*     .. Data statements ..
222      DATA               ISEEDY / 1988, 1989, 1990, 1991 /
223      DATA               UPLOS / 'U', 'L' / , FACTS / 'F', 'N' /
224*     ..
225*     .. Executable Statements ..
226*
227*     Initialize constants and the random number seed.
228*
229*     Test path
230*
231      PATH( 1: 1 ) = 'Complex precision'
232      PATH( 2: 3 ) = 'HR'
233*
234*     Path to generate matrices
235*
236      MATPATH( 1: 1 ) = 'Complex precision'
237      MATPATH( 2: 3 ) = 'HE'
238*
239      NRUN = 0
240      NFAIL = 0
241      NERRS = 0
242      DO 10 I = 1, 4
243         ISEED( I ) = ISEEDY( I )
244   10 CONTINUE
245      LWORK = MAX( 2*NMAX, NMAX*NRHS )
246*
247*     Test the error exits
248*
249      IF( TSTERR )
250     $   CALL CERRVX( PATH, NOUT )
251      INFOT = 0
252*
253*     Set the block size and minimum block size for which the block
254*     routine should be used, which will be later returned by ILAENV.
255*
256      NB = 1
257      NBMIN = 2
258      CALL XLAENV( 1, NB )
259      CALL XLAENV( 2, NBMIN )
260*
261*     Do for each value of N in NVAL
262*
263      DO 180 IN = 1, NN
264         N = NVAL( IN )
265         LDA = MAX( N, 1 )
266         XTYPE = 'N'
267         NIMAT = NTYPES
268         IF( N.LE.0 )
269     $      NIMAT = 1
270*
271         DO 170 IMAT = 1, NIMAT
272*
273*           Do the tests only if DOTYPE( IMAT ) is true.
274*
275            IF( .NOT.DOTYPE( IMAT ) )
276     $         GO TO 170
277*
278*           Skip types 3, 4, 5, or 6 if the matrix size is too small.
279*
280            ZEROT = IMAT.GE.3 .AND. IMAT.LE.6
281            IF( ZEROT .AND. N.LT.IMAT-2 )
282     $         GO TO 170
283*
284*           Do first for UPLO = 'U', then for UPLO = 'L'
285*
286            DO 160 IUPLO = 1, 2
287               UPLO = UPLOS( IUPLO )
288*
289*                 Begin generate the test matrix A.
290*
291*                 Set up parameters with CLATB4 for the matrix generator
292*                 based on the type of matrix to be generated.
293*
294                  CALL CLATB4( MATPATH, IMAT, N, N, TYPE, KL, KU, ANORM,
295     $                         MODE, CNDNUM, DIST )
296*
297*                 Generate a matrix with CLATMS.
298*
299                  SRNAMT = 'CLATMS'
300                  CALL CLATMS( N, N, DIST, ISEED, TYPE, RWORK, MODE,
301     $                         CNDNUM, ANORM, KL, KU, UPLO, A, LDA,
302     $                         WORK, INFO )
303*
304*                 Check error code from CLATMS and handle error.
305*
306                  IF( INFO.NE.0 ) THEN
307                     CALL ALAERH( PATH, 'CLATMS', INFO, 0, UPLO, N, N,
308     $                            -1, -1, -1, IMAT, NFAIL, NERRS, NOUT )
309                     GO TO 160
310                  END IF
311*
312*                 For types 3-6, zero one or more rows and columns of
313*                 the matrix to test that INFO is returned correctly.
314*
315                  IF( ZEROT ) THEN
316                     IF( IMAT.EQ.3 ) THEN
317                        IZERO = 1
318                     ELSE IF( IMAT.EQ.4 ) THEN
319                        IZERO = N
320                     ELSE
321                        IZERO = N / 2 + 1
322                     END IF
323*
324                     IF( IMAT.LT.6 ) THEN
325*
326*                       Set row and column IZERO to zero.
327*
328                        IF( IUPLO.EQ.1 ) THEN
329                           IOFF = ( IZERO-1 )*LDA
330                           DO 20 I = 1, IZERO - 1
331                              A( IOFF+I ) = ZERO
332   20                      CONTINUE
333                           IOFF = IOFF + IZERO
334                           DO 30 I = IZERO, N
335                              A( IOFF ) = ZERO
336                              IOFF = IOFF + LDA
337   30                      CONTINUE
338                        ELSE
339                           IOFF = IZERO
340                           DO 40 I = 1, IZERO - 1
341                              A( IOFF ) = ZERO
342                              IOFF = IOFF + LDA
343   40                      CONTINUE
344                           IOFF = IOFF - IZERO
345                           DO 50 I = IZERO, N
346                              A( IOFF+I ) = ZERO
347   50                      CONTINUE
348                        END IF
349                     ELSE
350                        IF( IUPLO.EQ.1 ) THEN
351*
352*                       Set the first IZERO rows and columns to zero.
353*
354                           IOFF = 0
355                           DO 70 J = 1, N
356                              I2 = MIN( J, IZERO )
357                              DO 60 I = 1, I2
358                                 A( IOFF+I ) = ZERO
359   60                         CONTINUE
360                              IOFF = IOFF + LDA
361   70                      CONTINUE
362                        ELSE
363*
364*                       Set the first IZERO rows and columns to zero.
365*
366                           IOFF = 0
367                           DO 90 J = 1, N
368                              I1 = MAX( J, IZERO )
369                              DO 80 I = I1, N
370                                 A( IOFF+I ) = ZERO
371   80                         CONTINUE
372                              IOFF = IOFF + LDA
373   90                      CONTINUE
374                        END IF
375                     END IF
376                  ELSE
377                     IZERO = 0
378                  END IF
379*
380*                 End generate the test matrix A.
381*
382*
383               DO 150 IFACT = 1, NFACT
384*
385*                 Do first for FACT = 'F', then for other values.
386*
387                  FACT = FACTS( IFACT )
388*
389*                 Compute the condition number for comparison with
390*                 the value returned by CHESVX_ROOK.
391*
392                  IF( ZEROT ) THEN
393                     IF( IFACT.EQ.1 )
394     $                  GO TO 150
395                     RCONDC = ZERO
396*
397                  ELSE IF( IFACT.EQ.1 ) THEN
398*
399*                    Compute the 1-norm of A.
400*
401                     ANORM = CLANHE( '1', UPLO, N, A, LDA, RWORK )
402*
403*                    Factor the matrix A.
404*
405                     CALL CLACPY( UPLO, N, N, A, LDA, AFAC, LDA )
406                     CALL CHETRF_ROOK( UPLO, N, AFAC, LDA, IWORK, WORK,
407     $                                 LWORK, INFO )
408*
409*                    Compute inv(A) and take its norm.
410*
411                     CALL CLACPY( UPLO, N, N, AFAC, LDA, AINV, LDA )
412                     LWORK = (N+NB+1)*(NB+3)
413                     CALL CHETRI_ROOK( UPLO, N, AINV, LDA, IWORK,
414     $                                 WORK, INFO )
415                     AINVNM = CLANHE( '1', UPLO, N, AINV, LDA, RWORK )
416*
417*                    Compute the 1-norm condition number of A.
418*
419                     IF( ANORM.LE.ZERO .OR. AINVNM.LE.ZERO ) THEN
420                        RCONDC = ONE
421                     ELSE
422                        RCONDC = ( ONE / ANORM ) / AINVNM
423                     END IF
424                  END IF
425*
426*                 Form an exact solution and set the right hand side.
427*
428                  SRNAMT = 'CLARHS'
429                  CALL CLARHS( MATPATH, XTYPE, UPLO, ' ', N, N, KL, KU,
430     $                         NRHS, A, LDA, XACT, LDA, B, LDA, ISEED,
431     $                         INFO )
432                  XTYPE = 'C'
433*
434*                 --- Test CHESV_ROOK  ---
435*
436                  IF( IFACT.EQ.2 ) THEN
437                     CALL CLACPY( UPLO, N, N, A, LDA, AFAC, LDA )
438                     CALL CLACPY( 'Full', N, NRHS, B, LDA, X, LDA )
439*
440*                    Factor the matrix and solve the system using
441*                    CHESV_ROOK.
442*
443                     SRNAMT = 'CHESV_ROOK'
444                     CALL CHESV_ROOK( UPLO, N, NRHS, AFAC, LDA, IWORK,
445     $                                X, LDA, WORK, LWORK, INFO )
446*
447*                    Adjust the expected value of INFO to account for
448*                    pivoting.
449*
450                     K = IZERO
451                     IF( K.GT.0 ) THEN
452  100                   CONTINUE
453                        IF( IWORK( K ).LT.0 ) THEN
454                           IF( IWORK( K ).NE.-K ) THEN
455                              K = -IWORK( K )
456                              GO TO 100
457                           END IF
458                        ELSE IF( IWORK( K ).NE.K ) THEN
459                           K = IWORK( K )
460                           GO TO 100
461                        END IF
462                     END IF
463*
464*                    Check error code from CHESV_ROOK and handle error.
465*
466                     IF( INFO.NE.K ) THEN
467                        CALL ALAERH( PATH, 'CHESV_ROOK', INFO, K, UPLO,
468     $                               N, N, -1, -1, NRHS, IMAT, NFAIL,
469     $                               NERRS, NOUT )
470                        GO TO 120
471                     ELSE IF( INFO.NE.0 ) THEN
472                        GO TO 120
473                     END IF
474*
475*+    TEST 1      Reconstruct matrix from factors and compute
476*                 residual.
477*
478                     CALL CHET01_ROOK( UPLO, N, A, LDA, AFAC, LDA,
479     $                                 IWORK, AINV, LDA, RWORK,
480     $                                 RESULT( 1 ) )
481*
482*+    TEST 2      Compute residual of the computed solution.
483*
484                     CALL CLACPY( 'Full', N, NRHS, B, LDA, WORK, LDA )
485                     CALL CPOT02( UPLO, N, NRHS, A, LDA, X, LDA, WORK,
486     $                            LDA, RWORK, RESULT( 2 ) )
487*
488*+    TEST 3
489*                 Check solution from generated exact solution.
490*
491                     CALL CGET04( N, NRHS, X, LDA, XACT, LDA, RCONDC,
492     $                            RESULT( 3 ) )
493                     NT = 3
494*
495*                    Print information about the tests that did not pass
496*                    the threshold.
497*
498                     DO 110 K = 1, NT
499                        IF( RESULT( K ).GE.THRESH ) THEN
500                           IF( NFAIL.EQ.0 .AND. NERRS.EQ.0 )
501     $                        CALL ALADHD( NOUT, PATH )
502                           WRITE( NOUT, FMT = 9999 )'CHESV_ROOK', UPLO,
503     $                            N, IMAT, K, RESULT( K )
504                           NFAIL = NFAIL + 1
505                        END IF
506  110                CONTINUE
507                     NRUN = NRUN + NT
508  120                CONTINUE
509                  END IF
510*
511  150          CONTINUE
512*
513  160       CONTINUE
514  170    CONTINUE
515  180 CONTINUE
516*
517*     Print a summary of the results.
518*
519      CALL ALASVM( PATH, NOUT, NFAIL, NRUN, NERRS )
520*
521 9999 FORMAT( 1X, A, ', UPLO=''', A1, ''', N =', I5, ', type ', I2,
522     $      ', test ', I2, ', ratio =', G12.5 )
523      RETURN
524*
525*     End of CDRVHE_ROOK
526*
527      END
528