1include(CheckCXXCompilerFlag)
2include(CompilerRTCompile)
3include(CompilerRTLink)
4
5include_directories(..)
6include_directories(../..)
7
8set(MSAN_LIBCXX_CFLAGS
9  -fsanitize=memory
10  -fsanitize-memory-track-origins
11  -fno-sanitize-memory-param-retval  # unittests test mostly this mode.
12  -Wno-pedantic
13  -Xclang -fdepfile-entry=${COMPILER_RT_OUTPUT_DIR}/share/msan_ignorelist.txt
14  )
15
16# Unittest sources and build flags.
17set(MSAN_UNITTEST_SOURCES
18  msan_test.cpp
19  msan_test_main.cpp
20  )
21set(MSAN_LOADABLE_SOURCE
22  msan_loadable.cpp
23  )
24set(MSAN_UNITTEST_HEADERS
25  msan_test_config.h
26  ../../../include/sanitizer/msan_interface.h
27  )
28set(MSAN_UNITTEST_COMMON_CFLAGS
29  -nostdinc++
30  ${COMPILER_RT_UNITTEST_CFLAGS}
31  ${COMPILER_RT_GTEST_CFLAGS}
32  -I${COMPILER_RT_SOURCE_DIR}/include
33  -I${COMPILER_RT_SOURCE_DIR}/lib
34  -I${COMPILER_RT_SOURCE_DIR}/lib/msan
35  -g
36  -O2
37  -fno-omit-frame-pointer
38  -mno-omit-leaf-frame-pointer
39  -Wno-deprecated-declarations
40  -Wno-unused-variable
41  -Wno-zero-length-array
42  -Wno-uninitialized
43  -Werror=sign-compare
44  -Wno-gnu-zero-variadic-macro-arguments
45  -fno-sanitize-memory-param-retval  # unittests test mostly this mode.
46)
47# Remove -stdlib= which is unused when passing -nostdinc++.
48string(REGEX REPLACE "-stdlib=[a-zA-Z+]*" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
49
50set(MSAN_UNITTEST_INSTRUMENTED_CFLAGS
51  ${MSAN_UNITTEST_COMMON_CFLAGS}
52  -fsanitize=memory
53  -fsanitize-memory-track-origins
54  -mllvm -msan-keep-going=1
55)
56set(MSAN_UNITTEST_LINK_FLAGS
57  -nostdlib++
58  ${COMPILER_RT_UNITTEST_LINK_FLAGS}
59  ${COMPILER_RT_UNWINDER_LINK_LIBS}
60  -fsanitize=memory
61  # Don't need -stdlib=libc++ because we explicitly list libc++.a in the linker
62  # inputs.
63)
64
65append_list_if(COMPILER_RT_HAS_LIBDL -ldl MSAN_UNITTEST_LINK_FLAGS)
66
67macro(msan_compile obj_list source arch kind cflags)
68  sanitizer_test_compile(
69    ${obj_list} ${source} ${arch}
70    KIND ${kind}
71    COMPILE_DEPS ${MSAN_UNITTEST_HEADERS}
72    DEPS llvm_gtest msan
73    CFLAGS -isystem ${CMAKE_CURRENT_BINARY_DIR}/../libcxx_msan_${arch}/include/c++/v1
74           ${MSAN_UNITTEST_INSTRUMENTED_CFLAGS} ${cflags}
75  )
76endmacro()
77
78macro(msan_link_shared so_list so_name arch kind)
79  cmake_parse_arguments(SOURCE "" "" "OBJECTS;LINK_FLAGS;DEPS" ${ARGN})
80  set(output_so "${CMAKE_CURRENT_BINARY_DIR}/${so_name}.${arch}${kind}.so")
81  get_target_flags_for_arch(${arch} TARGET_LINK_FLAGS)
82  if(NOT COMPILER_RT_STANDALONE_BUILD)
83    list(APPEND SOURCE_DEPS msan)
84  endif()
85  clang_link_shared(${output_so}
86                OBJECTS ${SOURCE_OBJECTS}
87                LINK_FLAGS ${COMPILER_RT_UNITTEST_LINK_FLAGS} ${TARGET_LINK_FLAGS} ${SOURCE_LINK_FLAGS}
88                DEPS ${SOURCE_DEPS})
89  list(APPEND ${so_list} ${output_so})
90endmacro()
91
92# Main MemorySanitizer unit tests.
93add_custom_target(MsanUnitTests)
94set_target_properties(MsanUnitTests PROPERTIES FOLDER "MSan unit tests")
95
96# Adds MSan unit tests and benchmarks for architecture.
97macro(add_msan_tests_for_arch arch kind cflags)
98  # Build gtest instrumented with MSan.
99  set(MSAN_INST_GTEST)
100  msan_compile(MSAN_INST_GTEST ${COMPILER_RT_GTEST_SOURCE} ${arch} "${kind}"
101                               "${cflags}")
102
103  # Instrumented tests.
104  set(MSAN_INST_TEST_OBJECTS)
105  foreach (SOURCE ${MSAN_UNITTEST_SOURCES})
106    msan_compile(MSAN_INST_TEST_OBJECTS ${SOURCE} ${arch} "${kind}" "${cflags}")
107  endforeach(SOURCE)
108
109  # Instrumented loadable module objects.
110  set(MSAN_INST_LOADABLE_OBJECTS)
111  msan_compile(MSAN_INST_LOADABLE_OBJECTS ${MSAN_LOADABLE_SOURCE} ${arch} "${kind}"
112               "-fPIC;${cflags}")
113
114  # Instrumented loadable library tests.
115  set(MSAN_LOADABLE_SO)
116  msan_link_shared(MSAN_LOADABLE_SO "libmsan_loadable" ${arch} "${kind}"
117                   OBJECTS ${MSAN_INST_LOADABLE_OBJECTS}
118                   DEPS ${MSAN_INST_LOADABLE_OBJECTS})
119
120  set(MSAN_TEST_OBJECTS ${MSAN_INST_TEST_OBJECTS} ${MSAN_INST_GTEST})
121  set(MSAN_TEST_DEPS ${MSAN_TEST_OBJECTS} libcxx_msan_${arch}-build
122                     ${MSAN_LOADABLE_SO}
123		     "${MSAN_LIBCXX_DIR}/libc++.a" "${MSAN_LIBCXX_DIR}/libc++abi.a")
124  if(NOT COMPILER_RT_STANDALONE_BUILD)
125    list(APPEND MSAN_TEST_DEPS msan)
126  endif()
127  get_target_flags_for_arch(${arch} TARGET_LINK_FLAGS)
128  add_compiler_rt_test(MsanUnitTests "Msan-${arch}${kind}-Test" ${arch}
129    OBJECTS ${MSAN_TEST_OBJECTS} "${MSAN_LIBCXX_DIR}/libc++.a" "${MSAN_LIBCXX_DIR}/libc++abi.a"
130    DEPS ${MSAN_TEST_DEPS}
131    LINK_FLAGS ${MSAN_UNITTEST_LINK_FLAGS}
132               ${TARGET_LINK_FLAGS})
133endmacro()
134
135# We should only build MSan unit tests if we can build instrumented libcxx.
136if(COMPILER_RT_CAN_EXECUTE_TESTS AND
137   COMPILER_RT_LIBCXX_PATH AND
138   COMPILER_RT_LIBCXXABI_PATH)
139  foreach(arch ${MSAN_SUPPORTED_ARCH})
140    get_target_flags_for_arch(${arch} TARGET_CFLAGS)
141    set(LIBCXX_PREFIX ${CMAKE_CURRENT_BINARY_DIR}/../libcxx_msan_${arch})
142    add_custom_libcxx(libcxx_msan_${arch} ${LIBCXX_PREFIX}
143      DEPS ${MSAN_RUNTIME_LIBRARIES}
144      CFLAGS ${MSAN_LIBCXX_CFLAGS} ${TARGET_CFLAGS}
145      USE_TOOLCHAIN)
146    set(MSAN_LIBCXX_DIR ${LIBCXX_PREFIX}/lib/)
147
148    add_msan_tests_for_arch(${arch} "" "")
149    add_msan_tests_for_arch(${arch} "-with-call"
150                            "-mllvm;-msan-instrumentation-with-call-threshold=0")
151  endforeach()
152endif()
153