1# ex:ts=8 sw=4:
2# $OpenBSD: AddCreateDelete.pm,v 1.48 2020/01/11 13:46:39 espie Exp $
3#
4# Copyright (c) 2007-2014 Marc Espie <espie@openbsd.org>
5#
6# Permission to use, copy, modify, and distribute this software for any
7# purpose with or without fee is hereby granted, provided that the above
8# copyright notice and this permission notice appear in all copies.
9#
10# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
11# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
12# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
13# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
14# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
15# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
16# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
17#
18
19use strict;
20use warnings;
21
22# common framework, let's place most everything in there
23
24package OpenBSD::AddCreateDelete::State;
25our @ISA = qw(OpenBSD::State);
26
27use OpenBSD::State;
28use OpenBSD::ProgressMeter;
29
30sub init
31{
32	my $self = shift;
33
34	$self->{progressmeter} = OpenBSD::ProgressMeter->new;
35	$self->{bad} = 0;
36	$self->SUPER::init(@_);
37	$self->{export_level}++;
38}
39
40sub progress
41{
42	my $self = shift;
43	return $self->{progressmeter};
44}
45
46sub not
47{
48	my $self = shift;
49	return $self->{not};
50}
51
52sub sync_display
53{
54	my $self = shift;
55	$self->progress->clear;
56}
57
58sub add_interactive_options
59{
60	my $self = shift;
61	$self->{has_interactive_options} = 1;
62	return $self;
63}
64
65sub handle_options
66{
67	my ($state, $opt_string, @usage) = @_;
68
69	my $i;
70
71	if ($state->{has_interactive_options}) {
72		$opt_string .= 'iI';
73		$state->{opt}{i} = sub {
74			$i++;
75		};
76	};
77
78	$state->SUPER::handle_options($opt_string.'L:mnx', @usage);
79
80	$state->progress->setup($state->opt('x'), $state->opt('m'), $state);
81	$state->{not} = $state->opt('n');
82	if ($state->{has_interactive_options}) {
83		if ($state->opt('I')) {
84			$i = 0;
85		} elsif (!defined $i) {
86			$i = -t STDIN;
87		}
88	}
89	if ($i) {
90		require OpenBSD::Interactive;
91		$state->{interactive} = OpenBSD::Interactive->new($state, $i);
92	}
93	$state->{interactive} //= OpenBSD::InteractiveStub->new($state);
94}
95
96
97sub is_interactive
98{
99	return shift->{interactive}->is_interactive;
100}
101
102sub find_window_size
103{
104	my ($state, $cont) = @_;
105	$state->SUPER::find_window_size;
106	$state->{progressmeter}->compute_playfield($cont);
107}
108
109sub confirm_defaults_to_no
110{
111	my $self = shift;
112	return $self->{interactive}->confirm($self->f(@_), 0);
113}
114
115sub confirm_defaults_to_yes
116{
117	my $self = shift;
118	return $self->{interactive}->confirm($self->f(@_), 1);
119}
120
121sub ask_list
122{
123	my $self = shift;
124	return $self->{interactive}->ask_list(@_);
125}
126
127sub vsystem
128{
129	my $self = shift;
130	if ($self->verbose < 2) {
131		$self->system(@_);
132	} else {
133		$self->verbose_system(@_);
134	}
135}
136
137sub system
138{
139	my $self = shift;
140	$self->SUPER::system(@_);
141}
142
143sub run_makewhatis
144{
145	my ($state, $opts, $l) = @_;
146	my $braindead = sub { chdir('/'); };
147	while (@$l > 1000) {
148		my @b = splice(@$l, 0, 1000);
149		$state->vsystem($braindead,
150		    OpenBSD::Paths->makewhatis, @$opts, '--', @b);
151	}
152	$state->vsystem($braindead,
153	    OpenBSD::Paths->makewhatis, @$opts, '--', @$l);
154}
155
156sub ntogo
157{
158	my ($self, $offset) = @_;
159
160	return $self->{wantntogo} ?
161	    $self->progress->ntogo($self, $offset) :
162	    $self->f("ok");
163}
164
165sub ntogo_string
166{
167	my ($self, $offset) = @_;
168
169	return $self->{wantntogo} ?
170	    $self->f(" (#1)", $self->ntodo($offset // 0)) :
171	    $self->f("");
172}
173
174sub solve_dependency
175{
176	my ($self, $solver, $dep, $package) = @_;
177	# full dependency solving with everything
178	return $solver->really_solve_dependency($self, $dep, $package);
179}
180
181package OpenBSD::AddCreateDelete;
182use OpenBSD::Error;
183
184sub handle_options
185{
186	my ($self, $opt_string, $state, @usage) = @_;
187	$state->handle_options($opt_string, $self, @usage);
188}
189
190sub try_and_run_command
191{
192	my ($self, $state) = @_;
193	if ($state->defines('pkg-debug')) {
194		$self->run_command($state);
195	} else {
196		try {
197			$self->run_command($state);
198		} catch {
199			$state->errsay("#1: #2", $state->{cmd}, $_);
200			OpenBSD::Handler->reset;
201			if ($_ =~ m/^Caught SIG(\w+)/o) {
202				kill $1, $$;
203			}
204			$state->{bad}++;
205		};
206	}
207}
208
209package OpenBSD::InteractiveStub;
210sub new
211{
212	my $class = shift;
213	bless {}, $class;
214}
215
216sub ask_list
217{
218	my ($self, $prompt, @values) = @_;
219	return $values[0];
220}
221
222sub confirm
223{
224	my ($self, $prompt, $yesno) = @_;
225	return $yesno;
226}
227
228sub is_interactive
229{
230	return 0;
231}
2321;
233