1AC_DEFUN([MP_WITH_CURSES],
2  [AC_ARG_WITH(ncurses, AC_HELP_STRING([--with-ncurses ],[Force the use of ncurses over curses ]),,)
3   mp_save_LIBS="$LIBS"
4   CURSES_LIB=""
5   if test "$with_ncurses" != yes
6   then
7     AC_CACHE_CHECK([for working curses], mp_cv_curses,
8       [LIBS="$LIBS -lcurses"
9        AC_TRY_LINK(
10          [#include <curses.h>],
11          [chtype a; int b=A_STANDOUT, c=KEY_LEFT; initscr(); ],
12          mp_cv_curses=yes, mp_cv_curses=no)])
13     if test "$mp_cv_curses" = yes
14     then
15       AC_DEFINE(HAVE_CURSES_H)
16       CURSES_LIB="-lcurses"
17     fi
18   fi
19   if test ! "$CURSES_LIB"
20   then
21     AC_CACHE_CHECK([for working ncurses], mp_cv_ncurses,
22       [LIBS="$mp_save_LIBS -lncurses"
23        AC_TRY_LINK(
24          [#include <ncurses.h>],
25          [chtype a; int b=A_STANDOUT, c=KEY_LEFT; initscr(); ],
26          mp_cv_ncurses=yes, mp_cv_ncurses=no)])
27     if test "$mp_cv_ncurses" = yes
28     then
29       AC_DEFINE(HAVE_NCURSES_H)
30       CURSES_LIB="-lncurses"
31     fi
32   fi
33   LIBS="$mp_save_LIBS"
34])dnl
35