1 %option nounput
2
3 %{
4
5 /* Copyright (C) 1991-2016 Free Software Foundation, Inc.
6 Written by Steve Chamberlain of Cygnus Support.
7
8 This file is part of the GNU Binutils.
9
10 This program is free software; you can redistribute it and/or modify
11 it under the terms of the GNU General Public License as published by
12 the Free Software Foundation; either version 3 of the License, or
13 (at your option) any later version.
14
15 This program is distributed in the hope that it will be useful,
16 but WITHOUT ANY WARRANTY; without even the implied warranty of
17 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 GNU General Public License for more details.
19
20 You should have received a copy of the GNU General Public License
21 along with this program; if not, write to the Free Software
22 Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
23 MA 02110-1301, USA. */
24
25 #include "sysdep.h"
26 #include "bfd.h"
27 #include "safe-ctype.h"
28 #include "bfdlink.h"
29 #include "ld.h"
30 #include "ldmisc.h"
31 #include "ldexp.h"
32 #include "ldlang.h"
33 #include <ldgram.h>
34 #include "ldfile.h"
35 #include "ldlex.h"
36 #include "ldmain.h"
37 #include "libiberty.h"
38
39 /* The type of top-level parser input.
40 yylex and yyparse (indirectly) both check this. */
41 input_type parser_input;
42
43 /* Line number in the current input file.
44 (FIXME Actually, it doesn't appear to get reset for each file?) */
45 unsigned int lineno = 1;
46
47 /* The string we are currently lexing, or NULL if we are reading a
48 file. */
49 const char *lex_string = NULL;
50
51 /* Support for flex reading from more than one input file (stream).
52 `include_stack' is flex's input state for each open file;
53 `file_name_stack' is the file names. `lineno_stack' is the current
54 line numbers.
55
56 If `include_stack_ptr' is 0, we haven't started reading anything yet.
57 Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid. */
58
59 #undef YY_INPUT
60 #define YY_INPUT(buf,result,max_size) result = yy_input (buf, max_size)
61
62 #ifndef YY_NO_UNPUT
63 #define YY_NO_UNPUT
64 #endif
65
66 #define MAX_INCLUDE_DEPTH 10
67 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
68 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
69 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
70 static unsigned int sysrooted_stack[MAX_INCLUDE_DEPTH];
71 static unsigned int include_stack_ptr = 0;
72 static int vers_node_nesting = 0;
73
74 static int yy_input (char *, int);
75 static void comment (void);
76 static void lex_warn_invalid (char *where, char *what);
77
78 /* STATES
79 EXPRESSION definitely in an expression
80 SCRIPT definitely in a script
81 INPUTLIST definitely in a script, a filename-list
82 BOTH either EXPRESSION or SCRIPT
83 DEFSYMEXP in an argument to -defsym
84 MRI in an MRI script
85 VERS_START starting a Sun style mapfile
86 VERS_SCRIPT a Sun style mapfile
87 VERS_NODE a node within a Sun style mapfile
88 */
89 #define RTOKEN(x) { yylval.token = x; return x; }
90
91 /* Some versions of flex want this. */
92 #ifndef yywrap
yywrap(void)93 int yywrap (void) { return 1; }
94 #endif
95 %}
96
97 %a 4000
98 %o 5000
99
100 CMDFILENAMECHAR [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
101 CMDFILENAMECHAR1 [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
102 FILENAMECHAR1 [_a-zA-Z\/\.\\\$\_\~]
103 SYMBOLCHARN [_a-zA-Z\/\.\\\$\_\~0-9]
104 FILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
105 WILDCHAR [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*\^\!]
106 WHITE [ \t\n\r]+
107
108 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
109
110 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
111 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
112
113 %s SCRIPT
114 %s INPUTLIST
115 %s EXPRESSION
116 %s BOTH
117 %s DEFSYMEXP
118 %s MRI
119 %s VERS_START
120 %s VERS_SCRIPT
121 %s VERS_NODE
122 %%
123
124 if (parser_input != input_selected)
125 {
126 /* The first token of the input determines the initial parser state. */
127 input_type t = parser_input;
128 parser_input = input_selected;
129 switch (t)
130 {
131 case input_script: return INPUT_SCRIPT; break;
132 case input_mri_script: return INPUT_MRI_SCRIPT; break;
133 case input_version_script: return INPUT_VERSION_SCRIPT; break;
134 case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
135 case input_defsym: return INPUT_DEFSYM; break;
136 default: abort ();
137 }
138 }
139
140 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>"/*" { comment (); }
141
142
143 <DEFSYMEXP>"-" { RTOKEN('-');}
144 <DEFSYMEXP>"+" { RTOKEN('+');}
145 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}* { yylval.name = xstrdup (yytext); return NAME; }
146 <DEFSYMEXP>"=" { RTOKEN('='); }
147
148 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
149 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
150 yylval.bigint.str = NULL;
151 return INT;
152 }
153
154 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
155 int ibase ;
156 switch (yytext[yyleng - 1]) {
157 case 'X':
158 case 'x':
159 case 'H':
160 case 'h':
161 ibase = 16;
162 break;
163 case 'O':
164 case 'o':
165 ibase = 8;
166 break;
167 case 'B':
168 case 'b':
169 ibase = 2;
170 break;
171 default:
172 ibase = 10;
173 }
174 yylval.integer = bfd_scan_vma (yytext, 0,
175 ibase);
176 yylval.bigint.str = NULL;
177 return INT;
178 }
179 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
180 char *s = yytext;
181 int ibase = 0;
182
183 if (*s == '$')
184 {
185 ++s;
186 ibase = 16;
187 }
188 yylval.integer = bfd_scan_vma (s, 0, ibase);
189 yylval.bigint.str = NULL;
190 if (yytext[yyleng - 1] == 'M'
191 || yytext[yyleng - 1] == 'm')
192 {
193 yylval.integer *= 1024 * 1024;
194 }
195 else if (yytext[yyleng - 1] == 'K'
196 || yytext[yyleng - 1]=='k')
197 {
198 yylval.integer *= 1024;
199 }
200 else if (yytext[0] == '0'
201 && (yytext[1] == 'x'
202 || yytext[1] == 'X'))
203 {
204 yylval.bigint.str = xstrdup (yytext + 2);
205 }
206 return INT;
207 }
208 <BOTH,SCRIPT,EXPRESSION,MRI>"]" { RTOKEN(']');}
209 <BOTH,SCRIPT,EXPRESSION,MRI>"[" { RTOKEN('[');}
210 <BOTH,SCRIPT,EXPRESSION,MRI>"<<=" { RTOKEN(LSHIFTEQ);}
211 <BOTH,SCRIPT,EXPRESSION,MRI>">>=" { RTOKEN(RSHIFTEQ);}
212 <BOTH,SCRIPT,EXPRESSION,MRI>"||" { RTOKEN(OROR);}
213 <BOTH,SCRIPT,EXPRESSION,MRI>"==" { RTOKEN(EQ);}
214 <BOTH,SCRIPT,EXPRESSION,MRI>"!=" { RTOKEN(NE);}
215 <BOTH,SCRIPT,EXPRESSION,MRI>">=" { RTOKEN(GE);}
216 <BOTH,SCRIPT,EXPRESSION,MRI>"<=" { RTOKEN(LE);}
217 <BOTH,SCRIPT,EXPRESSION,MRI>"<<" { RTOKEN(LSHIFT);}
218 <BOTH,SCRIPT,EXPRESSION,MRI>">>" { RTOKEN(RSHIFT);}
219 <BOTH,SCRIPT,EXPRESSION,MRI>"+=" { RTOKEN(PLUSEQ);}
220 <BOTH,SCRIPT,EXPRESSION,MRI>"-=" { RTOKEN(MINUSEQ);}
221 <BOTH,SCRIPT,EXPRESSION,MRI>"*=" { RTOKEN(MULTEQ);}
222 <BOTH,SCRIPT,EXPRESSION,MRI>"/=" { RTOKEN(DIVEQ);}
223 <BOTH,SCRIPT,EXPRESSION,MRI>"&=" { RTOKEN(ANDEQ);}
224 <BOTH,SCRIPT,EXPRESSION,MRI>"|=" { RTOKEN(OREQ);}
225 <BOTH,SCRIPT,EXPRESSION,MRI>"&&" { RTOKEN(ANDAND);}
226 <BOTH,SCRIPT,EXPRESSION,MRI>">" { RTOKEN('>');}
227 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>"," { RTOKEN(',');}
228 <BOTH,SCRIPT,EXPRESSION,MRI>"&" { RTOKEN('&');}
229 <BOTH,SCRIPT,EXPRESSION,MRI>"|" { RTOKEN('|');}
230 <BOTH,SCRIPT,EXPRESSION,MRI>"~" { RTOKEN('~');}
231 <BOTH,SCRIPT,EXPRESSION,MRI>"!" { RTOKEN('!');}
232 <BOTH,SCRIPT,EXPRESSION,MRI>"?" { RTOKEN('?');}
233 <BOTH,SCRIPT,EXPRESSION,MRI>"*" { RTOKEN('*');}
234 <BOTH,SCRIPT,EXPRESSION,MRI>"+" { RTOKEN('+');}
235 <BOTH,SCRIPT,EXPRESSION,MRI>"-" { RTOKEN('-');}
236 <BOTH,SCRIPT,EXPRESSION,MRI>"/" { RTOKEN('/');}
237 <BOTH,SCRIPT,EXPRESSION,MRI>"%" { RTOKEN('%');}
238 <BOTH,SCRIPT,EXPRESSION,MRI>"<" { RTOKEN('<');}
239 <BOTH,SCRIPT,EXPRESSION,MRI>"=" { RTOKEN('=');}
240 <BOTH,SCRIPT,EXPRESSION,MRI>"}" { RTOKEN('}') ; }
241 <BOTH,SCRIPT,EXPRESSION,MRI>"{" { RTOKEN('{'); }
242 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>")" { RTOKEN(')');}
243 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>"(" { RTOKEN('(');}
244 <BOTH,SCRIPT,EXPRESSION,MRI>":" { RTOKEN(':'); }
245 <BOTH,SCRIPT,EXPRESSION,MRI>";" { RTOKEN(';');}
246 <BOTH,SCRIPT>"MEMORY" { RTOKEN(MEMORY);}
247 <BOTH,SCRIPT>"REGION_ALIAS" { RTOKEN(REGION_ALIAS);}
248 <BOTH,SCRIPT>"LD_FEATURE" { RTOKEN(LD_FEATURE);}
249 <BOTH,SCRIPT,EXPRESSION>"ORIGIN" { RTOKEN(ORIGIN);}
250 <BOTH,SCRIPT>"VERSION" { RTOKEN(VERSIONK);}
251 <EXPRESSION,BOTH,SCRIPT>"BLOCK" { RTOKEN(BLOCK);}
252 <EXPRESSION,BOTH,SCRIPT>"BIND" { RTOKEN(BIND);}
253 <BOTH,SCRIPT,EXPRESSION>"LENGTH" { RTOKEN(LENGTH);}
254 <EXPRESSION,BOTH,SCRIPT>"ALIGN" { RTOKEN(ALIGN_K);}
255 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN" { RTOKEN(DATA_SEGMENT_ALIGN);}
256 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END" { RTOKEN(DATA_SEGMENT_RELRO_END);}
257 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END" { RTOKEN(DATA_SEGMENT_END);}
258 <EXPRESSION,BOTH,SCRIPT>"ADDR" { RTOKEN(ADDR);}
259 <EXPRESSION,BOTH,SCRIPT>"LOADADDR" { RTOKEN(LOADADDR);}
260 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF" { RTOKEN(ALIGNOF); }
261 <EXPRESSION,BOTH>"MAX" { RTOKEN(MAX_K); }
262 <EXPRESSION,BOTH>"MIN" { RTOKEN(MIN_K); }
263 <EXPRESSION,BOTH>"LOG2CEIL" { RTOKEN(LOG2CEIL); }
264 <EXPRESSION,BOTH,SCRIPT>"ASSERT" { RTOKEN(ASSERT_K); }
265 <BOTH,SCRIPT>"ENTRY" { RTOKEN(ENTRY);}
266 <BOTH,SCRIPT,MRI>"EXTERN" { RTOKEN(EXTERN);}
267 <EXPRESSION,BOTH,SCRIPT>"NEXT" { RTOKEN(NEXT);}
268 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers" { RTOKEN(SIZEOF_HEADERS);}
269 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS" { RTOKEN(SIZEOF_HEADERS);}
270 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
271 <BOTH,SCRIPT>"MAP" { RTOKEN(MAP);}
272 <EXPRESSION,BOTH,SCRIPT>"SIZEOF" { RTOKEN(SIZEOF);}
273 <BOTH,SCRIPT>"TARGET" { RTOKEN(TARGET_K);}
274 <BOTH,SCRIPT>"SEARCH_DIR" { RTOKEN(SEARCH_DIR);}
275 <BOTH,SCRIPT>"OUTPUT" { RTOKEN(OUTPUT);}
276 <BOTH,SCRIPT>"INPUT" { RTOKEN(INPUT);}
277 <EXPRESSION,BOTH,SCRIPT>"GROUP" { RTOKEN(GROUP);}
278 <EXPRESSION,BOTH,SCRIPT,INPUTLIST>"AS_NEEDED" { RTOKEN(AS_NEEDED);}
279 <EXPRESSION,BOTH,SCRIPT>"DEFINED" { RTOKEN(DEFINED);}
280 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS" { RTOKEN(CREATE_OBJECT_SYMBOLS);}
281 <BOTH,SCRIPT>"CONSTRUCTORS" { RTOKEN( CONSTRUCTORS);}
282 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION" { RTOKEN(FORCE_COMMON_ALLOCATION);}
283 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
284 <BOTH,SCRIPT>"SECTIONS" { RTOKEN(SECTIONS);}
285 <BOTH,SCRIPT>"INSERT" { RTOKEN(INSERT_K);}
286 <BOTH,SCRIPT>"AFTER" { RTOKEN(AFTER);}
287 <BOTH,SCRIPT>"BEFORE" { RTOKEN(BEFORE);}
288 <BOTH,SCRIPT>"FILL" { RTOKEN(FILL);}
289 <BOTH,SCRIPT>"STARTUP" { RTOKEN(STARTUP);}
290 <BOTH,SCRIPT>"OUTPUT_FORMAT" { RTOKEN(OUTPUT_FORMAT);}
291 <BOTH,SCRIPT>"OUTPUT_ARCH" { RTOKEN( OUTPUT_ARCH);}
292 <BOTH,SCRIPT>"HLL" { RTOKEN(HLL);}
293 <BOTH,SCRIPT>"SYSLIB" { RTOKEN(SYSLIB);}
294 <BOTH,SCRIPT>"FLOAT" { RTOKEN(FLOAT);}
295 <BOTH,SCRIPT>"QUAD" { RTOKEN( QUAD);}
296 <BOTH,SCRIPT>"SQUAD" { RTOKEN( SQUAD);}
297 <BOTH,SCRIPT>"LONG" { RTOKEN( LONG);}
298 <BOTH,SCRIPT>"SHORT" { RTOKEN( SHORT);}
299 <BOTH,SCRIPT>"BYTE" { RTOKEN( BYTE);}
300 <BOTH,SCRIPT>"NOFLOAT" { RTOKEN(NOFLOAT);}
301 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS" { RTOKEN(NOCROSSREFS);}
302 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS_TO" { RTOKEN(NOCROSSREFS_TO);}
303 <BOTH,SCRIPT>"OVERLAY" { RTOKEN(OVERLAY); }
304 <BOTH,SCRIPT>"SORT_BY_NAME" { RTOKEN(SORT_BY_NAME); }
305 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT" { RTOKEN(SORT_BY_ALIGNMENT); }
306 <BOTH,SCRIPT>"SORT" { RTOKEN(SORT_BY_NAME); }
307 <BOTH,SCRIPT>"SORT_BY_INIT_PRIORITY" { RTOKEN(SORT_BY_INIT_PRIORITY); }
308 <BOTH,SCRIPT>"SORT_NONE" { RTOKEN(SORT_NONE); }
309 <EXPRESSION,BOTH,SCRIPT>"NOLOAD" { RTOKEN(NOLOAD);}
310 <EXPRESSION,BOTH,SCRIPT>"DSECT" { RTOKEN(DSECT);}
311 <EXPRESSION,BOTH,SCRIPT>"COPY" { RTOKEN(COPY);}
312 <EXPRESSION,BOTH,SCRIPT>"INFO" { RTOKEN(INFO);}
313 <EXPRESSION,BOTH,SCRIPT>"OVERLAY" { RTOKEN(OVERLAY);}
314 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO" { RTOKEN(ONLY_IF_RO); }
315 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW" { RTOKEN(ONLY_IF_RW); }
316 <EXPRESSION,BOTH,SCRIPT>"SPECIAL" { RTOKEN(SPECIAL); }
317 <BOTH,SCRIPT>"o" { RTOKEN(ORIGIN);}
318 <BOTH,SCRIPT>"org" { RTOKEN(ORIGIN);}
319 <BOTH,SCRIPT>"l" { RTOKEN( LENGTH);}
320 <BOTH,SCRIPT>"len" { RTOKEN( LENGTH);}
321 <EXPRESSION,BOTH,SCRIPT>"INPUT_SECTION_FLAGS" { RTOKEN(INPUT_SECTION_FLAGS); }
322 <EXPRESSION,BOTH,SCRIPT>"INCLUDE" { RTOKEN(INCLUDE);}
323 <BOTH,SCRIPT>"PHDRS" { RTOKEN (PHDRS); }
324 <EXPRESSION,BOTH,SCRIPT>"AT" { RTOKEN(AT);}
325 <EXPRESSION,BOTH,SCRIPT>"ALIGN_WITH_INPUT" { RTOKEN(ALIGN_WITH_INPUT);}
326 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN" { RTOKEN(SUBALIGN);}
327 <EXPRESSION,BOTH,SCRIPT>"HIDDEN" { RTOKEN(HIDDEN); }
328 <EXPRESSION,BOTH,SCRIPT>"PROVIDE" { RTOKEN(PROVIDE); }
329 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
330 <EXPRESSION,BOTH,SCRIPT>"KEEP" { RTOKEN(KEEP); }
331 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE" { RTOKEN(EXCLUDE_FILE); }
332 <EXPRESSION,BOTH,SCRIPT>"CONSTANT" { RTOKEN(CONSTANT);}
333 <MRI>"#".*\n? { ++ lineno; }
334 <MRI>"\n" { ++ lineno; RTOKEN(NEWLINE); }
335 <MRI>"*".* { /* Mri comment line */ }
336 <MRI>";".* { /* Mri comment line */ }
337 <MRI>"END" { RTOKEN(ENDWORD); }
338 <MRI>"ALIGNMOD" { RTOKEN(ALIGNMOD);}
339 <MRI>"ALIGN" { RTOKEN(ALIGN_K);}
340 <MRI>"CHIP" { RTOKEN(CHIP); }
341 <MRI>"BASE" { RTOKEN(BASE); }
342 <MRI>"ALIAS" { RTOKEN(ALIAS); }
343 <MRI>"TRUNCATE" { RTOKEN(TRUNCATE); }
344 <MRI>"LOAD" { RTOKEN(LOAD); }
345 <MRI>"PUBLIC" { RTOKEN(PUBLIC); }
346 <MRI>"ORDER" { RTOKEN(ORDER); }
347 <MRI>"NAME" { RTOKEN(NAMEWORD); }
348 <MRI>"FORMAT" { RTOKEN(FORMAT); }
349 <MRI>"CASE" { RTOKEN(CASE); }
350 <MRI>"START" { RTOKEN(START); }
351 <MRI>"LIST".* { RTOKEN(LIST); /* LIST and ignore to end of line */ }
352 <MRI>"SECT" { RTOKEN(SECT); }
353 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE" { RTOKEN(ABSOLUTE); }
354 <MRI>"end" { RTOKEN(ENDWORD); }
355 <MRI>"alignmod" { RTOKEN(ALIGNMOD);}
356 <MRI>"align" { RTOKEN(ALIGN_K);}
357 <MRI>"chip" { RTOKEN(CHIP); }
358 <MRI>"base" { RTOKEN(BASE); }
359 <MRI>"alias" { RTOKEN(ALIAS); }
360 <MRI>"truncate" { RTOKEN(TRUNCATE); }
361 <MRI>"load" { RTOKEN(LOAD); }
362 <MRI>"public" { RTOKEN(PUBLIC); }
363 <MRI>"order" { RTOKEN(ORDER); }
364 <MRI>"name" { RTOKEN(NAMEWORD); }
365 <MRI>"format" { RTOKEN(FORMAT); }
366 <MRI>"case" { RTOKEN(CASE); }
367 <MRI>"extern" { RTOKEN(EXTERN); }
368 <MRI>"start" { RTOKEN(START); }
369 <MRI>"list".* { RTOKEN(LIST); /* LIST and ignore to end of line */ }
370 <MRI>"sect" { RTOKEN(SECT); }
371 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute" { RTOKEN(ABSOLUTE); }
372
373 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}* {
374 /* Filename without commas, needed to parse mri stuff */
375 yylval.name = xstrdup (yytext);
376 return NAME;
377 }
378
379
380 <BOTH,INPUTLIST>{FILENAMECHAR1}{FILENAMECHAR}* {
381 yylval.name = xstrdup (yytext);
382 return NAME;
383 }
384 <INPUTLIST>"="{FILENAMECHAR1}{FILENAMECHAR}* {
385 /* Filename to be prefixed by --sysroot or when non-sysrooted, nothing. */
386 yylval.name = xstrdup (yytext);
387 return NAME;
388 }
389 <BOTH,INPUTLIST>"-l"{FILENAMECHAR}+ {
390 yylval.name = xstrdup (yytext + 2);
391 return LNAME;
392 }
393 <EXPRESSION>{FILENAMECHAR1}{NOCFILENAMECHAR}* {
394 yylval.name = xstrdup (yytext);
395 return NAME;
396 }
397 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
398 yylval.name = xstrdup (yytext + 2);
399 return LNAME;
400 }
401 <SCRIPT>{WILDCHAR}* {
402 /* Annoyingly, this pattern can match comments, and we have
403 longest match issues to consider. So if the first two
404 characters are a comment opening, put the input back and
405 try again. */
406 if (yytext[0] == '/' && yytext[1] == '*')
407 {
408 yyless (2);
409 comment ();
410 }
411 else
412 {
413 yylval.name = xstrdup (yytext);
414 return NAME;
415 }
416 }
417
418 <EXPRESSION,BOTH,SCRIPT,VERS_NODE,INPUTLIST>"\""[^\"]*"\"" {
419 /* No matter the state, quotes
420 give what's inside */
421 yylval.name = xstrdup (yytext + 1);
422 yylval.name[yyleng - 2] = 0;
423 return NAME;
424 }
425 <BOTH,SCRIPT,EXPRESSION>"\n" { lineno++;}
426 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+ { }
427
428 <VERS_NODE,VERS_SCRIPT>[:,;] { return *yytext; }
429
430 <VERS_NODE>global { RTOKEN(GLOBAL); }
431
432 <VERS_NODE>local { RTOKEN(LOCAL); }
433
434 <VERS_NODE>extern { RTOKEN(EXTERN); }
435
436 <VERS_NODE>{V_IDENTIFIER} { yylval.name = xstrdup (yytext);
437 return VERS_IDENTIFIER; }
438
439 <VERS_SCRIPT>{V_TAG} { yylval.name = xstrdup (yytext);
440 return VERS_TAG; }
441
442 <VERS_START>"{" { BEGIN(VERS_SCRIPT); return *yytext; }
443
444 <VERS_SCRIPT>"{" { BEGIN(VERS_NODE);
445 vers_node_nesting = 0;
446 return *yytext;
447 }
448 <VERS_SCRIPT>"}" { return *yytext; }
449 <VERS_NODE>"{" { vers_node_nesting++; return *yytext; }
450 <VERS_NODE>"}" { if (--vers_node_nesting < 0)
451 BEGIN(VERS_SCRIPT);
452 return *yytext;
453 }
454
455 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[\n] { lineno++; }
456
457 <VERS_START,VERS_NODE,VERS_SCRIPT>#.* { /* Eat up comments */ }
458
459 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[ \t\r]+ { /* Eat up whitespace */ }
460
461 <<EOF>> {
462 include_stack_ptr--;
463 if (include_stack_ptr == 0)
464 yyterminate ();
465 else
466 yy_switch_to_buffer (include_stack[include_stack_ptr]);
467
468 lineno = lineno_stack[include_stack_ptr];
469 input_flags.sysrooted = sysrooted_stack[include_stack_ptr];
470
471 return END;
472 }
473
474 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>. lex_warn_invalid (" in script", yytext);
475 <EXPRESSION,DEFSYMEXP,BOTH>. lex_warn_invalid (" in expression", yytext);
476
477 %%
478
479
480 /* Switch flex to reading script file NAME, open on FILE,
481 saving the current input info on the include stack. */
482
483 void
484 lex_push_file (FILE *file, const char *name, unsigned int sysrooted)
485 {
486 if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
487 {
488 einfo ("%F:includes nested too deeply\n");
489 }
490 file_name_stack[include_stack_ptr] = name;
491 lineno_stack[include_stack_ptr] = lineno;
492 sysrooted_stack[include_stack_ptr] = input_flags.sysrooted;
493 include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
494
495 include_stack_ptr++;
496 lineno = 1;
497 input_flags.sysrooted = sysrooted;
498 yyin = file;
499 yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
500 }
501
502 /* Return a newly created flex input buffer containing STRING,
503 which is SIZE bytes long. */
504
505 static YY_BUFFER_STATE
506 yy_create_string_buffer (const char *string, size_t size)
507 {
508 YY_BUFFER_STATE b;
509
510 /* Calls to m-alloc get turned by sed into xm-alloc. */
511 b = malloc (sizeof (struct yy_buffer_state));
512 b->yy_input_file = 0;
513 b->yy_buf_size = size;
514
515 /* yy_ch_buf has to be 2 characters longer than the size given because
516 we need to put in 2 end-of-buffer characters. */
517 b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
518
519 b->yy_ch_buf[0] = '\n';
520 strcpy (b->yy_ch_buf+1, string);
521 b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
522 b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
523 b->yy_n_chars = size+1;
524 b->yy_buf_pos = &b->yy_ch_buf[1];
525
526 b->yy_is_our_buffer = 1;
527 b->yy_is_interactive = 0;
528 b->yy_at_bol = 1;
529 b->yy_fill_buffer = 0;
530
531 /* flex 2.4.7 changed the interface. FIXME: We should not be using
532 a flex internal interface in the first place! */
533 #ifdef YY_BUFFER_NEW
534 b->yy_buffer_status = YY_BUFFER_NEW;
535 #else
536 b->yy_eof_status = EOF_NOT_SEEN;
537 #endif
538
539 return b;
540 }
541
542 /* Switch flex to reading from STRING, saving the current input info
543 on the include stack. */
544
545 void
546 lex_redirect (const char *string, const char *fake_filename, unsigned int count)
547 {
548 YY_BUFFER_STATE tmp;
549
550 yy_init = 0;
551 if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
552 {
553 einfo("%F: macros nested too deeply\n");
554 }
555 file_name_stack[include_stack_ptr] = fake_filename;
556 lineno_stack[include_stack_ptr] = lineno;
557 include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
558 include_stack_ptr++;
559 lineno = count;
560 tmp = yy_create_string_buffer (string, strlen (string));
561 yy_switch_to_buffer (tmp);
562 }
563
564 /* Functions to switch to a different flex start condition,
565 saving the current start condition on `state_stack'. */
566
567 static int state_stack[MAX_INCLUDE_DEPTH * 2];
568 static int *state_stack_p = state_stack;
569
570 void
571 ldlex_script (void)
572 {
573 *(state_stack_p)++ = yy_start;
574 BEGIN (SCRIPT);
575 }
576
577 void
578 ldlex_inputlist (void)
579 {
580 *(state_stack_p)++ = yy_start;
581 BEGIN (INPUTLIST);
582 }
583
584 void
585 ldlex_mri_script (void)
586 {
587 *(state_stack_p)++ = yy_start;
588 BEGIN (MRI);
589 }
590
591 void
592 ldlex_version_script (void)
593 {
594 *(state_stack_p)++ = yy_start;
595 BEGIN (VERS_START);
596 }
597
598 void
599 ldlex_version_file (void)
600 {
601 *(state_stack_p)++ = yy_start;
602 BEGIN (VERS_SCRIPT);
603 }
604
605 void
606 ldlex_defsym (void)
607 {
608 *(state_stack_p)++ = yy_start;
609 BEGIN (DEFSYMEXP);
610 }
611
612 void
613 ldlex_expression (void)
614 {
615 *(state_stack_p)++ = yy_start;
616 BEGIN (EXPRESSION);
617 }
618
619 void
620 ldlex_both (void)
621 {
622 *(state_stack_p)++ = yy_start;
623 BEGIN (BOTH);
624 }
625
626 void
627 ldlex_popstate (void)
628 {
629 yy_start = *(--state_stack_p);
630 }
631
632 /* Return the current file name, or the previous file if no file is
633 current. */
634
635 const char*
636 ldlex_filename (void)
637 {
638 return file_name_stack[include_stack_ptr - (include_stack_ptr != 0)];
639 }
640
641
642 /* Place up to MAX_SIZE characters in BUF and return
643 either the number of characters read, or 0 to indicate EOF. */
644
645 static int
646 yy_input (char *buf, int max_size)
647 {
648 int result = 0;
649 if (YY_CURRENT_BUFFER->yy_input_file)
650 {
651 if (yyin)
652 {
653 result = fread (buf, 1, max_size, yyin);
654 if (result < max_size && ferror (yyin))
655 einfo ("%F%P: read in flex scanner failed\n");
656 }
657 }
658 return result;
659 }
660
661 /* Eat the rest of a C-style comment. */
662
663 static void
664 comment (void)
665 {
666 int c;
667
668 while (1)
669 {
670 c = input();
671 while (c != '*' && c != EOF)
672 {
673 if (c == '\n')
674 lineno++;
675 c = input();
676 }
677
678 if (c == '*')
679 {
680 c = input();
681 while (c == '*')
682 c = input();
683 if (c == '/')
684 break; /* found the end */
685 }
686
687 if (c == '\n')
688 lineno++;
689
690 if (c == EOF)
691 {
692 einfo( "%F%P: EOF in comment\n");
693 break;
694 }
695 }
696 }
697
698 /* Warn the user about a garbage character WHAT in the input
699 in context WHERE. */
700
701 static void
702 lex_warn_invalid (char *where, char *what)
703 {
704 char buf[5];
705
706 /* If we have found an input file whose format we do not recognize,
707 and we are therefore treating it as a linker script, and we find
708 an invalid character, then most likely this is a real object file
709 of some different format. Treat it as such. */
710 if (ldfile_assumed_script)
711 {
712 bfd_set_error (bfd_error_file_not_recognized);
713 einfo ("%F%s: file not recognized: %E\n", ldlex_filename ());
714 }
715
716 if (! ISPRINT (*what))
717 {
718 sprintf (buf, "\\%03o", *(unsigned char *) what);
719 what = buf;
720 }
721
722 einfo ("%P:%S: ignoring invalid character `%s'%s\n", NULL, what, where);
723 }
724