1gsd_xsettings_gtk = files('gsd-xsettings-gtk.c')
2
3fc_monitor = files('fc-monitor.c')
4
5wm_button_layout_translation = files('wm-button-layout-translation.c')
6
7sources = gsd_xsettings_gtk + fc_monitor + wm_button_layout_translation + files(
8  'gsd-xsettings-manager.c',
9  'xsettings-common.c',
10  'xsettings-manager.c',
11  'main.c'
12)
13
14deps = plugins_deps + [
15  gtk_dep,
16  x11_dep,
17  dependency('fontconfig')
18]
19
20cflags += ['-DGTK_MODULES_DIRECTORY="@0@"'.format(join_paths(gsd_pkglibdir, 'gtk-modules'))]
21
22executable(
23  'gsd-' + plugin_name,
24  sources,
25  include_directories: [top_inc, common_inc, data_inc],
26  dependencies: deps,
27  c_args: cflags,
28  install: true,
29  install_rpath: gsd_pkglibdir,
30  install_dir: gsd_libexecdir
31)
32
33programs = [
34  ['test-gtk-modules', gsd_xsettings_gtk + ['test-gtk-modules.c'], cflags],
35  ['test-fontconfig-monitor', fc_monitor, cflags + ['-DFONTCONFIG_MONITOR_TEST']],
36  ['test-wm-button-layout-translations', wm_button_layout_translation + ['test-wm-button-layout-translations.c'], []]
37]
38
39foreach program: programs
40  executable(
41    program[0],
42    program[1],
43    include_directories: top_inc,
44    dependencies: deps,
45    c_args: program[2]
46  )
47endforeach
48
49install_data(
50  files('00-xrdb'),
51  install_dir: join_paths(gsd_sysconfdir, 'xdg/Xwayland-session.d')
52)
53
54test_py = find_program('test.py')
55
56envs = [
57  'BUILDDIR=' + meson.current_build_dir(),
58  'TOP_BUILDDIR=' + meson.build_root()
59]
60
61test(
62  'test-xsettings',
63  test_py,
64  env: envs,
65  timeout: 300
66)
67