1project('gupnp-tools', ['c'], version: '0.10.2')
2
3gnome = import('gnome')
4i18n = import('i18n')
5
6if host_machine.system() == 'windows'
7    win = import('windows')
8endif
9
10gssdp = dependency('gssdp-1.2', version: '>= 1.2.0', default_options: ['sniffer=false'])
11gupnp = dependency('gupnp-1.2', version: '>= 1.2.0')
12soup = dependency('libsoup-2.4', version: '>= 2.42')
13gupnp_av = dependency('gupnp-av-1.0', version: '>= 0.5.5', required: get_option('av-tools'))
14gtk = dependency('gtk+-3.0', version: '>= 3.10')
15glib = dependency('glib-2.0', version: '>= 2.24')
16gio = dependency('gio-2.0', version: '>= 2.24')
17libxml = dependency('libxml-2.0', version: '>= 2.0')
18gobject = dependency('gobject-2.0', version: '>= 2.24')
19
20# Check for gtksourceview (used for XML syntax highlighting)
21gtksourceview = dependency('gtksourceview-4', required: false)
22if not gtksourceview.found()
23    gtksourceview = dependency('gtksourceview-3.0', version: '>= 3.2.0', required: false)
24endif
25
26prefix = get_option('prefix')
27datadir = join_paths(prefix, get_option('datadir'))
28localedir = join_paths(prefix, get_option('localedir'))
29
30resource_data = join_paths(meson.source_root(), 'data')
31if get_option('uninstalled')
32    shareddir = resource_data
33else
34    shareddir = join_paths(datadir, meson.project_name())
35endif
36
37desktopdir = join_paths(datadir, 'applications')
38
39conf = configuration_data()
40conf.set('VERSION', '"@0@"'.format(meson.project_version()))
41conf.set('DATA_DIR', '"@0@"'.format(shareddir))
42conf.set('HAVE_GTK_SOURCEVIEW', gtksourceview.found())
43conf.set('GETTEXT_PACKAGE', '"@0@"'.format(meson.project_name()))
44conf.set('LOCALEDIR', '"@0@"'.format(localedir))
45
46configure_file(input: 'config.h.meson', output: 'config.h', configuration: conf)
47config_header = declare_dependency(compile_args : '-DHAVE_CONFIG_H=1', include_directories : include_directories('.'))
48
49subdir('data')
50subdir('src')
51subdir('po')
52