1option(host_build)
2
3QT = core qmldevtools-private
4DEFINES += QT_NO_CAST_TO_ASCII QT_NO_CAST_FROM_ASCII
5
6SOURCES += main.cpp
7include(../shared/shared.pri)
8
9load(cmake_functions)
10
11CMAKE_BIN_DIR = $$cmakeRelativePath($$[QT_HOST_BINS], $$[QT_INSTALL_PREFIX])
12contains(CMAKE_BIN_DIR, "^\\.\\./.*") {
13    CMAKE_BIN_DIR = $$[QT_HOST_BINS]/
14    CMAKE_BIN_DIR_IS_ABSOLUTE = True
15}
16
17CMAKE_QML_DIR = $$cmakeRelativePath($$[QT_INSTALL_QML], $$[QT_INSTALL_PREFIX])
18contains(CMAKE_QML_DIR, "^\\.\\./.*") {
19    CMAKE_QML_DIR = $$[QT_INSTALL_QML]/
20    CMAKE_QML_DIR_IS_ABSOLUTE = True
21}
22load(qt_build_paths)
23
24static|staticlib:CMAKE_STATIC_TYPE = true
25
26# Compute the platform target suffix.
27CMAKE_QML_PLUGIN_SUFFIX_RELEASE =
28win32: CMAKE_QML_PLUGIN_SUFFIX_DEBUG = d
29else:darwin: CMAKE_QML_PLUGIN_SUFFIX_DEBUG = _debug
30else: CMAKE_QML_PLUGIN_SUFFIX_DEBUG =
31
32# Find out which configurations should be handled in the generated Config.cmake file.
33CMAKE_DEBUG_TYPE =
34CMAKE_RELEASE_TYPE =
35if(qtConfig(debug_and_release)|contains(QT_CONFIG, debug, debug|release)): CMAKE_DEBUG_TYPE = debug
36if(qtConfig(debug_and_release)|contains(QT_CONFIG, release, debug|release)): CMAKE_RELEASE_TYPE = release
37
38qtConfig(debug_and_release) {
39    CMAKE_DEBUG_AND_RELEASE = TRUE
40} else {
41    CMAKE_DEBUG_AND_RELEASE = FALSE
42}
43
44equals(QMAKE_HOST.os, Windows): CMAKE_BIN_SUFFIX = ".exe"
45cmake_config_file.input = $$PWD/Qt5QmlImportScannerConfig.cmake.in
46cmake_config_file.output = $$MODULE_BASE_OUTDIR/lib/cmake/Qt5QmlImportScanner/Qt5QmlImportScannerConfig.cmake
47QMAKE_SUBSTITUTES += cmake_config_file
48
49cmake_build_integration.files = $$cmake_config_file.output $$PWD/Qt5QmlImportScannerTemplate.cpp.in
50cmake_build_integration.path = $$[QT_INSTALL_PREFIX]/lib/cmake/Qt5QmlImportScanner
51prefix_build: INSTALLS += cmake_build_integration
52else: COPIES += cmake_build_integration
53
54QMAKE_TARGET_DESCRIPTION = QML Import Scanner
55
56load(qt_tool)
57