1# Returns the host triple.
2# Invokes config.guess
3
4function( get_host_triple var )
5  if( MSVC )
6    if( CMAKE_SIZEOF_VOID_P EQUAL 8 )
7      set( value "x86_64-pc-windows-msvc" )
8    else()
9      set( value "i686-pc-windows-msvc" )
10    endif()
11  elseif( MINGW AND NOT MSYS )
12    if( CMAKE_SIZEOF_VOID_P EQUAL 8 )
13      set( value "x86_64-w64-windows-gnu" )
14    else()
15      set( value "i686-pc-windows-gnu" )
16    endif()
17  elseif( CMAKE_SYSTEM_NAME MATCHES "OS390" )
18    set( value "s390x-ibm-zos" )
19  elseif( CMAKE_SYSTEM_NAME STREQUAL AIX )
20    # We defer to dynamic detection of the host AIX version.
21    if( CMAKE_SIZEOF_VOID_P EQUAL 8 )
22      set( value "powerpc64-ibm-aix" )
23    else()
24      set( value "powerpc-ibm-aix" )
25    endif()
26  else( MSVC )
27    if(CMAKE_HOST_SYSTEM_NAME STREQUAL Windows AND NOT MSYS)
28      message(WARNING "unable to determine host target triple")
29    else()
30      set(config_guess ${LLVM_MAIN_SRC_DIR}/cmake/config.guess)
31      execute_process(COMMAND sh ${config_guess}
32        RESULT_VARIABLE TT_RV
33        OUTPUT_VARIABLE TT_OUT
34        OUTPUT_STRIP_TRAILING_WHITESPACE)
35      if( NOT TT_RV EQUAL 0 )
36        message(FATAL_ERROR "Failed to execute ${config_guess}")
37      endif( NOT TT_RV EQUAL 0 )
38      set( value ${TT_OUT} )
39    endif()
40  endif( MSVC )
41  set( ${var} ${value} PARENT_SCOPE )
42endfunction( get_host_triple var )
43