1#
2# qmake configuration for Compilers based on the Microsoft Visual Studio
3# C/C++ Compilers like win32-clang-msvc
4
5#
6# Version-specific changes
7#
8
9isEmpty(QMAKE_MSC_VER): error("msvc-based-version.conf loaded but QMAKE_MSC_VER isn't set")
10
11MSVC_VER = 14.0
12COMPAT_MKSPEC       = win32-msvc2015
13
14# -utf-8 compiler option for Visual Studio 2015 Update 2
15greaterThan(QMAKE_MSC_FULL_VER, 190023918):!intel_icl {
16    isEmpty(QT_CLANG_MAJOR_VERSION)|!lessThan(QT_CLANG_MAJOR_VERSION, 4) {
17        QMAKE_CFLAGS_UTF8_SOURCE = -utf-8
18    }
19}
20
21greaterThan(QMAKE_MSC_VER, 1909) {
22    # Visual Studio 2017 (15.0) / Visual C++ 19.10 and up
23    MSVC_VER            = 15.0
24    COMPAT_MKSPEC       = win32-msvc2017
25}
26
27greaterThan(QMAKE_MSC_VER, 1910) {
28    # No compat spec past MSVC 2017
29    COMPAT_MKSPEC       =
30}
31
32greaterThan(QMAKE_MSC_VER, 1919) {
33    # Visual Studio 2019 (16.0) / Visual C++ 19.20 and up
34    MSVC_VER            = 16.0
35}
36
37!isEmpty(COMPAT_MKSPEC):!$$COMPAT_MKSPEC: CONFIG += $$COMPAT_MKSPEC
38