1AC_INIT(configure.ac)
2
3dnl extract recommended PTLIB version from parent directory
4if test \! -e ../configure ; then
5  echo "ERROR: unable to find '../configure'"
6else
7  PTLIB_REC_VERSION=`grep '^PTLIB_REC_VERSION=' ../configure | sed -e 's/^PTLIB_REC_VERSION=//' -e 's/\"//g'`
8  echo PTLIB_REC_VERSION $PTLIB_REC_VERSION
9  if test "x$PTLIB_REC_VERSION" = "x" ; then
10    echo "ERROR: unable to extract PTLIB_REC_VERSION from ../configure"
11    exit -1
12  fi
13fi
14
15PKG_PROG_PKG_CONFIG()
16AC_CANONICAL_TARGET()
17
18m4_include(../opal.m4)
19
20OPAL_FIND_PTLIB()
21
22CFLAGS="$CFLAGS $PTLIB_CFLAGS"
23CXXFLAGS="$CXXFLAGS $PTLIB_CXXFLAGS -D__STDC_CONSTANT_MACROS"
24
25AC_PROG_CXX
26AC_PROG_CC
27AC_PROG_INSTALL
28AC_PROG_RANLIB
29AC_CHECK_TOOL([NM], [nm], [:])
30AC_CHECK_TOOL([LDD], [ldd], [:])
31AC_CHECK_TOOL([OBJDUMP], [objdump], [:])
32
33AC_HEADER_STDC
34AC_CHECK_HEADERS([stddef.h limits.h float.h fcntl.h])
35
36dnl Enable compiler warnings
37dnl if test "x$ac_cv_c_compiler_gnu" = xyes; then
38dnl for later...
39dnl  CFLAGS="$CFLAGS -Wall -Wextra -Winit-self -Wswitch-default -Wswitch-enum -Wstrict-aliasing=2 -Wfloat-equal -Wshadow -Wno-comment -Wno-missing-field-initializers -Wno-unused"
40dnl  CXXFLAGS="$CXXFLAGS -Wall -Wextra -Winit-self -Wswitch-default -Wswitch-enum -Wstrict-aliasing=2 -Wfloat-equal -Wshadow -Wno-comment -Wno-missing-field-initializers  -Wno-unused"
41dnl fi
42
43dnl ########################################################################
44dnl Directories
45dnl ########################################################################
46
47OPAL_DETERMINE_VERSION([..])
48OPAL_DETERMINE_PLUGIN_DIR()
49
50AC_PLUGIN_DIR="${PLUGIN_DIR}/codecs/audio"
51VC_PLUGIN_DIR="${PLUGIN_DIR}/codecs/video"
52LID_PLUGIN_DIR="${PLUGIN_DIR}/lid"
53FAX_PLUGIN_DIR="${PLUGIN_DIR}/fax"
54
55PLUGINDIR=`pwd`
56
57AC_SUBST(prefix)
58AC_SUBST(exec_prefix)
59AC_SUBST(libdir)
60AC_SUBST(OSTYPE)
61AC_SUBST(MACHTYPE)
62AC_SUBST(PLUGINDIR)
63AC_SUBST(AC_PLUGIN_DIR)
64AC_SUBST(VC_PLUGIN_DIR)
65AC_SUBST(LID_PLUGIN_DIR)
66AC_SUBST(FAX_PLUGIN_DIR)
67
68dnl ########################################################################
69dnl Platform specific section
70dnl ########################################################################
71WIN32=no
72LDSO=
73case "$target_os" in
74       solaris*)
75          CFLAGS="$CFLAGS -KPIC"
76          LDSO='-Bdynamic -G -h $@'
77          PLUGINEXT=so
78          AC_CHECK_HEADERS([sys/time.h sys/file.h netinet/in.h])
79          AC_FUNC_FORK()
80        ;;
81
82        darwin*)
83         CFLAGS="$CFLAGS -fno-common -dynamic"
84          LDSO='-dynamiclib -multiply_defined suppress'
85          CFLAGS="$CFLAGS -fPIC -D__MACOSX__"
86          case "$target_cpu" in
87            x86 | i686 | i586 | i486 | i386 ) CFLAGS="${CFLAGS} -m486" ;;
88          esac
89          PLUGINEXT=dylib
90          AC_CHECK_HEADERS([sys/time.h sys/file.h netinet/in.h])
91          AC_FUNC_FORK()
92        ;;
93
94        cygwin*|mingw**)
95          LDSO='-module -shared'
96          PLUGINEXT=dll
97          WIN32=yes
98          AC_CHECK_HEADERS([malloc.h])
99          AC_DEFINE([PLUGIN_CODEC_DLL_EXPORTS], [1], [For win32 build])
100        ;;
101
102        *)
103          CFLAGS="$CFLAGS -fPIC"
104          LDSO='-shared -Wl,-soname,$(SONAME)'
105          PLUGINEXT=so
106          AC_CHECK_HEADERS([sys/time.h sys/file.h netinet/in.h])
107          AC_FUNC_FORK()
108        ;;
109esac
110AC_SUBST(LDSO)
111AC_SUBST(PLUGINEXT)
112AC_SUBST(CFLAGS)
113AC_SUBST(WIN32)
114
115OPAL_FIND_LIBDL([HAVE_LIBDL=yes], [HAVE_LIBDL=no])
116AC_SUBST(HAVE_LIBDL)
117AC_SUBST(DL_LIBS)
118
119
120dnl ########################################################################
121dnl Defaults
122dnl ########################################################################
123
124HAVE_VPB=no
125HAVE_IXJ=no
126HAVE_SPANDSP=yes
127DEFAULT_TO_FULL_CAPABILITIES=yes
128
129SUBDIRS=""
130AC_SUBST(SUBDIRS)
131
132
133AC_MSG_CHECKING([if linker accepts -Wl,--no-as-needed])
134AC_LANG_CONFTEST([AC_LANG_PROGRAM([[]],[[]])])
135$CC -o conftest$ac_exeext $CPPFLAGS $CFLAGS $LDFLAGS -Wl,--no-as-needed conftest.$ac_ext > /dev/null 2>&1
136if test $? = 0 ; then
137   AC_MSG_RESULT(yes)
138   NO_AS_NEEDED_LDFLAG="-Wl,--no-as-needed"
139else
140   AC_MSG_RESULT(no)
141fi
142
143
144
145dnl ########################################################################
146dnl Audio Codecs
147dnl ########################################################################
148
149dnl #########
150
151if test -d audio/GSM0610 ; then
152  AC_ARG_ENABLE([gsm],
153                [AC_HELP_STRING([--disable-gsm],[Disable GSM 06.10])],
154                [HAVE_GSM0610=$enableval],
155                [HAVE_GSM0610=yes])
156else
157  HAVE_GSM0610=no
158fi
159if test "x${HAVE_GSM0610}" = "xyes" ; then
160  AC_CONFIG_FILES(audio/GSM0610/Makefile)
161  SUBDIRS+=" audio/GSM0610"
162
163  AC_ARG_ENABLE([localgsm],
164                [AC_HELP_STRING([--enable-localgsm],[Force use local version of GSM library rather than system version])],
165                [localgsm=$enableval],
166                [localgsm=])
167
168  if test "x${localgsm}" = "xyes" ; then
169    AC_MSG_NOTICE(Forcing use of local GSM sources)
170    GSM_SYSTEM=no
171
172  elif test "x${localgsm}" = "xno" ; then
173    AC_MSG_NOTICE(Forcing use of system GSM library)
174    OPAL_FIND_GSM([HAVE_GSM=yes], [HAVE_GSM=no])
175    if test "x${HAVE_GSM}" != "xyes" ; then
176      AC_MSG_ERROR([cannot find system GSM])
177    else
178      GSM_SYSTEM=yes
179    fi
180
181  else
182    OPAL_FIND_GSM([HAVE_GSM=yes], [HAVE_GSM=no])
183    if test "x${HAVE_GSM}" = "xyes" ; then
184      GSM_SYSTEM=yes
185    else
186      GSM_SYSTEM=no
187    fi
188  fi
189
190  if test "x${GSM_SYSTEM}" = "xyes" ; then
191    AC_SUBST(GSM_CFLAGS)
192    AC_SUBST(GSM_LIBS)
193    AC_MSG_RESULT(using system GSM)
194  fi
195  AC_SUBST(GSM_SYSTEM)
196fi
197
198
199dnl #########
200
201if test -d audio/gsm-amr ; then
202  AC_ARG_ENABLE([gsmamr],
203                [AC_HELP_STRING([--disable-gsmamr],[Disable GSM-AMR])],
204                [HAVE_GSMAMR=$enableval],
205                [HAVE_GSMAMR=yes])
206else
207  HAVE_GSMAMR=no
208fi
209if test "x${HAVE_GSMAMR}" = "xyes" ; then
210  AC_CONFIG_FILES(audio/gsm-amr/Makefile)
211  SUBDIRS+=" audio/gsm-amr"
212fi
213
214dnl #########
215
216if test -d audio/iLBC ; then
217  AC_ARG_ENABLE([iLBC],
218                [AC_HELP_STRING([--disable-iLBC],[Disable iLBC])],
219                [HAVE_iLBC=$enableval],
220                [HAVE_iLBC=yes])
221else
222  HAVE_iLBC=no
223fi
224if test "x${HAVE_iLBC}" = "xyes" ; then
225  AC_CONFIG_FILES(audio/iLBC/Makefile)
226  SUBDIRS+=" audio/iLBC"
227
228  OPAL_DETERMINE_ILBC()
229  AC_SUBST(ILBC_SYSTEM)
230  AC_SUBST(ILBC_CFLAGS)
231  AC_SUBST(ILBC_LIBS)
232fi
233
234dnl #########
235
236if test -d audio/Speex ; then
237  AC_ARG_ENABLE([speex],
238                [AC_HELP_STRING([--disable-speex],[Disable Speex])],
239                [HAVE_SPEEX=$enableval],
240                [HAVE_SPEEX=yes])
241else
242  HAVE_SPEEX=no
243fi
244if test "x${HAVE_SPEEX}" = "xyes" ; then
245  AC_OUTPUT(audio/Speex/libspeex/speex_config_types.h)
246  AC_CONFIG_FILES(audio/Speex/Makefile)
247  SUBDIRS+=" audio/Speex"
248
249  OPAL_SPEEX_TYPES()
250  AC_SUBST(SIZE16)
251  AC_SUBST(SIZE32)
252  OPAL_DETERMINE_SPEEX()
253  AC_SUBST(SPEEX_SYSTEM)
254  AC_SUBST(SPEEX_CFLAGS)
255  AC_SUBST(SPEEX_LIBS)
256fi
257
258dnl #########
259
260if test -d audio/G722 ; then
261  AC_ARG_ENABLE([g.722],
262                [AC_HELP_STRING([--disable-g.722],[Disable G.722])],
263                [HAVE_G722=$enableval],
264                [HAVE_G722=yes])
265else
266  HAVE_G722=no
267fi
268if test "x${HAVE_G722}" = "xyes" ; then
269  AC_CONFIG_FILES(audio/G722/Makefile)
270  SUBDIRS+=" audio/G722"
271fi
272
273dnl #########
274
275if test -d audio/G.722.1 ; then
276  AC_ARG_ENABLE([g.722.1],
277                [AC_HELP_STRING([--disable-g.722.1],[Disable G.722.1])],
278                [HAVE_G7221=$enableval],
279                [HAVE_G7221=yes])
280else
281  HAVE_G7221=no
282fi
283if test "x${HAVE_G7221}" = "xyes" ; then
284  AC_CONFIG_FILES(audio/G.722.1/Makefile)
285  SUBDIRS+=" audio/G.722.1"
286fi
287
288dnl #########
289
290if test -d audio/G.722.2 ; then
291  AC_ARG_ENABLE([g.722.2],
292                [AC_HELP_STRING([--disable-g.722.2],[Disable G.722.2])],
293                [HAVE_G7222=$enableval],
294                [HAVE_G7222=yes])
295else
296  HAVE_G7222=no
297fi
298if test "x${HAVE_G7222}" = "xyes" ; then
299  AC_CONFIG_FILES(audio/G.722.2/Makefile)
300  SUBDIRS+=" audio/G.722.2"
301fi
302
303dnl #########
304
305if test -d audio/G726 ; then
306  AC_ARG_ENABLE([g.726],
307                [AC_HELP_STRING([--disable-g.726],[Disable G.726])],
308                [HAVE_G726=$enableval],
309                [HAVE_G726=yes])
310else
311  HAVE_G726=no
312fi
313if test "x${HAVE_G726}" = "xyes" ; then
314  AC_CONFIG_FILES(audio/G726/Makefile)
315  SUBDIRS+=" audio/G726"
316fi
317
318dnl #########
319
320if test -d audio/LPC_10 ; then
321  AC_ARG_ENABLE([lpc10],
322                [AC_HELP_STRING([--disable-lpc10],[Disable LPC-10])],
323                [HAVE_LPC10=$enableval],
324                [HAVE_LPC10=yes])
325else
326  HAVE_LPC10=no
327fi
328if test "x${HAVE_LPC10}" = "xyes" ; then
329  AC_CONFIG_FILES(audio/LPC_10/Makefile)
330  SUBDIRS+=" audio/LPC_10"
331fi
332
333dnl #########
334
335if test -d audio/IMA_ADPCM ; then
336  AC_ARG_ENABLE([ima-adpcm],
337                [AC_HELP_STRING([--disable-ima-adpcm],[Disable IMA ADPCM])],
338                [HAVE_IMA_ADPCM=$enableval],
339                [HAVE_IMA_ADPCM=yes])
340else
341  HAVE_IMA_ADPCM=no
342fi
343if test "x${HAVE_IMA_ADPCM}" = "xyes" ; then
344  AC_CONFIG_FILES(audio/IMA_ADPCM/Makefile)
345  SUBDIRS+=" audio/IMA_ADPCM"
346fi
347
348dnl #########
349dnl sbc,Bluetooth SBC for telephony with CD quality
350
351if test -d audio/SBC -a -d audio/SBC/bluez_sbc ; then
352  AC_ARG_ENABLE([sbc],
353                [AC_HELP_STRING([--disable-sbc],[Disable Bluetooth SBC])],
354                [HAVE_SBC=$enableval],
355                [HAVE_SBC=yes])
356  if test "x${HAVE_SBC}" = "xyes" ; then
357    AC_CHECK_LIB(samplerate,src_get_version,has_samplerate=yes,has_samplerate=no)
358    HAVE_SBC=$has_samplerate
359  fi
360else
361  HAVE_SBC=no
362fi
363if test "x${HAVE_SBC}" = "xyes" ; then
364  AC_CONFIG_FILES(audio/SBC/Makefile)
365  SUBDIRS+=" audio/SBC"
366fi
367
368dnl #########
369
370if test -d audio/celt ; then
371  AC_ARG_ENABLE([celt],
372                [AC_HELP_STRING([--disable-celt],[Disable CELT])],
373                [HAVE_CELT=$enableval],
374                [HAVE_CELT=yes])
375  PKG_CHECK_MODULES([CELT],
376                    [celt],
377                    [
378                      AC_SUBST(CELT_CFLAGS)
379                      AC_SUBST(CELT_LIBS)
380                    ],
381                    [
382                      HAVE_CELT=no
383                    ])
384else
385  HAVE_CELT=no
386fi
387if test "x${HAVE_CELT}" = "xyes" ; then
388  CELT_CFLAGS="${CELT_CFLAGS} -DCELT_VERSION=\"`pkg-config --modversion celt | \
389                  sed -e "s/\./*10000+/" -e "s/\./*100+/"`\""
390  AC_CONFIG_FILES(audio/celt/Makefile)
391  SUBDIRS+=" audio/celt"
392fi
393
394dnl #########
395
396if test -d audio/SILK ; then
397  AC_ARG_ENABLE([silk],
398                [AC_HELP_STRING([--disable-silk],[Disable SILK])],
399                [HAVE_SILK=$enableval],
400                [HAVE_SILK=yes])
401else
402  HAVE_SILK=no
403fi
404if test "x${HAVE_SILK}" = "xyes" ; then
405  AC_CONFIG_FILES(audio/SILK/Makefile)
406  SUBDIRS+=" audio/SILK"
407fi
408
409
410dnl ########################################################################
411dnl Video Codecs
412dnl ########################################################################
413
414if test -d video/H.261-vic ; then
415  AC_ARG_ENABLE([h.261],
416                [AC_HELP_STRING([--disable-h.261],[Disable H.261 (vic)])],
417                [HAVE_H261=$enableval],
418                [HAVE_H261=yes])
419else
420  HAVE_H261=no
421fi
422if test "x${HAVE_H261}" = "xyes" ; then
423  AC_CONFIG_FILES(video/H.261-vic/Makefile)
424  SUBDIRS+=" video/H.261-vic"
425fi
426
427
428dnl     ########################
429dnl     Capabilities option
430dnl     ########################
431OPAL_SIMPLE_OPTION([default-to-full-capabilties],[DEFAULT_TO_FULL_CAPABILITIES], [default to full capabilities at empty fmtp lines])
432
433dnl     ########################
434dnl     libavcodec (ffmpeg)
435dnl     ########################
436AC_ARG_ENABLE([libavcodec],
437              [AC_HELP_STRING([--disable-libavcodec],[disable libavcodec support])],
438              [HAVE_LIBAVCODEC=$enableval])
439
440if test "x$HAVE_LIBAVCODEC" = "xno" ; then
441  AC_MSG_RESULT(Manually disabled libavcodec support)
442else
443  PKG_CHECK_MODULES([LIBAVCODEC],
444                    [libavcodec >= 51.11.0],
445                    [
446                     AC_SUBST(LIBAVCODEC_CFLAGS)
447                     AC_SUBST(LIBAVCODEC_LIBS)
448                     AC_DEFINE([HAVE_LIBAVCODEC], [1], [ffmpeg])
449                     OPAL_GET_LIBNAME([LIBAVCODEC], [libavcodec], [$LIBAVCODEC_LIBS])
450                     AC_SUBST(LIBAVCODEC_LIB_NAME)
451                     case "$target_os" in
452                        cygwin* | mingw* )
453                                           LIBAVCODEC_LIB_NAME="avcodec.dll"
454                                           ;;
455                     esac
456                     HAVE_LIBAVCODEC=yes
457                    ],
458                    [
459                     HAVE_LIBAVCODEC=no
460                    ]
461                   )
462fi
463
464if test "x$HAVE_LIBAVCODEC" = "xyes" ; then
465  OPAL_LIBAVCODEC_SOURCE()
466
467  PKG_CHECK_MODULES(
468    [LIBAVUTIL],
469    [libavutil],
470    [
471      AC_SUBST(LIBAVUTIL_CFLAGS)
472      AC_SUBST(LIBAVUTIL_LIBS)
473      OPAL_GET_LIBNAME([LIBAVUTIL], [libavutil], [$LIBAVUTIL_LIBS])
474      AC_SUBST(LIBAVUTIL_LIB_NAME)
475    ]
476  )
477
478  AC_MSG_CHECKING(if libavcodec has rtp_mode);
479  AC_COMPILE_IFELSE(
480    [
481      AC_LANG_PROGRAM(
482        [[#include "libavcodec/avcodec.h"]],
483        [[AVCodecContext c; c.rtp_mode = 1; ]]
484      )
485    ],
486    [
487      HAVE_LIBAVCODEC_RTP_MODE=1
488      AC_MSG_RESULT(yes);
489    ],
490    [
491      AC_MSG_RESULT(no)
492    ]
493  )
494
495  AC_MSG_CHECKING(if libavutil has AV_PICTURE_TYPE_NONE);
496  CFLAGS="$CFLAGS $LIBAVUTIL_CFLAGS"
497  AC_COMPILE_IFELSE(
498    [
499      AC_LANG_PROGRAM(
500        [[#include "libavcodec/avcodec.h"
501          #include <libavutil/avutil.h>]],
502        [[enum AVPictureType t = AV_PICTURE_TYPE_NONE; ]]
503      )
504    ],
505    [
506      AC_MSG_RESULT(yes);
507    ],
508    [
509      AC_MSG_RESULT(no)
510      AC_MSG_CHECKING(if libavutil has AVPictureType);
511      AC_COMPILE_IFELSE(
512        [
513          AC_LANG_PROGRAM(
514            [[#include "libavcodec/avcodec.h"]],
515            [[enum AVPictureType t; ]]
516          )
517        ],
518        [
519          AC_MSG_RESULT(yes);
520          AC_DEFINE([AV_PICTURE_TYPE_NONE], [(AVPictureType)0])
521        ],
522        [
523          AC_MSG_RESULT(no)
524          AC_DEFINE([AV_PICTURE_TYPE_NONE], [0])
525        ]
526      )
527    ]
528  )
529fi
530
531AC_SUBST(HAVE_LIBAVCODEC)
532AC_SUBST(LIBAVCODEC_SOURCE_DIR)
533AC_SUBST(HAVE_LIBAVCODEC_RTP_MODE)
534
535if test "x${HAVE_LIBAVCODEC}" = "xyes"; then
536  AC_CONFIG_FILES(video/H.263-1998/Makefile)
537  SUBDIRS+=" video/H.263-1998"
538fi
539
540if test "x${HAVE_LIBAVCODEC}" = "xyes"; then
541  AC_CONFIG_FILES(video/MPEG4-ffmpeg/Makefile)
542  SUBDIRS+=" video/MPEG4-ffmpeg"
543fi
544
545
546dnl     ########################
547dnl     x264
548dnl     ########################
549HAVE_H264=no
550IS_H264_LICENSED=no
551AC_SUBST(IS_H264_LICENSED)
552
553if test "x${HAVE_LIBAVCODEC}" = "xno"; then
554  AC_MSG_RESULT(H.264 not built since libavcodec support is disabled)
555else
556  AC_ARG_ENABLE([x264],
557                [AC_HELP_STRING([--disable-x264],[disable x264 support])],
558                [HAVE_H264=$enableval],
559                [PKG_CHECK_MODULES([X264],
560                                   [x264 >= 0.102],
561                                   [
562				     HAVE_H264=yes
563                                     AC_SUBST(X264_CFLAGS)
564                                     AC_SUBST(X264_LIBS)
565                                     OPAL_GET_LIBNAME([X264], [libx264], [$X264_LIBS])
566                                     AC_SUBST(X264_LIB_NAME)
567                                     OPAL_X264_LINKAGE
568                                   ],
569                                   [
570                                     HAVE_H264=no
571                                   ])
572                ])
573fi
574
575if test "x$HAVE_H264" = "xyes" ; then
576  AC_ARG_ENABLE([x264-licensed],
577                [AC_HELP_STRING([--enable-x264-licensed],[enable commercially licensed x264 support])],
578                [IS_H264_LICENSED=$enableval])
579
580  SUBDIRS+=" video/H.264"
581  AC_CONFIG_FILES(video/H.264/Makefile)
582  AC_CONFIG_FILES(video/H.264/gpl/Makefile)
583fi
584
585
586dnl     ########################
587dnl     theora
588dnl     ########################
589if test -d video/THEORA ; then
590  AC_ARG_ENABLE([theora],
591                [AC_HELP_STRING([--disable-theora],[disable Theora support])],
592                [HAVE_THEORA=$enableval],
593                [HAVE_THEORA=yes])
594  PKG_CHECK_MODULES([THEORA],
595                    [theora],
596                    [
597                     AC_SUBST(THEORA_CFLAGS)
598                     AC_SUBST(THEORA_LIBS)
599                    ],
600                    [
601                     HAVE_THEORA=no
602                    ])
603else
604  HAVE_THEORA=no
605fi
606if test "x$HAVE_THEORA" = "xyes" ; then
607  AC_CONFIG_FILES(video/THEORA/Makefile)
608  SUBDIRS+=" video/THEORA"
609fi
610
611
612dnl ########################################################################
613dnl LID Devices
614dnl ########################################################################
615
616dnl     ########################
617dnl     Quicknet xJACK cards
618dnl     #######################
619if test -d LID/IxJ ; then
620  AC_ARG_ENABLE([ixj],
621                [AC_HELP_STRING([--enable-ixj],[enable xJack cards])],
622                [HAVE_IXJ=$enableval])
623  if test "x$HAVE_IXJ" = "xyes" ; then
624    OPAL_MSG_CHECK([IXJ], [$HAVE_IXJ])
625    if test "x$HAVE_IXJ" = "xyes" ; then
626      AC_CHECK_HEADERS([linux/telephony.h],
627                     [HAVE_IXJ=yes],
628                     [AC_CHECK_HEADERS([ sys/telephony.h], [HAVE_IXJ=yes], [HAVE_IXJ=no])])
629      if test "x$HAVE_IXJ" = "xyes" ; then
630        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ixjuser.h>]], [[ return 0; ]])],
631                          [HAVE_IXJ=yes], [HAVE_IXJ=no])
632      fi
633    fi
634  fi
635  OPAL_MSG_CHECK([IXJ], [$HAVE_IXJ])
636else
637  HAVE_IXJ=no
638fi
639
640if test "x$HAVE_IXJ" = "xyes" ; then
641  AC_CONFIG_FILES(LID/IxJ/Makefile)
642  SUBDIRS+=" LID/IxJ"
643fi
644
645dnl     ########################
646dnl     VoiceTronics VPB card
647dnl     ########################
648if test -d LID/VPB ; then
649  OPAL_SIMPLE_OPTION([vpb],[HAVE_VPB], [enable voicetronix vpb])
650fi
651if test "x$HAVE_VPB" = "xyes" ; then
652  AC_CONFIG_FILES(LID/VPB/Makefile)
653  SUBDIRS+=" LID/VPB"
654fi
655
656
657
658dnl ########################################################################
659dnl FAX Devices
660dnl ########################################################################
661
662dnl     ########################
663dnl     spanDSP
664dnl     ########################
665if test -d fax/fax_spandsp ; then
666  AC_ARG_ENABLE([spandsp],
667                [AC_HELP_STRING([--enable-spandsp],[enable spanDSP-based fax support])],
668                [HAVE_SPANDSP=$enableval])
669  if test "x${HAVE_SPANDSP}" = "xyes" ; then
670    OPAL_FIND_SPANDSP([HAVE_SPANDSP=yes], [HAVE_SPANDSP=no])
671  fi
672else
673  HAVE_SPANDSP=no
674fi
675
676if test "x$HAVE_SPANDSP" = "xyes" ; then
677  AC_CONFIG_FILES(fax/fax_spandsp/Makefile)
678  SUBDIRS+=" fax/fax_spandsp"
679fi
680
681
682dnl ########################################################################
683dnl Various checks
684dnl ########################################################################
685
686AC_LANG_PUSH([C++])
687AC_MSG_CHECKING(for posix_memalign)
688AC_COMPILE_IFELSE([
689  AC_LANG_PROGRAM([[#include <stdlib.h>]],
690                  [[
691                  void * p; posix_memalign(&p, 16, 16); return 0;
692                  ]]
693                  )
694                  ],
695  AC_MSG_RESULT(yes)
696  AC_DEFINE(HAVE_POSIX_MEMALIGN, 1, [Is posix_memalign supported]),
697  AC_MSG_RESULT(no)
698)
699AC_LANG_POP([C++])
700
701dnl ########################################################################
702
703AC_CONFIG_FILES(Makefile)
704
705dnl ########################################################################
706dnl Header file
707
708dnl ########################################################################
709dnl Output configured files
710
711AC_CONFIG_FILES(plugin-inc.mak)
712AC_CONFIG_HEADERS(plugin-config.h)
713AC_OUTPUT()
714
715dnl ########################################################################
716dnl Summary
717dnl ########################################################################
718echo ""
719echo "=================== Plugin configuration ======================"
720echo " prefix                           : $prefix"
721echo " exec_prefix                      : $exec_prefix"
722echo " libdir                           : $libdir"
723echo " Audio Codec plugin install dir   : "'${libdir}'"/$AC_PLUGIN_DIR"
724echo " Video Codec plugin install prefix: "'${libdir}'"/$VC_PLUGIN_DIR"
725echo " LID plugin install prefix        : "'${libdir}'"/$LID_PLUGIN_DIR"
726echo " FAX plugin install prefix        : "'${libdir}'"/$FAX_PLUGIN_DIR"
727
728echo ""
729
730if test "x${HAVE_GSM0610}" = "xno" ; then
731echo "                              GSM :  no"
732elif test "x${GSM_SYSTEM}" = "xyes" ; then
733echo "                              GSM :  yes (system)"
734else
735echo "                              GSM :  yes (internal)"
736fi
737
738echo "                          GSM-AMR :  ${HAVE_GSMAMR}"
739
740if test "x${HAVE_iLBC}" = "xno" ; then
741echo "                             iLBC :  no"
742elif test "x${ILBC_SYSTEM}" = "xyes" ; then
743echo "                             iLBC :  yes (system)"
744else
745echo "                             iLBC :  yes (internal)"
746fi
747
748if test "x${HAVE_SPEEX}" = "xno" ; then
749echo "                            Speex :  no"
750elif test "x${SPEEX_SYSTEM}" = "xyes" ; then
751echo "                            Speex :  yes (system, version $SPEEX_SYSTEM_VERSION)"
752else
753echo "                            Speex :  yes (internal, version $SPEEX_INTERNAL_VERSION)"
754fi
755
756echo "                            G.722 :  ${HAVE_G722}"
757echo "                          G.722.1 :  ${HAVE_G7221}"
758echo "                          G.722.2 :  ${HAVE_G7222}"
759echo "                            G.726 :  ${HAVE_G726}"
760echo "                            LPC10 :  ${HAVE_LPC10}"
761echo "                        IMA_ADPCM :  ${HAVE_IMA_ADPCM}"
762echo "                              SBC :  ${HAVE_SBC}"
763echo "                             CELT :  ${HAVE_CELT}"
764echo "                             SILK :  ${HAVE_SILK}"
765
766echo ""
767
768echo "                           H.261  :  ${HAVE_H261} (vic)"
769echo "                     H.263/H.263+ :  ${HAVE_LIBAVCODEC} (ffmpeg)"
770
771if test "x${HAVE_H264}" = "xno" ; then
772echo "                           H.264  :  no"
773elif test "x${IS_H264_LICENSED}" = "xno" ; then
774echo "                           H.264  :  yes (GPL x264)"
775else
776echo "                           H.264  :  yes (Licensed x264)"
777fi
778
779echo "                          THEORA  :  ${HAVE_THEORA}"
780
781if test "x${HAVE_LIBAVCODEC}" = "xyes" ; then
782if test "x${LIBAVCODEC_SOURCE_DIR}" = "x" ; then
783echo "                    MPEG4 Part 2  :  yes (no rate control correction)"
784else
785echo "                    MPEG4 Part 2  :  yes"
786fi
787else
788echo "                    MPEG4 Part 2  :  no"
789fi
790
791echo ""
792echo "                     SpanDSP FAX  :  $HAVE_SPANDSP"
793
794echo ""
795
796echo "           Quicknet xJACK support :  $HAVE_IXJ"
797echo "         Voicetronics VPB support :  $HAVE_VPB"
798
799echo ""
800
801echo "                         OS Type  :  $target_os"
802echo "                    Machine Type  :  $target_cpu"
803echo ""
804echo " If all settings are OK, type make and make install "
805echo "========================================================"
806