1AC_INIT([mate-control-center], [1.26.0], [http://www.mate-desktop.org/])
2
3AC_CONFIG_MACRO_DIR([m4])
4AC_CONFIG_SRCDIR([shell])
5AC_CONFIG_HEADERS([config.h])
6
7AM_INIT_AUTOMAKE([1.9 no-dist-gzip dist-xz tar-ustar])
8AM_MAINTAINER_MODE
9m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
10
11MATE_COMMON_INIT
12MATE_DEBUG_CHECK
13MATE_COMPILE_WARNINGS
14MATE_MAINTAINER_MODE_DEFINES
15
16AC_PROG_CC
17AM_PROG_CC_C_O
18AC_STDC_HEADERS
19AM_PROG_LIBTOOL
20AC_PATH_PROG([GLA11Y], [gla11y], [true])
21
22# Use the Yelp documentation framework
23YELP_HELP_INIT
24
25# Internationalization support
26AM_GNU_GETTEXT([external])
27AM_GNU_GETTEXT_VERSION([0.19.8])
28AM_CONDITIONAL([USE_NLS], [test "x${USE_NLS}" = "xyes"])
29
30GETTEXT_PACKAGE=mate-control-center
31AC_SUBST(GETTEXT_PACKAGE)
32AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
33
34# GLIB_COMPILE_RESOURCES
35
36AC_ARG_VAR([GLIB_COMPILE_RESOURCES],[glib-compile-resources bin])
37AC_PATH_PROG([GLIB_COMPILE_RESOURCES],[glib-compile-resources],[])
38if test -z "$GLIB_COMPILE_RESOURCES"; then
39  AC_MSG_ERROR([glib-compile-resources not found])
40fi
41
42# XMLLINT
43
44AC_ARG_VAR([XMLLINT],[xmllint bin])
45AC_PATH_PROG([XMLLINT],[xmllint],[])
46if test -z "$XMLLINT"; then
47  AC_MSG_ERROR([xmllint not found])
48fi
49
50AC_PATH_XTRA
51x_libs="$X_PRE_LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
52
53AC_CHECK_FUNC(XScreenSaverQueryInfo, [
54  TYPING_BREAK="typing-break"], [
55  save_LIBS=$LIBS
56  LIBS="$LIBS $X_PRE_LIBS $X_LIBS -lXss -lXext -lX11"
57  AC_CHECK_LIB(Xss, XScreenSaverQueryInfo, [
58    TYPING_BREAK="typing-break"
59    SCREENSAVER_LIBS="$X_PRE_LIBS $X_LIBS -lXss -lXext -lX11"], [
60    LIBS=$save_LIBS
61    LIBS="$LIBS $X_PRE_LIBS $X_LIBS -lXext -lX11"
62    AC_CHECK_LIB(Xext, XScreenSaverQueryInfo, [
63      TYPING_BREAK="typing-break"
64      SCREENSAVER_LIBS="$X_PRE_LIBS $X_LIBS -lXext -lX11"],[])])
65  LIBS=$save_LIBS])
66AC_SUBST(TYPING_BREAK)
67AC_SUBST(SCREENSAVER_LIBS)
68
69GLIB_REQUIRED=2.50.0
70GTK_REQUIRED=3.22.0
71MARCO_REQUIRED=1.17.0
72MATEKBD_REQUIRED=1.17.0
73MATE_DESKTOP_REQUIRED=1.25.0
74APPINDICATOR_REQUIRED=0.0.13
75
76ENGINES_FOLDER="theming-engines"
77
78PKG_CHECK_MODULES(LIBCANBERRA_GTK, libcanberra-gtk3, [
79    CANBERRA_GTK=1
80    AC_SUBST(LIBCANBERRA_GTK_CFLAGS)
81    AC_SUBST(LIBCANBERRA_GTK_LIBS)
82    ], [:])
83AM_CONDITIONAL(HAVE_LIBCANBERRA_GTK, test "x$CANBERRA_GTK" = "x1")
84
85AM_CONDITIONAL(HAVE_TYPING_BREAK, test "x$TYPING_BREAK" = xtyping-break)
86
87dnl app indicator
88APPINDICATOR_PKG=appindicator3-0.1
89
90AC_ARG_ENABLE(appindicator,
91                        AS_HELP_STRING([--enable-appindicator[=@<:@no/auto/yes@:>@]],[Build support for application indicators ]),
92                        [enable_appindicator=$enableval],
93                        [enable_appindicator="auto"])
94
95if test x$enable_appindicator = xauto ; then
96        PKG_CHECK_EXISTS([$APPINDICATOR_PKG >= $APPINDICATOR_REQUIRED],
97                         enable_appindicator="yes",
98                         enable_appindicator="no")
99fi
100
101if test x$enable_appindicator = xyes ; then
102        PKG_CHECK_EXISTS([$APPINDICATOR_PKG >= $APPINDICATOR_REQUIRED],,
103                         AC_MSG_ERROR([appindicator-0.1 is not installed]))
104        PKG_CHECK_MODULES(APP_INDICATOR,
105                        $APPINDICATOR_PKG >= $APPINDICATOR_REQUIRED)
106        AC_SUBST(APP_INDICATOR_CFLAGS)
107        AC_SUBST(APP_INDICATOR_LIBS)
108        AC_DEFINE(HAVE_APP_INDICATOR, 1, [Have AppIndicator])
109fi
110AM_CONDITIONAL(HAVE_APP_INDICATOR, test x"$enable_appindicator" = xyes)
111
112dnl keyboard-properties-capplet
113savecppflags=$CPPFLAGS
114CPPFLAGS="$CPPFLAGS $X_CFLAGS"
115AC_CHECK_HEADERS([X11/Xlib.h])
116AC_CHECK_HEADERS(X11/extensions/XKB.h)
117CPPFLAGS=$savecppflags
118
119AC_CHECK_LIB(m, floor)
120
121dnl ==============================================
122dnl Check that we meet the  dependencies
123dnl ==============================================
124
125PKG_CHECK_MODULES(GMODULE,gmodule-2.0,[GMODULE_ADD="gmodule-2.0"],[GMODULE_ADD=""])
126COMMON_MODULES="gtk+-3.0 >= $GTK_REQUIRED dnl
127 $GMODULE_ADD dnl
128 glib-2.0 >= $GLIB_REQUIRED dnl
129 gthread-2.0 dnl
130 gio-2.0 dnl
131 gio-unix-2.0 dnl
132 libxml-2.0 dnl
133 mate-desktop-2.0 >= $MATE_DESKTOP_REQUIRED"
134PKG_CHECK_MODULES(CAPPLET, $COMMON_MODULES)
135PKG_CHECK_MODULES(MATECC, $COMMON_MODULES libmate-menu >= 1.21.0)
136PKG_CHECK_MODULES(MATECC_SHELL, $COMMON_MODULES libmate-menu)
137
138PKG_CHECK_MODULES(POLKIT, polkit-gobject-1)
139PKG_CHECK_MODULES(MATE_DESKTOP, mate-desktop-2.0 >= $MATE_DESKTOP_REQUIRED)
140PKG_CHECK_MODULES(DEFAULT_APPLICATIONS_CAPPLET, libxml-2.0)
141PKG_CHECK_MODULES(MARCO, libmarco-private >= $MARCO_REQUIRED)
142PKG_CHECK_MODULES(TYPING, $GMODULE_ADD glib-2.0 >= $GLIB_REQUIRED gio-2.0 gtk+-3.0 >= $GTK_REQUIRED)
143PKG_CHECK_MODULES(GIO, gio-2.0)
144
145PKG_CHECK_MODULES([DCONF], [dconf >= 0.13.4])
146AC_SUBST(DCONF_CFLAGS)
147AC_SUBST(DCONF_LIBS)
148
149gtk_lib_dir=`$PKG_CONFIG --variable libdir gtk+-3.0`
150gtk_binary_version=`$PKG_CONFIG --variable gtk_binary_version gtk+-3.0`
151GTK_ENGINE_DIR="$gtk_lib_dir/gtk-3.0/$gtk_binary_version/$ENGINES_FOLDER"
152AC_SUBST(GTK_ENGINE_DIR)
153
154PKG_CHECK_MODULES(GLIB, glib-2.0 >= $GLIB_REQUIRED $GMODULE_ADD)
155
156dnl
157dnl Check dependencies of libmate-slab
158dnl
159PKG_CHECK_MODULES(LIBSLAB, [
160			   gio-2.0 mate-desktop-2.0 librsvg-2.0 libmate-menu pango
161			   ],
162			   have_libmateslab=yes,
163			   have_libmateslab=no)
164
165AC_SUBST(LIBMATESLAB_CFLAGS)
166AC_SUBST(LIBMATESLAB_LIBS)
167AC_SUBST(WARN_CFLAGS)
168
169AM_CONDITIONAL(HAVE_LIBMATESLAB, [test $have_libmateslab = yes])
170
171dnl
172dnl Check dependencies of accountsservice
173dnl
174
175ACCOUNTSSERVICE_REQUIRED=0.6.21
176
177AC_ARG_WITH([accountsservice], AC_HELP_STRING([--without-accountsservice], [disable accountsservice support]))
178have_accountsservice=no
179if test x$with_accountsservice != xno; then
180    PKG_CHECK_MODULES(ACCOUNTSSERVICE, accountsservice >= $ACCOUNTSSERVICE_REQUIRED, have_accountsservice=yes, have_accountsservice=no)
181fi
182if test "x$have_accountsservice" = "xyes"; then
183  AC_DEFINE(HAVE_ACCOUNTSSERVICE, 1, [ACCOUNTSSERVICE Support.])
184fi
185
186AM_CONDITIONAL([HAVE_ACCOUNTSSERVICE], [test "x$have_accountsservice" = xyes])
187
188
189PKG_CHECK_MODULES(FONT_CAPPLET, $COMMON_MODULES pango)
190PKG_CHECK_MODULES(FONT_VIEWER, $COMMON_MODULES fontconfig freetype2 mate-desktop-2.0)
191
192PKG_CHECK_MODULES(AT_CAPPLET, $COMMON_MODULES)
193
194PKG_CHECK_MODULES(DISPLAY_CAPPLET, $COMMON_MODULES)
195DISPLAY_CAPPLET_LIBS="$DISPLAY_CAPPLET_LIBS"
196
197CAPPLET_LIBS="$CAPPLET_LIBS $x_libs"
198MATECC_LIBS="$MATECC_LIBS $x_libs"
199
200PKG_CHECK_MODULES(XCURSOR, xcursor)
201XCURSOR_ICONDIR=$($PKG_CONFIG --variable=icondir xcursor)
202AC_DEFINE_UNQUOTED(XCURSOR_ICONDIR, "${XCURSOR_ICONDIR}", [Define to the xcursor icon path])
203
204CAPPLET_LIBS="$CAPPLET_LIBS $XCURSOR_LIBS"
205
206dnl ======================
207dnl X Input library >= 1.5
208dnl ======================
209
210PKG_CHECK_MODULES(XINPUT, xi >= 1.5)
211
212CAPPLET_LIBS="$CAPPLET_LIBS $XINPUT_LIBS"
213
214PKG_CHECK_MODULES(LIBMATEKBD, [libmatekbd >= $MATEKBD_REQUIRED libxklavier >= 5.2])
215AC_SUBST(LIBMATEKBD_CFLAGS)
216AC_SUBST(LIBMATEKBD_LIBS)
217
218PKG_CHECK_MODULES(LIBMATEKBDUI, [libmatekbdui >= $MATEKBD_REQUIRED])
219AC_SUBST(LIBMATEKBDUI_CFLAGS)
220AC_SUBST(LIBMATEKBDUI_LIBS)
221
222dnl ==============================================
223dnl End: Check that we meet the  dependencies
224dnl ==============================================
225
226AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
227
228if test x"$GLIB_GENMARSHAL" = xno; then
229  AC_MSG_ERROR([glib-genmarshal executable not found in your path - should be installed with glib])
230fi
231
232AC_SUBST(GLIB_GENMARSHAL)
233
234dnl ==============================================
235dnl Special GSettings section
236dnl ==============================================
237
238GLIB_GSETTINGS
239
240dnl ==============================================
241dnl Define the main variables
242dnl ==============================================
243COMMON_CFLAGS="-I\$(top_srcdir)/capplets/common"
244COMMON_LIBS="\$(top_builddir)/capplets/common/libcommon.la"
245
246EXTRA_CFLAGS="-I\$(top_srcdir)/ -DG_LOG_DOMAIN=\"\\\"\$(cappletname)-properties\\\"\""
247
248MATECC_CAPPLETS_CFLAGS="${COMMON_CFLAGS} ${CAPPLET_CFLAGS} ${EXTRA_CFLAGS} ${POLKIT_CFLAGS}"
249MATECC_CAPPLETS_LIBS="${COMMON_LIBS} ${CAPPLET_LIBS} ${POLKIT_LIBS}"
250
251MATECC_CAPPLETS_CLEANFILES="\$(desktop) \$(desktop).in"
252MATECC_CAPPLETS_EXTRA_DIST="ChangeLog \$(desktop).in.in \$(cappletname)-capplet.png \$(pixmaps_DATA)"
253
254AC_SUBST(MATECC_CAPPLETS_EXTRA_DIST)
255AC_SUBST(MATECC_CAPPLETS_CLEANFILES)
256AC_SUBST(MATECC_CAPPLETS_CFLAGS)
257AC_SUBST(MATECC_CAPPLETS_LIBS)
258
259dnl =======================================
260dnl Update Mime Database
261dnl =======================================
262
263AC_PATH_PROG(UPDATE_MIME_DATABASE, update-mime-database, no)
264
265AC_ARG_ENABLE(update-mimedb,
266   AC_HELP_STRING([--disable-update-mimedb],
267                   [do not update mime database after installation]),,
268                   enable_update_mimedb=yes)
269AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x$enable_update_mimedb = xyes)
270
271AC_CONFIG_FILES([
272Makefile
273org.mate.control-center.gschema.xml
274org.mate.control-center.keybinding.gschema.xml
275capplets/Makefile
276capplets/about-me/Makefile
277capplets/accessibility/Makefile
278capplets/accessibility/at-properties/Makefile
279capplets/appearance/Makefile
280capplets/appearance/data/Makefile
281capplets/common/Makefile
282capplets/default-applications/Makefile
283capplets/default-applications/mate-default-applications.pc
284capplets/default-applications/icons/Makefile
285capplets/display/Makefile
286capplets/keybindings/Makefile
287capplets/keybindings/mate-keybindings.pc
288capplets/keyboard/Makefile
289capplets/mouse/Makefile
290capplets/network/Makefile
291capplets/time-admin/Makefile
292capplets/time-admin/src/Makefile
293capplets/time-admin/data/Makefile
294capplets/windows/Makefile
295font-viewer/Makefile
296help/Makefile
297libwindow-settings/Makefile
298libwindow-settings/mate-window-settings-2.0.pc
299man/Makefile
300po/Makefile.in
301libslab/mate-slab.pc
302libslab/Makefile
303shell/Makefile
304typing-break/Makefile
305])
306
307dnl due to a bug in intltool we need to expand something from the root last control-center.spec
308AC_OUTPUT
309
310dnl ---------------------------------------------------------------------------
311dnl - Show summary
312dnl ---------------------------------------------------------------------------
313
314echo "
315Configure summary:
316
317        ${PACKAGE_STRING}
318        `echo $PACKAGE_STRING | sed "s/./=/g"`
319
320        Compiler:                  ${CC}
321        Compiler flags:            ${CFLAGS}
322        Warning flags:             ${WARN_CFLAGS}
323        Linker flags:              ${LDFLAGS}
324
325        Appindicator:              ${enable_appindicator}
326        Libmate-slab:              ${have_libmateslab}
327        Accountsservice:           ${have_accountsservice}
328        Native Language support:   ${USE_NLS}
329"
330