1# ===========================================================================
2#       http://www.gnu.org/software/autoconf-archive/ax_is_release.html
3# ===========================================================================
4#
5# SYNOPSIS
6#
7#   AX_IS_RELEASE(POLICY)
8#
9# DESCRIPTION
10#
11#   Determine whether the code is being configured as a release, or from
12#   git. Set the ax_is_release variable to 'yes' or 'no'.
13#
14#   If building a release version, it is recommended that the configure
15#   script disable compiler errors and debug features, by conditionalising
16#   them on the ax_is_release variable.  If building from git, these
17#   features should be enabled.
18#
19#   The POLICY parameter specifies how ax_is_release is determined. It can
20#   take the following values:
21#
22#    * git-directory:  ax_is_release will be 'no' if a '.git' directory exists
23#    * minor-version:  ax_is_release will be 'no' if the minor version number
24#                      in $PACKAGE_VERSION is odd; this assumes
25#                      $PACKAGE_VERSION follows the 'major.minor.micro' scheme
26#    * micro-version:  ax_is_release will be 'no' if the micro version number
27#                      in $PACKAGE_VERSION is odd; this assumes
28#                      $PACKAGE_VERSION follows the 'major.minor.micro' scheme
29#    * always:         ax_is_release will always be 'yes'
30#    * never:          ax_is_release will always be 'no'
31#
32#   Other policies may be added in future.
33#
34# LICENSE
35#
36#   Copyright (c) 2015 Philip Withnall <philip@tecnocode.co.uk>
37#
38#   Copying and distribution of this file, with or without modification, are
39#   permitted in any medium without royalty provided the copyright notice
40#   and this notice are preserved.
41
42#serial 3
43
44AC_DEFUN([AX_IS_RELEASE],[
45    AC_BEFORE([AC_INIT],[$0])
46
47    m4_case([$1],
48      [git-directory],[
49        # $is_release = (.git directory does not exist)
50        AS_IF([test -d .git],[ax_is_release=no],[ax_is_release=yes])
51      ],
52      [minor-version],[
53        # $is_release = ($minor_version is even)
54        minor_version=`echo "$PACKAGE_VERSION" | sed 's/[[^.]][[^.]]*.\([[^.]][[^.]]*\).*/\1/'`
55        AS_IF([test "$(( $minor_version % 2 ))" -ne 0],
56              [ax_is_release=no],[ax_is_release=yes])
57      ],
58      [micro-version],[
59        # $is_release = ($micro_version is even)
60        micro_version=`echo "$PACKAGE_VERSION" | sed 's/[[^.]]*\.[[^.]]*\.\([[^.]]*\).*/\1/'`
61        AS_IF([test "$(( $micro_version % 2 ))" -ne 0],
62              [ax_is_release=no],[ax_is_release=yes])
63      ],
64      [always],[ax_is_release=yes],
65      [never],[ax_is_release=no],
66      [
67        AC_MSG_ERROR([Invalid policy. Valid policies: git-directory, minor-version.])
68      ])
69])
70